C_CommodityOrderRequestLeg

@AbapCatalog.sqlViewName                : 'CCMMDTYORDREQLEG'
@AbapCatalog.compiler.compareFilter     : true
@AbapCatalog.preserveKey                : true
@AccessControl.authorizationCheck       : #CHECK
@AccessControl.personalData.blocking    : #REQUIRED
@VDM.viewType                           : #CONSUMPTION
@Search.searchable                      : false
@Metadata.allowExtensions               : true
@EndUserText.label                      : 'Cmmdty Drvtv Order Request Leg Details'

@ClientHandling: {
   type         :      #CLIENT_DEPENDENT,
   algorithm    : #SESSION_VARIABLE 
}
   
---- Object Model for Commodity Order Request Leg
@ObjectModel.usageType: {
        serviceQuality : #D,
        sizeCategory   : #L,
        dataClass      : #TRANSACTIONAL   
}   

define view C_CommodityOrderRequestLeg
  as select from    I_CmmdtyOrderReqLeg             as Leg
  
  -- To get Commodity Derivative Order Request Details
    left outer join I_CommodityOrderRequest   as CommodityOrderRequest   on Leg.CommodityOrderRequestUUID = CommodityOrderRequest.CommodityOrderRequestUUID
    
  --To get Future Details
    left outer join I_CmmdtyOrderFutureIDVH   as FutureId                on  Leg.CommodityDerivativeFuture = FutureId.CmmdtyOrderFillFutureID
                                                                         and Leg.MaturityKeyDate           = FutureId.MaturityKeyDate
  -- To get text for Commodity Order Request Flow Type
    left outer join I_CmmdtyDrvtvFlowTypeText as CmmdtyDrvtvFlowTypeText on Leg.CmmdtyOrderRequestFlowType = CmmdtyDrvtvFlowTypeText.CmmdtyOrderRequestFlowType
{

  key    Leg.CmmdtyOrderReqLegUUID                                             as CmmdtyOrderReqLegUUID,
         Leg.CommodityOrderRequestUUID                                         as CommodityOrderRequestUUID,
         CommodityOrderRequest.CommodityOrderRequest                                as CommodityOrderRequest,

         -------------------------Commodity Order Request Leg Information----------------------------------
         Leg.CmmdtyOrderReqLegCategory                                         as CmmdtyOrderReqLegCategory,
         Leg.CmmdtyOrderRequestFlowType                                        as CmmdtyOrderRequestFlowType,
         CmmdtyDrvtvFlowTypeText.CmmdtyDerivativeFlowTypeText                       as CmmdtyDerivativeFlowTypeText,
         Leg.CmmdtyOrdRequestQuantityInLot                                     as CmmdtyOrdRequestQuantityInLot,
         Leg.CmmdtyDerivativeQuantityPerLot                                    as CmmdtyDerivativeQuantityPerLot,
         Leg.CmmdtyDrvtvQuantityUnitPerLot                                     as CmmdtyDrvtvQuantityUnitPerLot,
         Leg.CmmdtyDerivativeCurrencyPerLot                                    as CmmdtyDerivativeCurrencyPerLot,

         -------------------------Future Information-------------------------------------------------------
         Leg.CommodityDerivativeFuture                                         as CommodityDerivativeFuture,
         FutureId.CmmdtyOrderFillFutureName                                         as CommodityDerivativeFutureName,
         cast(FutureId.DerivativeContrSpecification
           as cmmfdor_derivativecontractspec preserving type )                      as DerivativeContrSpecification,
         FutureId.MarketIdentifierCode                                              as MarketIdentifierCode,
         cast(FutureId.Commodity
           as cmmfdor_exchangecommodity preserving type )                           as Commodity,
         Leg.MaturityKeyDate                                                   as MaturityKeyDate,

         -------------------------Administrative Data------------------------------------------------------
         Leg.CreatedByUser                                                     as CreatedByUser,
         Leg.CreationDateTime                                                  as CreationDateTime,
         Leg.LastChangedByUser                                                 as LastChangedByUser,
         Leg.LastChangeDateTime                                                as LastChangeDateTime
}