C_CollectionsInvoiceTP

@Metadata: { allowExtensions: true }
@VDM: { usage: { type:     [ #TRANSACTIONAL_PROCESSING_SERVICE ] },
                 viewType: #CONSUMPTION }
@AccessControl: { personalData:           { blocking: #BLOCKED_DATA_EXCLUDED },
                  authorizationCheck:     #CHECK }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory:   #L,
                             dataClass:      #TRANSACTIONAL },
                representativeKey: 'AccountingDocumentItem',
                semanticKey: [ 'CollectionSegment',
                               'Customer',
                               'BranchAccount',
                               'PostingKey',
                               'CompanyCode',
                               'FiscalYear',
                               'AccountingDocument',
                               'AccountingDocumentItem',
                               'DisputeCase',
                               'PromiseToPay' ],
                query: { implementedBy: 'ABAP:CL_COLL_PR_INV_QUERY' },
                supportedCapabilities: [ #SITUATION_ANCHOR ] }
@EndUserText: { label: 'Collections Invoice' }

define root view entity C_CollectionsInvoiceTP
  provider contract transactional_query
  as projection on R_CollectionsInvoiceTP as CollectionsInvoice
{

          @ObjectModel: { text: { element: [ 'CollectionSegmentName' ] } } 
  key     CollectionSegment,

          @ObjectModel: { text: { element: [ 'CompanyCodeName' ] } }
  key     CompanyCode,

  key     FiscalYear,
  key     AccountingDocument,
  key     AccountingDocumentItem,

          @ObjectModel: { text: { element: [ 'CustomerName' ] } }
          Customer,

          @ObjectModel: { text: { element: [ 'BranchAccountName' ] } }
          BranchAccount,

          DocumentDate,
          PostingDate,
          DunningLevel,
          LastDunningDate,

          @ObjectModel: { text: { element: [ 'OverdueDays' ] } }
          NetDueDate,

          Reference1InDocumentHeader,
          Reference2InDocumentHeader,

          @ObjectModel: { text: { element: [ 'PaymentMethodDescription' ] } }
          PaymentMethod,

          FinancialAccountType,

          OverdueDays,
          CashDiscount1Days,
          AmountInTransactionCurrency,
          PaidAmount,
          DunnedAmount,
          OpenAmountInDocumentCurrency,

          CashDiscountAmtInTransacCrcy,
          TransactionCurrency,
          PaymentDate,

          @ObjectModel: { text: { element: [ 'DunningBlockingReasonDesc' ] } }
          DunningBlockingReason,

          @ObjectModel: { text: { element: [ 'SpecialGLCodeLongName' ] } }
          SpecialGLCode,

          OperationalGLAccount,
          FiscalPeriod,
          BillingDocument,

          @ObjectModel: { text: { element: [ 'PostingKeyName' ] } }
          PostingKey,

          DocumentItemText,
          ReferenceDocumentLogicalSystem,

          @ObjectModel: { text: { element: [ 'CaseStatusName' ] } }
          CaseStatus,

          CaseStatusName,

          @ObjectModel: { text: { element: [ 'ReasonCodeName' ] } }
          CaseReason,
          ReasonCodeName,

          @ObjectModel: { text: { element: [ 'PromiseToPayStatusName' ] } }
          PromiseToPayStatus,

          DisputeCase,
          PromiseToPay,
          NumberOfResubmissions,
          ArrangedAmount,
          PromisedAmount,
          PromiseToPayLevel,
          PromiseToPayDueDate,
          DisputedAmount,
          CreditedAmount,
          DocumentReferenceID,
          LastDunningDurationInDays,
          ObjectKey,
          Country,
          ResubmissionUUID,
          ResubmissionDueDate,
          ResubmissionReason,
          NumberOfDaysSinceResubmission,
          CaseUniqueID,
          
          @ObjectModel: { text: { element: [ 'LatePaymentRiskName' ] } }
          LatePaymentRisk,

          // Text elements

          _PromiseToPayStatus._Text.PromiseToPayStatusName                                    as PromiseToPayStatusName    : localized,
          _PostingKey._PostingKeyText.PostingKeyName                                          as PostingKeyName            : localized,
          _SpecialGLCode._Text.SpecialGLCodeLongName                                          as SpecialGLCodeLongName     : localized,
          _DunningBlockingReasonCode._Text.DunningBlockingReasonDesc                          as DunningBlockingReasonDesc : localized,
          _CollectionSegment._Text.CollectionSegmentName                                      as CollectionSegmentName     : localized,
          _CompanyCode.CompanyCodeName                                                        as CompanyCodeName,
          _Customer.CustomerName                                                              as CustomerName,
          _BranchAccount.CustomerName                                                         as BranchAccountName,
          _PaymentMethod._Text.PaymentMethodDescription                                       as PaymentMethodDescription  : localized,
          _CollsInvcPaytDelayPrediction._CollectionsLatePaymentRisk._Text.LatePaymentRiskName as LatePaymentRiskName       : localized,

          // Virtual Elements

  virtual UICT_OverdueDays             : char1,
  virtual Criticality                  : char1,
  virtual UICT_CollectionSegment       : boolean,
  virtual UICT_DebtCollectionsIsActive : boolean,
  virtual UICT_BillingDocumentIcon     : boolean,
  virtual SitnNumberOfInstances        : sit_de_inst_count,
  virtual CollectionsInvoiceUniqueID   : sit_de_def_ancobj,

          // Exposed Associations

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _CollectionSegment,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _CompanyCode,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _Customer,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _BranchAccount,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _BillingDocument,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _DunningBlockingReasonCode,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _SpecialGLCode,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _PostingKey,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _PromiseToPayStatus,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _OperationalAcctgDocItem,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _CollectionsInvoiceNote       : redirected to C_CollectionsInvoiceNote,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _LinkedDisputeCase            : redirected to C_CollsInvoiceRelatedDsputCase,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _LinkedPromiseToPay           : redirected to C_CollsInvoiceRelatedPrms2P,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _LinkedResubmission           : redirected to C_CollsInvoiceRelatedResubmsn,

          @ObjectModel: { sort: { enabled: false },
                          filter: { enabled: false } }
          _CollsInvcPaytDelayPrediction : redirected to C_CollsInvcPaytDelayPrediction

}