C_CnsldtnUnitByTimeTP

DDL: C_CNSLDTNUNITBYTIMETP Type: view_entity CONSUMPTION Package: FIN_CS_MD_UNIT

Consolidation Unit Time Dependent

C_CnsldtnUnitByTimeTP is a Consumption CDS View that provides data about "Consolidation Unit Time Dependent" in SAP S/4HANA. It reads from 1 data source (R_CnsldtnUnitByTimeTP) and exposes 8 fields with key fields ConsolidationUnit, FromFiscalYearPeriod. It is exposed through 1 OData service (UI_FINCS_CONSUNIT_DEFINE). It is used in 1 Fiori application: Define Consolidation Units. Part of development package FIN_CS_MD_UNIT.

1 data source(s) Exposed by 1 service(s) Used in 1 Fiori app(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
R_CnsldtnUnitByTimeTP R_CnsldtnUnitByTimeTP projection

Annotations (8)

NameValueLevelField
Metadata.allowExtensions false view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Consolidation Unit Time Dependent view
Metadata.ignorePropagatedAnnotations true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_FINCS_CONSUNIT_DEFINE UI_FINCS_CONSUNIT_DEFINE V2 C1 NOT_RELEASED

Fiori Apps (1)

App IDApp NameTypeDescription
F4685 Define Consolidation Units Transactional An application used to create / change / display consolidation units master data.

Define Consolidation Units

Business Role: Administrator - Group Reporting

With this app, you manage the master data of consolidation units, including the assignment of time- and version-dependent attribute values, such as currency translation method, tax rate, or universal journal integration.Alternatively you can maintain this master data using the "Import Consolidation Master Data" app.For more information, see https://help.sap.com/viewer/4ebf1502064b406c964b0911adfb3f01/LATEST/en-US/a8f3c709a7f642398f1dd15de35b5320.html

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY ConsolidationUnit _CnsldtnUnitByTime ConsolidationUnit
KEY FromFiscalYearPeriod _CnsldtnUnitByTime FromFiscalYearPeriod
ToFiscalYearPeriod _CnsldtnUnitByTime ToFiscalYearPeriod
ConsolidationUnitLocalCurrency _CnsldtnUnitByTime ConsolidationUnitLocalCurrency
Company _CnsldtnUnitByTime Company
ETag _CnsldtnUnitByTime ETag
CurrencyNamelocalized
CompanyNamelocalized 
@Metadata.allowExtensions: false
@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #C,
  sizeCategory: #M
}
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consolidation Unit Time Dependent'
@Metadata.ignorePropagatedAnnotations: true
define view entity C_CnsldtnUnitByTimeTP
  as projection on R_CnsldtnUnitByTimeTP as _CnsldtnUnitByTime
{
  key _CnsldtnUnitByTime.ConsolidationUnit, // no value help required as field is not input enabled on UI



      @EndUserText: {
        label: 'From Fiscal Year and Period',
        quickInfo: 'From Fiscal Year and Period'
      }
      @Semantics.fiscal.yearPeriod: true
  key _CnsldtnUnitByTime.FromFiscalYearPeriod,


      @EndUserText: {
        label: 'To Fiscal Year and Period',
        quickInfo: 'To Fiscal Year and Period'
      }
      @Semantics.fiscal.yearPeriod: true
      _CnsldtnUnitByTime.ToFiscalYearPeriod,


      @Consumption.valueHelpDefinition: [{
        entity:{
          name:'C_CnsldtnCurrencyVH',
          element:'Currency'}
      }]
      @EndUserText: {
        label: 'Local Currency',
        quickInfo: 'Local Currency'
      }
      @ObjectModel.text.element: [ 'CurrencyName' ]
      @UI.textArrangement: #TEXT_LAST
      _CnsldtnUnitByTime.ConsolidationUnitLocalCurrency,


      @Consumption.valueHelpDefinition: [{
        entity:{
          name:'C_CnsldtnCompanyVH',
          element:'Company'}
      }]
      @EndUserText: {
        label: 'Company',
        quickInfo: 'Company'
      }
      @ObjectModel.text.element: [ 'CompanyName' ]
      @UI.textArrangement: #TEXT_LAST
      _CnsldtnUnitByTime.Company,
      

      @UI.hidden: true
      _CnsldtnUnitByTime.ETag,

      // texts

      @EndUserText: {
        label: 'Local Currency Description',
        quickInfo: 'Local Currency Description'
      }
      @Semantics.text:true
      _CnsldtnUnitByTime._Currency._Text.CurrencyName : localized,

      @EndUserText: {
        label: 'Company Description',
        quickInfo: 'Company Description'
      }
      @Semantics.text:true
      _CnsldtnUnitByTime._Company._Text.CompanyName : localized,


      // parent definition

      _CnsldtnUnit as _CnsldtnUnit : redirected to parent C_CnsldtnUnitTP
}

Learn More