C_ChmlCmplncPrpsAssgmtTP

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'CCCPRPSASSGMTTP'

@AccessControl.authorizationCheck: #MANDATORY

@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Chemical Compliance Purpose Assignment'

@Metadata.allowExtensions: true

@ObjectModel.createEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: [ 'CmplncPrpsUUID' ]
@ObjectModel.transactionalProcessingDelegated: true
@ObjectModel.updateEnabled: true
@ObjectModel.usageType: { dataClass: #MASTER, sizeCategory: #M, serviceQuality: #C }

@Search.searchable: true

@VDM.viewType: #CONSUMPTION

define view C_ChmlCmplncPrpsAssgmtTP
  as select from I_ChmlCmplncPrpsAssgmtTP

  association [1..1] to C_ChmlCmplncInfoTP           as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  association [0..1] to P_ChmlCmplncPrpsMktRqmtCt    as _PrpsMktRqmtCt  on _PrpsMktRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [0..1] to P_ChmlCmplncPrpsDGRqmtCt     as _PrpsDGRqmtCt   on _PrpsDGRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [0..1] to P_ChmlCmplncPrpsSdsRqmtCt    as _PrpsSdsRqmtCt  on _PrpsSdsRqmtCt.CmplncPrpsUUID = $projection.CmplncPrpsUUID
  association [0..*] to C_CmplncPrpsNameWithFallback as _CmplncPrpsText on _CmplncPrpsText.CmplncPrpsUUID = $projection.CmplncPrpsUUID

{
      @ObjectModel.readOnly: true
  key ChmlCmplncPrpsAssgmtUUID                              as ChmlCmplncPrpsAssgmtUUID,

      ChmlCmplncInfoUUID                                    as ChmlCmplncInfoUUID,

      @Consumption.semanticObject: 'CompliancePurpose'
      @Consumption.semanticObjectMapping.element: 'CmplncPrpsNavgnLink'
      @ObjectModel.text.element: [ 'CmplncPrpsName' ]
      CmplncPrpsUUID                                        as CmplncPrpsUUID,

      CmplncPrps                                            as CmplncPrps,

      @ObjectModel.readOnly: true
      @Semantics.text: true
      cast(_CmplncPrpsText.CmplncPrps as ehfnd_cmplnc_prps) as CmplncPrpsName,

      // For search only

      @ObjectModel.readOnly: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #MEDIUM
      _CmplncPrpsText.CmplncPrpsName                        as CmplncPrpsFallbackName,

      // For search only

      @ObjectModel.readOnly: true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      @Search.ranking: #MEDIUM
      _CmplncPrpsText.CmplncPrpsEnglishName                 as CmplncPrpsEnglishName,

      @ObjectModel.readOnly: true
      _PrpsMktRqmtCt.NmbrOfChmlCmplncMktRqmts               as NmbrOfChmlCmplncMktRqmts,

      // Number of Compliance Requirement - Dangerous Goods

      @ObjectModel.readOnly: true
      _PrpsDGRqmtCt.NmbrOfChmlCmplncDngrsGdsRqmts           as NmbrOfChmlCmplncDngrsGdsRqmts,

      // Number of Compliance Requirement - Dangerous Goods

      @ObjectModel.readOnly: true
      _PrpsSdsRqmtCt.NmbrOfChmlCmplncDataShtRqmts           as NmbrOfChmlCmplncDataShtRqmts,

      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChmlCmplncInfo,

      _Purpose
}