C_ChgImpactNtwkDets

@AbapCatalog.sqlViewName: 'CCHGIMPNTWKDET'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Network Order Details'
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.semanticKey: ['NetworkOrder']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@UI.headerInfo:
{

  title:{value:'ProjectNetwork'}
  }

define view C_ChgImpactNtwkDets
  as select from I_ProjectNetwork as netw
  association [1..*] to I_WBSElement                as _WBSElementText   on $projection.wbselementinternalid = _WBSElementText.WBSElementInternalID
  association [1..1] to I_ProjectByInternalKey      as _Project          on $projection.projectinternalid = _Project.ProjectInternalID 
  association [1..1] to I_ChgImpactOrderEffectivity as _OrderEffectivity on $projection.ProjectNetwork = _OrderEffectivity.OrderID

{

      @UI.facet: [
                 ----HeaderFacets
                   { type: #FIELDGROUP_REFERENCE, position: 10, targetQualifier: 'GeneralData'},
                   { type: #FIELDGROUP_REFERENCE, position: 20, targetQualifier: 'AdministrativeData'}
                   ]
      @UI.lineItem: [{position: 10, importance: #HIGH }]
  key netw.ProjectNetwork,
      @UI.lineItem: [{position: 20, importance: #HIGH }]
      @UI.fieldGroup:[{position: 10,qualifier: 'Qualifier1',label:'Network Description', importance: #HIGH}]
      netw.ProjectNetworkDescription,
      @UI.lineItem: [{position: 20, importance: #HIGH }]
      @UI.fieldGroup: [{position: 30, qualifier: 'Qualifier1',label:'Scheduled Start Date', importance: #HIGH }]
      netw.ScheduledBasicStartDate,

      @UI.lineItem: [{position: 10, importance: #HIGH }]
      @UI.fieldGroup: [{position: 40, qualifier: 'Qualifier2',label:'Network Type', importance: #HIGH }]
      netw.ProjectNetworkType,

      @UI.lineItem: [{position: 20, importance: #HIGH }]
      @UI.fieldGroup: [{position: 50, qualifier: 'Qualifier2',label:'Scheduled End Date', importance: #HIGH }]
      netw.ScheduledBasicEndDate,

      -- Effectivity Parameter

      @UI.hidden: true
      _OrderEffectivity.EffectivityParameterVariant,     
      _OrderEffectivity.Material,
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_MPE_GET_EFFECTIVITY_VALUE'
      }
      cast('' as mpe_effectivity_parameter_desc)                                                                            as  EffectivityParameterDesc,

      @UI.hidden: true
      @ObjectModel: {
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_MPE_GET_EFFECTIVITY_VALUE'
      }
      @UI.fieldGroup: [{position: 30, qualifier: 'Label',label:'EffctyTypeCnctntdParamDesc', importance: #HIGH ,value: 'EffectivityParameterDesc'}, 
                       {position: 60, qualifier: 'Qualifier1',label:'Effectivity', importance: #HIGH ,value: 'EffectivityParameterDesc' }]
      
      cast('' as abap.sstring( 256 ))                                                                                       as  EffctyTypeCnctntdParamDesc,
      
      @UI.fieldGroup: [{position: 20, qualifier: 'GeneralData',label:'Plant', groupLabel: 'General Data' }]
      netw.Plant,
      @UI.fieldGroup: [{position: 30, qualifier: 'GeneralData',label:'MRP Controller', groupLabel: 'General Data' }]
      netw.MRPController,
      @UI.fieldGroup: [{position: 40, qualifier: 'GeneralData',label:'Project', groupLabel: 'General Data' }]
      concat_with_space( netw._WBSElementText.Project, concat(concat('(' , netw._Project.ProjectDescription),')'), 2 ) as ProjectName,
      @UI.fieldGroup: [{position: 50, qualifier: 'GeneralData',label:'WBS Element ID', groupLabel: 'General Data' }]
      concat_with_space( netw._WBSElementText.WBSElement, concat(concat('(' , netw._WBSElementText.WBSDescription),')'), 2 ) as WBSElementDescription,
      @UI.fieldGroup: [{position: 60, qualifier: 'GeneralData',label:'Actual Start Date', groupLabel: 'General Data' }]
      netw.ActualStartDate,
      @UI.fieldGroup: [{position: 70, qualifier: 'GeneralData',label:'Actual End Date',  groupLabel: 'General Data' }]
      netw.ActualEndDate,
      @UI.fieldGroup:[{position: 10,qualifier: 'AdministrativeData',label:'Created By',groupLabel: 'Administrative Data'}]
      netw.CreatedByUser,
      @UI.fieldGroup:[{position: 20,qualifier: 'AdministrativeData',label:'Creation Date',groupLabel: 'Administrative Data'}]
      netw.CreationDate,
      @UI.fieldGroup:[{position: 30,qualifier: 'AdministrativeData',label:'Last Changed Date',groupLabel: 'Administrative Data'}]
      netw.LastChangeDate,
      @UI.hidden: true
      netw._WBSElementText.WBSElementInternalID,
      @UI.hidden: true
      netw._Project.ProjectInternalID,
      _WBSElementText,
      _Project
};