C_ChmlCmplncReqCustomerCntct

@EndUserText.label: 'Chemical Compliance Request Customer Contact Card (ship to)'

@AbapCatalog:
{
  sqlViewName: 'CCREQCUSTCNTCT',
  compiler.compareFilter: true
}

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]


@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data required because of link to business user

  personalData.blocking: #REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #XL,
    serviceQuality: #C
  },
  semanticKey: [ 'SalesDocument' ]
}

--Search
//@Search.searchable : true


define view C_ChmlCmplncReqCustomerCntct
  --Select data from business user
  as select from           I_SalesDocumentPartner    as SalesDocumentPartner
    left outer to one join I_BusinessPartnerCustomer as BPCustomer      on BPCustomer.Customer = SalesDocumentPartner.Customer
    join                   I_BusinessPartner         as BusinessPartner on BPCustomer.BusinessPartner = BusinessPartner.BusinessPartner

{

      --Business User
      @ObjectModel.readOnly: true
  key SalesDocumentPartner.SalesDocument         as SalesDocument,
  
      // just needed for DCL

      @ObjectModel:
       {
         readOnly: true,
         text.element:  [ 'BusinessPartnerFullName' ]
       }
      BusinessPartner.BusinessPartner, 

      --Company Name
      // used via AS_CONTACT in contact popup

      // can not be used for searching because of calculation

      @Semantics.name.fullName: true
      BusinessPartner.BusinessPartnerFullName,

      //      // part of BusinessUserFullName, only needed for searching

      //      @Search:

      //      {

      //        defaultSearchElement: true,

      //        ranking: #HIGH,

      //        fuzzinessThreshold: 0.8

      //      }

      //      BusinessUser.PersonFullName as BusinessUserFullName,


      --Postal Code
      // used via AS_CONTACT in contact popup

      @Semantics.address.zipCode: true
      BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
      --City Name
      // used via AS_CONTACT in contact popup

      @Semantics.address.city: true
      BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.CityName,
      --Country Code
      // used via AS_CONTACT in contact popup

      @Semantics.address.country: true
      BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.Country,

      // used via AS_CONTACT in contact popup

      @Semantics.telephone.type: [#WORK]
      BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation._CurrentDfltLandlinePhoneNmbr.InternationalPhoneNumber,

      @Semantics.eMail: { address: true, type: [ #WORK ] }
      BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation._CurrentDfltEmailAddress.EmailAddress,

      @Consumption.hidden: true
      BusinessPartner.AuthorizationGroup         as AuthorizationGroup,

      @Consumption.hidden: true
      BusinessPartner.IsBusinessPurposeCompleted as IsBusinessPurposeCompleted,
      
      @Consumption.hidden: true
      SalesDocumentPartner._SalesDocument,
      
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController1,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController2,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController3,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController4,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController6,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController7,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController8,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController9,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      BusinessPartner.DataController10


}
where
  SalesDocumentPartner.PartnerFunction = 'WE' // ship to party