C_ChmlCmplncReqPrpsAssgmtTP

@EndUserText.label: 'Requested Purpose of a Chemical Compliance Request'

@AbapCatalog:
{
  sqlViewName: 'CCCREQPRPSASSTP',
  compiler.compareFilter: true,
  preserveKey : true
}

@AccessControl:
{
  authorizationCheck: #CHECK
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  transactionalProcessingDelegated: true,
  createEnabled: true,
  updateEnabled: false,
  deleteEnabled: 'EXTERNAL_CALCULATION',
  semanticKey:  [ 'CmplncPrpsUUID' ],
  usageType:
  {
    /*Service Quality - reflects the quality of service with respect to the expected performance of the CDS view:
      #A: may be consumed within business logic for high volume transactions or background processing
      #B: may be consumed within business logic for transactions or background processing
    */
    dataClass: #MIXED,
    sizeCategory: #M,
    serviceQuality: #C
  }
}

@UI.presentationVariant : {
  sortOrder: [{by: 'ChmlCmplncReqChgType', direction : #DESC}, {by: 'CmplncPrpsName', direction: #ASC }],
  groupBy : ['ChmlCmplncReqChgType']
}

--Search
@Search.searchable : true

define view C_ChmlCmplncReqPrpsAssgmtTP
  as select from I_ChmlCmplncReqPrpsAssgmtTP

  association [1..1] to C_ChmlCmplncReqProcMkt    as _ChmlCmplncReq  on _ChmlCmplncReq.ChmlCmplncRequestUUID = $projection.ChmlCmplncRequestUUID
  association [0..1] to P_ChmlCmplncPrpsMktRqmtCt as _PrpsMktRqmtCt  on _PrpsMktRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID

  association [0..*] to I_CmplncPrpsText          as _CmplncPrpsText on _CmplncPrpsText.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [1..1] to I_ChmlCmplncReqChgType    as _ChangeType     on $projection.ChmlCmplncReqChgType = _ChangeType.ChmlCmplncReqChgType
  
{
      @UI.hidden: true
      @ObjectModel.readOnly: true
  key ChmlCmplncPrpsAssgmtUUID,

      @UI.hidden: true
      ChmlCmplncRequestUUID,

      -- Change Type
      @UI: {
        lineItem:
        {
          position: 5,
          importance: #MEDIUM
        },
        textArrangement: #TEXT_ONLY
      }
      @ObjectModel:
      {
        readOnly: true,
        text.element:  [ 'ChmlCmplncReqChgTypeName' ]
      }
      ChmlCmplncReqChgType,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChangeType._Text[1: Language = $session.system_language ].ChmlCmplncReqChgTypeName,

      @UI.hidden: true
      CmplncPrpsUUID,

      @UI:
      {
        lineItem:
        {
          position: 10,
          importance: #HIGH
        }
      }
      @ObjectModel.readOnly: true
      @Semantics.text: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      _CmplncPrpsText[ 1:Language = $session.system_language ].CmplncPrpsName    as CmplncPrpsName,

      @UI:
      {
       lineItem:
       {
         position: 20,
         importance: #HIGH
       }
      }
      @ObjectModel.readOnly: true
      _PrpsMktRqmtCt.NmbrOfChmlCmplncMktRqmts,

      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
      _ChmlCmplncReq
      
      
}