@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Cash Position Profile'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
serviceQuality: #A,
sizeCategory: #S,
dataClass: #TRANSACTIONAL
}
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@UI: { headerInfo: { typeName: 'Cash Position Profile',
typeNamePlural: 'Cash Position Profiles',
description: { type: #STANDARD, value: 'CashPositionProfileDescription' } ,
title: { type: #STANDARD , value: 'CashPositionProfile'}
} }
define view entity C_CashPositionProfile
as select from I_CashPositionProfile as profile
{
@UI.facet: [{ label: 'General Information',
id: 'CollectionForGeneralData',
type: #COLLECTION,
position: 10
},
{ targetQualifier: 'GenInfo',
id: 'GenInfo',
parentId:'CollectionForGeneralData',
purpose: #STANDARD,
position: 10,
label: 'General Information',
type: #FIELDGROUP_REFERENCE
},
{ label: 'Cycle Information',
id: 'CollectionForCycle',
type: #COLLECTION,
position: 20
},
{ targetQualifier: 'CycleProp',
id: 'CycleProp',
parentId:'CollectionForCycle',
purpose: #STANDARD,
position: 20,
label: 'Cycle Settings',
type: #FIELDGROUP_REFERENCE
},
{ label: 'Position Calculation Settings',
id: 'CollectionForCalculation',
type: #COLLECTION,
position: 30
},
{ targetQualifier: 'CalculationProp',
id: 'CalculationProp',
parentId: 'CollectionForCalculation',
purpose: #STANDARD,
position: 10,
label: 'Position Calculation Settings',
type: #FIELDGROUP_REFERENCE
},
{ label: 'Administration Information',
id: 'CollectionForAdmin',
type: #COLLECTION,
position: 40
},
{ targetQualifier:'AdminInfo',
id: 'AdminInfo',
parentId: 'CollectionForAdmin',
purpose: #STANDARD,
position: 20,
label: 'Administration Information',
type: #FIELDGROUP_REFERENCE
}]
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@ObjectModel.text.element: [ 'CashPositionProfileDescription' ]
@UI:{lineItem: [{ position: 10 }]}
@UI.selectionField: [{ position: 10 }]
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 10, groupLabel:'General Information' }]
@UI.textArrangement: #TEXT_LAST
key CashPositionProfile,
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@Semantics.text: true
CashPositionProfileDescription,
@UI.lineItem: [{ position: 20 }]
@UI.selectionField: [{ position: 20 }]
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 20 }]
CashPositionHierSource,
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 30 }]
CashPositionRootNodeIsNeeded,
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 40 }]
CashPositionRootNode,
@UI.lineItem: [{ position: 60 }]
@UI.selectionField: [{ position: 60 }]
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 50 }]
CshPosKeyDteInThePastIsAllowed,
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 60, hidden: #(CashPositionHierLevel1IsHidden)}]
CashPositionHierLevel1,
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 70, hidden: #(CashPositionHierLevel1IsHidden) }]
CashPositionHierLevel2,
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 80, hidden: #(CashPositionHierLevel1IsHidden) }]
CashPositionHierLevel3,
@UI.fieldGroup: [{ qualifier: 'GenInfo', position: 90, hidden: #(BankAccountHierarchyNameIsHdn)}]
BankAccountHierarchyName,
@UI.lineItem: [{ position: 30 }]
@UI.selectionField: [{ position: 30 }]
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 10 }]
CashBalanceType,
@UI.lineItem: [{ position: 40 }]
@UI.selectionField: [{ position: 40 }]
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 20 }]
CashPositionBalanceCategory,
@UI.lineItem: [{ position: 50 }]
@UI.selectionField: [{ position: 50 }]
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 30 }]
CashPositionViewCategory,
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 40 }]
CashPositionOvrdIsIncldInClsg,
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 50 }]
CashPositionSmartCrcyIsEnabled,
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 60 }]
DisplayCurrency,
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 70 }]
EmbeddedCshPosDetViewIsVisible,
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 80 }]
ExchangeRateType,
@UI.fieldGroup: [{ qualifier: 'CalculationProp', position: 90 }]
IntradayRecnclnRsltIsConsdrd,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 10 }]
CashPositionPrdfndInterimStep,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 20 }]
CashPositionPrdfndIncrement,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 30 }]
CashPositionPeriodEndIsNatural,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 40 }]
CashPositionOverdueIsVisible,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 50 }]
CashPositionFutureIsVisible,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 60 }]
CashPositionShiftOption,
@UI.fieldGroup: [{ qualifier: 'CycleProp', position: 70 }]
FactoryCalendar,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'CashPositionHierLevel1IsHidden'
@UI.hidden: true
case when CashPositionHierSource = '02' then 'X' else '' end as UICT_HierLevelIsHidden,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'BankAccountHierarchyNameIsHdn'
@UI.hidden: true
case when CashPositionHierSource <> '02' then 'X' else '' end as UICT_HierNameIsHidden,
@UI.hidden: true
// case when CashPositionHierSource = '02' then 'X' else '' end as UICT_HierLevelIsHidden,
case when CashPositionHierSource = '02' then 'X' else '' end as CashPositionHierLevel1IsHidden,
@UI.hidden: true
// case when CashPositionHierSource <> '02' then 'X' else '' end as UICT_HierNameIsHidden,
case when CashPositionHierSource <> '02' then 'X' else '' end as BankAccountHierarchyNameIsHdn,
@UI.fieldGroup: [{ qualifier: 'AdminInfo',position: 10}]
CreatedByUser,
@UI.fieldGroup: [{ qualifier: 'AdminInfo', position: 20 }]
CreationDateTime,
@UI.fieldGroup: [{ qualifier: 'AdminInfo',position: 30}]
LastChangedByUser,
@UI.fieldGroup: [{ qualifier: 'AdminInfo', position: 40 }]
LastChangeDateTime
}
where
CashPositionProfile is not initial