C_CmpstnHistory

@AbapCatalog: {
  sqlViewName: 'CMPSTNHISTORY',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION


@ObjectModel:
{
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@EndUserText.label: 'History of Composition'

define view C_CmpstnHistory
  as select from I_ChmlComposition as ChmlComposition

  association [1..1] to I_ChmlCompositionStatusText as _CompositionStatusText on  ChmlComposition.ChmlCompositionStatus = _CompositionStatusText.ChmlCompositionStatus
                                                                              and _CompositionStatusText.Language       = $session.system_language

  association [1..1] to I_BusinessUserBasic         as _LastChangedByUser     on  ChmlComposition.LastChangedByUser = _LastChangedByUser.UserID

  association [0..1] to I_BusinessUserBasic         as _ReleasedByUser        on  ChmlComposition.ReleasedByUser = _ReleasedByUser.BusinessPartner

{
  key ChmlComposition.ChmlCompositionUUID              as ChmlCompositionUUID,

      ChmlComposition.ChmlCmplncInfoUUID               as ChmlCmplncInfoUUID,
      ChmlComposition.SubstanceUUID                    as SubstanceUUID,


      ChmlComposition.ChmlCompositionType              as ChmlCompositionType,
      ChmlComposition.ProdCmplncLegalArea              as ProdCmplncLegalArea,

      ChmlComposition.PolymerCompositionIntID          as PolymerCompositionIntID,

      ChmlComposition.ChmlCompositionStatus            as ChmlCompositionStatus,
      _CompositionStatusText.ChmlCompositionStatusName as ChmlCompositionStatusName,

      _LastChangedByUser.PersonFullName                as LastChangedByUserFullName,
      ChmlComposition.LastChangeUTCDateTime            as LastChangeDateTime,
      _ReleasedByUser.PersonFullName                   as ReleasedByUserName,
      ChmlComposition.ReleaseDateTime                  as ReleaseDateTime,
      ChmlComposition.ValidityStartDateTime            as ValidityStartDateTime,
      ChmlComposition.ValidityEndDateTime              as ValidityEndDateTime,
      ChmlComposition.CreationUTCDateTime              as CreationUTCDateTime,

      /*Association*/
      _ChmlCmplncInfo,
      _Substance,
      _CompositionType,
      _CompositionStatus

}