C_CnsldtnPstRlGroupRelationTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Rule Group Relation'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
@OData.hierarchy.recursiveHierarchy:[{ entity.name: 'I_CnsldtnPstRlGroupHNRltnTP' }]
define view entity C_CnsldtnPstRlGroupRelationTP
  as projection on R_CnsldtnPstRlGroupRelationTP
{
      @UI.facet: [
        {
          label: '{@i18n>@addNode}',
          id: 'newNode',
          type: #COLLECTION,
          targetQualifier: 'NodeForm'
        },
        {
          label: '{@i18n>@addNode}',
          id: 'newRule',
          type: #COLLECTION,
          targetQualifier: 'RuleForm'
        },
        { 
          type: #FIELDGROUP_REFERENCE,
          targetQualifier: 'NewRule',
          parentId: 'newRule' 
        },
        { 
          type: #FIELDGROUP_REFERENCE,
          targetQualifier: 'NewNode',
          parentId: 'newNode'  
        }
      
       ]
      @UI.lineItem: [{ position: 10, label: 'Rule Group'  }]
  key ConsolidationPostingRuleGroup,
      @UI.lineItem: [{ position: 20, label: 'Node ID'  }]
  key CnsldtnPostingRuleGroupElement,
      @UI.lineItem: [{ position: 20, label: 'Parent Node'  }]
      CnsldtnPstRlGroupParent,
      @UI.lineItem: [{position: 30, label: 'Node Type'}]
      CnsldtnPstRlGroupNodeType,
      @UI.lineItem: [{ position: 30, label: 'Nodes'    }]
      HierarchyNodeVal,
      @UI.lineItem: [{ position: 40, label: 'Description'    }]
      @UI.fieldGroup: [{ position: 20, qualifier: 'NewNode' }]
      CnsldtnPstRlGroupNodeName,
      @UI.lineItem: [{ position: 40, label: 'Sequence'  }]
      CnsldtnPstRlGroupSequence,
      @UI.lineItem: [{ position: 50, label: 'Rule Group Reference'  }]
      @UI.fieldGroup: [{ position: 20, qualifier: 'NewNode' }]
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_CnsldtnPostingRuleGroupVH', element: 'ConsolidationPostingRuleGroup'}}]
      @ObjectModel.text.element: ['CnsldtnPostingRuleGroupText']
      CnsldtnPstRlGrpReferenceGroup,
      @UI.lineItem: [{ position: 70, label: 'Node Reference'  }]
      CnsldtnPstRlGrpRefNode,
      @UI.lineItem: [{position: 80, label: 'Rule Reference'}]
      @UI.fieldGroup: [{ position: 10, qualifier: 'NewRule' }] 
      @Consumption.valueHelpDefinition: [{ entity: { name: 'C_ConsolidationPostingRuleVH', element: 'ConsolidationPostingRule' },
                                           additionalBinding: [{ element: 'ConsolidationChartOfAccounts', localElement: 'ConsolidationChartOfAccounts', usage: #FILTER }],
                                           useForValidation: true
                                         } ]
      @ObjectModel.text.element: ['ConsolidationPostingRuleText']                     
      CnsldtnPstRlGrpReferenceRule,
      @UI.lineItem: [{ position: 60, label: 'Depends on Prev Rule'  }]
      CnsldtnPstRlIsDepdntOnPrevRule,
      CreatedByUser,
      ChangedBy,
      ChangedDateTime,
      @Semantics.text: true
      cast( _Description[1:Language=$session.system_language].CnsldtnPostingRuleGroupText as fincs_rulgrp_descr preserving type ) as CnsldtnPostingRuleGroupText,
      @Semantics.text: true
      cast( _RuleDesc[1:Language=$session.system_language].ConsolidationPostingRuleText as fincs_rule_descr preserving type ) as ConsolidationPostingRuleText,
      _Parent.ConsolidationChartOfAccounts as ConsolidationChartOfAccounts,

      /* Associations */
      _Description,
      _RuleDesc,
      _Parent : redirected to parent C_CnsldtnPostingRuleGroupTP,
      _Hierarchy : redirected to C_CnsldtnPstRlGroupRelationTP
}