C_ConvertPlannedOrder

@AbapCatalog.sqlViewName: 'CCONVPLNDORDERS'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl: {authorizationCheck: #CHECK,
                personalData.blocking: #REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Convert Planned Orders'
@Metadata.allowExtensions: true
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true

@ObjectModel: {
    usageType : { serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED }
}

// For UX inconsistency - Supervisor, MRPController text and ID appearance on the app

@AccessControl.privilegedAssociations: ['_MRPController', '_ProductionSupervisor']

define view C_ConvertPlannedOrder
  as select from I_PlannedOrder
    inner join   I_SDMAreaOfResponsibility as SDMAreaOfResponsibility on  I_PlannedOrder.MRPController   = SDMAreaOfResponsibility.MRPController
                                                                      and I_PlannedOrder.MRPPlant        = SDMAreaOfResponsibility.Plant
                                                                      and SDMAreaOfResponsibility.UserID = $session.user
{

       // Key

       @UI.dataPoint:{ title: 'Planned Order'}
       @Consumption.semanticObject: 'PlannedOrder'
       @UI.identification:[{position: 10 , type: #WITH_INTENT_BASED_NAVIGATION, semanticObjectAction: 'display' }]
       @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
       @Consumption.valueHelpDefinition: [{ entity: { name : 'I_PlannedOrderStdVH', element: 'PlannedOrder' } }]
  key  PlannedOrder,
       @Search: {defaultSearchElement: true,ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
       @Consumption.valueHelpDefinition: [{ entity: { name : 'I_MaterialStdVH', element: 'Material' } }]
       //@ObjectModel.foreignKey.association: '_Material'

       Material,
       @Search: {defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
       I_PlannedOrder._Material._Text[1: Language=$session.system_language].MaterialName,
       @Semantics.unitOfMeasure: true
       BaseUnit,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       PlannedTotalQtyInBaseUnit,
       PlannedOrderType,
       BillOfMaterialStatus,
       PlannedOrderCategory,
       @Consumption.valueHelpDefinition: [ { entity: { name: 'C_MRPAreaValHelp', element: 'MRPArea' } } ]
       MRPArea,
       @Consumption.valueHelpDefinition: [{entity:{name:'C_PlantByAreaOfRespyVH' , element: 'Plant'}}]
       MRPPlant,
       @Consumption.valueHelpDefinition: [{entity:{name:'C_PlantByAreaOfRespyVH' , element: 'Plant'}}]
       ProductionPlant,
       @Consumption.valueHelpDefinition: [{entity:{name:'C_MRPControllerByAreaOfRespyVH' , element: 'MRPController'}}]
       I_PlannedOrder.MRPController,
       MaterialProcurementCategory,
       PlannedOrderIsFirm,
       @Semantics.systemDate.createdAt: true
       @Consumption.filter.selectionType: #INTERVAL
   //  @ObjectModel.readOnly:true

  //   @ObjectModel.filter.enabled: true

       PlannedOrderOpeningDate,
       PlndOrderPlannedStartDate,
       PlndOrderPlannedEndDate,
       ProductionVersion,
       
       @Consumption.valueHelpDefinition: [{entity:{name:'I_MfgOrderProdnSupervisorVH' , element: 'ProductionSupervisor'}}]
       
       ProductionSupervisor,
       FixedSupplier                as Supplier,
       cast( '' as abap.char( 2 ) ) as PlndOrdProcessingActionControl,
       case MaterialProcurementCategory
       when 'E' then 'PDC'
       when 'F' then 'PRQ'
       else '' end                  as PlannedOrderMaintActivityType,
       
       @Consumption.valueHelpDefinition: [{entity:{name:'C_PlannedOrderPurchasingGrpVH' , element: 'PurchasingGroup'}}]
              
      // Associations

       _PurchasingDocument.PurchasingGroup,
       _PlannedOrderType,
       I_PlannedOrder._Material,
       _MRPArea,
       _MRPPlant,
       _MatlProcurementCategory,
       _PlannedOrderCategory,
       _ProductionPlant,
       I_PlannedOrder._MRPController,
       _Supplier,
       _ProductionVersion,
       _ProductionSupervisor,
       _PurchasingDocument._PurchasingGroup,
         
       @EndUserText.label: 'Long Text'
       I_PlannedOrder.PlannedOrderLongText
       
//as part of inline navigation poc

////        @EndUserText.label: 'BillOfOperationsType'

//        case  _ProductionVersion.BillOfOperationsType 

//       when 'N' then 'P'

//       when '2' then 'C'

//       else '' end                  as BillOfOperationsType

     
       
}
where
      MRPPlanningScenario       = '000'
  and PlannedOrderIsConvertible = 'X'