C_CAPaymentOrderTP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: [ '_CreatedByContact', '_ChangedByContact' ]
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@Search.searchable: true
@EndUserText.label: 'Manage Payment Orders'
@OData.entitySet.name: 'C_CAPaymentOrderTP'

@ObjectModel: { representativeKey: 'CAPaymentOrder',
                semanticKey: [ 'CAPaymentOrder' ],
                usageType:{ dataClass: #MIXED,
                            serviceQuality:#C,
                            sizeCategory:#XL}}

@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]

define root view entity C_CAPaymentOrderTP 
  provider contract transactional_query
  as projection on R_CAPaymentOrderTP as _CAPaymentOrder
  
  
{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
  key CAPaymentOrder,

      @EndUserText.label: 'Due Date of Paid Items' 
      PaidItemDueDate,

      CAPaymentOrderExpirationDate,

      @ObjectModel.text.element: ['CAPaymentOrderStatusName']
      CAPaymentOrderStatus,
      
      @ObjectModel.text.element: ['CAPaymentOrderStatusName']
      CAPaymentOrderStatusEnhanced,
      
      @Semantics.text: true
      _CAPaymentOrderStatusEnhanced._Text[1: Language=$session.system_language].CAPaymentOrderStatusName,
      
      CAPaymentDocument,

      CAPaymentOrderExternalRef,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CANetAmountInTransCurrency,
      
      TransactionCurrency,

      ValueDate,

      @ObjectModel.text.element: ['HouseBankName']
      HouseBank,
      
      @Semantics.text: true
      _HouseBank._Bank.BankName as HouseBankName,
      
      @ObjectModel.text.element: ['HouseBankAccountDescription']
      HouseBankAccount,
      
      @Semantics.text: true
      _HouseBankAccount._Text[1: Language=$session.system_language].HouseBankAccountDescription as HouseBankAccountDescription,
      
      @ObjectModel: { text.element: ['CAPaymentMethodName'] }
      CAPaymentMethod,
      
      @Semantics.text: true
      _CAPaymentMethod._Text[1: Language=$session.system_language].CAPaymentMethodName as CAPaymentMethodName,
      
      CAMassRunDate,

      CAMassRunID,
      
      @EndUserText.label: 'Payment Run'
      CAPaymentRunDateAndID,      
            
      @ObjectModel: { text.element: ['CompanyCodeName']}
      @EndUserText.label: 'Paying Company Code' 
      CompanyCode,

      @Semantics.text: true
      _CompanyCode.CompanyCodeName as CompanyCodeName,
      
//      @ObjectModel: { text.element: ['BusinessAreaName']}

//      BusinessArea,

//      

//      @Semantics.text: true

//      _BusinessArea._Text[1:Language = $session.system_language].BusinessAreaName as BusinessAreaName,

      
      CountryCode,
     
      @ObjectModel.text.element: ['BusinessPartnerFullName']
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 } 
      @Semantics.contact.type: #PERSON
      BusinessPartner,
      
      @UI.hidden: true
      @Semantics.booleanIndicator
      IsBusinessPurposeCompleted,
      
      BusinessPartner2,
     
      @Semantics.text: true
      BusinessPartnerFullName,
      
      @ObjectModel.text.element: [ 'CreatedByUserName' ]
      CreatedByUser,
      
      @Semantics.text: true
      _CreatedByContact.FullName as CreatedByUserName,
      
      @Semantics.systemDate.createdAt: true
      CreationDate,
      
      @Semantics.systemTime.createdAt: true      
      CreationTime,
      
      @Semantics.dateTime:true
      @Semantics.systemDate.createdAt: true
      @EndUserText.label: 'Created At'  
      CreationDateTime,
      
      @ObjectModel: { text.element:  [ 'LastChangedByUserFullName' ] }
      @Semantics.user.lastChangedBy: true
      @EndUserText.label: 'Last Changed By'
      ChangedByUserName,
      
      @Semantics.text: true
      _ChangedByContact.FullName as LastChangedByUserFullName,
      
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      
      @Semantics.systemTime.lastChangedAt: true
      LastChangeTime,
      
      @Semantics.dateTime:true
      @Semantics.systemDate.lastChangedAt: false
      @EndUserText.label: 'Last Changed At' 
      LastChangeDateTime,
                                                               
      @ObjectModel.text.element:  [ 'CardTypeText' ]
      PaymentCardType,
      
      @Semantics.text: true
      CardTypeText,
      
      PaytCardByDigitalPaymentSrvc,
      
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_PAYMENTORDER_CC_EXIT'
      MaskedCardNumber,   
      
      @EndUserText.label: 'Authorization Number' 
      CAAuthznByDigitalPaytSrvc,
      
      @EndUserText.label: 'Authorization Reference Number' 
      CAAuthorizationByAcquirer,
      
      @EndUserText.label: 'Clearing Document for Card Payment' 
      CAPaytOrdPaytCardClrgDocument,
      
      @EndUserText.label: 'Reversal Document for Card Payment'       
      cast(_CAClearingDocument.CAReversalDocumentNumber as storb_gfn_kk preserving type ) as CAPaytOrdPaytCardRvslDocument,
      
      @EndUserText.label: 'Expired'
      CAPaymentOrderIsExpired,      
      
      @UI.hidden: true
      CAPaymentOrderIsChangeable,
      
      @UI.hidden: true
      CAPaymentOrderIsNotChangeable,

      @UI.hidden: true
      CAPaymentOrderIsReversible,
      
      @UI.hidden: true
      CAPaymentOrderIsNotReversible,

      @UI.hidden: true
      CAPaytOrdHasNotPaymentCardData,  
      
      @UI.hidden: true
      CAClrgDocumentIsNotReversed,      
      
      /* Contact Card */
      _CreatedByContact,
      _ChangedByContact,
      
      /* Associations */
      //_BusinessPartner2,

      _CAPaymentOrderStatus,
      _CAPaymentOrderStatusEnhanced,
      _CAPaymentDocument,
      _CompanyCode,
      _CAPaymentMethod,
      _HouseBank,
      _HouseBankAccount,
      _CAClearingDocument,
      _CAPaymentOrderItem : redirected to composition child C_CAPaymentOrderItem,
      _PaymentCardType
}