@ObjectModel: { usageType: { dataClass: #TRANSACTIONAL,
sizeCategory: #L,
serviceQuality: #C },
query: { implementedBy: 'ABAP:CL_FICA_DM_QRY_NOT_DIS_INV_DOC' }
}
@AccessControl: { authorizationCheck: #CHECK,
personalData.blocking: #REQUIRED
}
@Metadata: { allowExtensions: true }
@EndUserText.label: 'Not disputed invoicing document'
@VDM.viewType: #CONSUMPTION
/*Fields shoud be identical to C_CADisputedInvcgDocDraftTP otherwise Include action doesn't work*/
define view entity C_CANotDisputedInvcgDoc as select from I_CAInvcgDocHeader as _CAInvcgDocHeader
{
//INVDOCNO
@UI.lineItem: [ { position: 10, importance: #HIGH }]
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAInvcgDocVH', element: 'CAInvoicingDocument' }}]
key _CAInvcgDocHeader.CAInvoicingDocument,
@UI.hidden: true
cast('' as sysuuid_c ) as CaseUUID,
//EXBEL
@UI.hidden: true
_CAInvcgDocHeader.CAOfficialDocumentNumber,
@UI.hidden: true
_CAInvcgDocHeader._BusinessPartner.FirstName,
@UI.hidden: true
_CAInvcgDocHeader._BusinessPartner.LastName,
@UI.hidden: true
@Semantics: { name.givenName: true , contact.type: #PERSON }
_CAInvcgDocHeader._BusinessPartner.BusinessPartnerFullName,
@UI.hidden: true
cast( concat_with_space(_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.StreetName,
_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.HouseNumber, 1)
as adress_gfn_kk preserving type ) as StreetName,
@UI.hidden: true
cast( concat_with_space(_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
_CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.CityName, 1)
as city_gfn_kk preserving type ) as AddressCityName,
@UI.hidden: true
cast( _CAInvcgDocHeader._BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation._Country._Text[1: Language=$session.system_language].CountryName
as country_gfn_kk preserving type ) as CountryName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner' }}]
@Consumption.semanticObject: 'CAContractPartner'
@ObjectModel.text.element: [ 'BusinessPartnerFullName' ]
_CAInvcgDocHeader.BusinessPartner,
//VKONT
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount' }}]
@Consumption.semanticObject: 'ContractAccount'
@ObjectModel.text.element: [ 'ContractAccountName' ]
_CAInvcgDocHeader.ContractAccount,
@UI.hidden: true
_CAInvcgDocHeader._ContractAccountHeader.ContractAccountName,
//INV_TYPE
@UI.lineItem: [{ position: 20, importance: #HIGH }]
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CAINVCGTYPEVH', element: 'CAInvcgType' }}]
@ObjectModel.text.element: [ 'CAInvcgTypeText' ]
_CAInvcgDocHeader.CAInvcgType,
//INVPERIOD
@UI.lineItem: [{ position: 30, importance: #HIGH }]
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CAInvcgDocPeriodDate,
//BLDAT
@UI: {
lineItem: [ { position: 40, importance: #HIGH } ]
}
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.DocumentDate,
//Amount and Currency
_CAInvcgDocHeader.TransactionCurrency,
@UI.lineItem: [{ position: 50, importance: #HIGH }]
_CAInvcgDocHeader.CAAmountInTransactionCurrency,
//INV_PROCESS
@ObjectModel.text.element: ['CAInvcgProcessText']
_CAInvcgDocHeader.CAInvcgProcess,
//DOCTYPE
@ObjectModel.text.element: ['CAInvcgDocumentTypeText']
_CAInvcgDocHeader.CAInvcgDocumentType,
//MAZAE
_CAInvcgDocHeader.CADunningCounter,
//CFCSIMULATED
_CAInvcgDocHeader.CAInvcgDocHasControlDoc,
//FORMKEY
_CAInvcgDocHeader.ApplicationForm,
//PRINTDATE
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CAInvcgDocumentPrintDate,
//PRINTLOCK
@ObjectModel.text.element: ['CAInvcgDocLockedForPrintText']
_CAInvcgDocHeader.CAInvcgDocIsLockedForPrinting,
//FAEDN - Due date for net payment
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CANetDueDate,
//REVREASON - Reversal Reason
@ObjectModel.text.element: ['CAInvcgDocReversalReasonText']
_CAInvcgDocHeader.CAInvcgDocumentReversalReason,
//INVOICED
_CAInvcgDocHeader.CAInvcgIsDocumentPosted,
//PRELIMINARY
_CAInvcgDocHeader.CAInvcgIsDocumentPreliminary,
//SIMULATED
_CAInvcgDocHeader.CAInvcgIsDocumentSimulated,
//BUDAT
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CAPostingDate,
//APPLK
_CAInvcgDocHeader.CAApplicationArea,
//TECHDOCTYPE
@ObjectModel.text.element: ['CAInvcgDocTechDocTypeText']
_CAInvcgDocHeader.CAInvcgTechnicalDocumentType,
//TARGPROCESS
@ObjectModel.text.element: ['CAInvcgTargetProcText']
_CAInvcgDocHeader.CAInvcgTargetProcess,
//MDCAT
@ObjectModel.text.element: ['CAInvcgMasterDataTypeText']
_CAInvcgDocHeader.CAInvcgMasterDataType,
//ABWVK
@Consumption.semanticObject: 'ContractAccount'
_CAInvcgDocHeader.AltvContractAcctForCollvBills,
//ABWBL
_CAInvcgDocHeader.CASubstituteDocumentNumber,
//CRNAME
@UI.hidden: true
_CAInvcgDocHeader.CreatedByUser,
//CRDATE
@UI.hidden
_CAInvcgDocHeader.CAInvcgCreationDate,
//CRTIME
@UI.hidden
_CAInvcgDocHeader.CAInvcgCreationTime,
@Semantics.dateTime: true
@Consumption.filter.selectionType: #INTERVAL
cast(dats_tims_to_tstmp(CAInvcgCreationDate,
CAInvcgCreationTime,
abap_system_timezone($session.client, 'NULL'),
$session.client, 'NULL') as invdoc_crtsmp_kk) as CAInvcgCreationDateTime,
//CRMODE
@ObjectModel.text.element: ['CAInvcgDocCreationModeText']
_CAInvcgDocHeader.CAInvcgDocCreationMode,
//RECNUM
_CAInvcgDocHeader.CAInvcgNmbrOfInvoicingDocItems,
//INVRUNNO
_CAInvcgDocHeader.CAInvcgDocInternalNumber,
//FIKEY
@Consumption.semanticObject: 'CAReconciliationKey'
_CAInvcgDocHeader.CAReconciliationKey,
//FAEDS
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CACashDiscountDueDate,
//SKTPZ
_CAInvcgDocHeader.CACashDiscountRate,
//PRLINV_CAT
_CAInvcgDocHeader.CAInvcgPreliminaryCategory,
//PRLINV_CNT
_CAInvcgDocHeader.CAPrelimInvcgDocValue,
//PRLINV_STATUS
_CAInvcgDocHeader.CAPreliminaryInvcgDocStatus,
//INV_CATEGORY
@ObjectModel.text.element: ['CAInvcgCategoryText']
_CAInvcgDocHeader.CAInvcgCategory,
//REVERSALDOC
// @Consumption.semanticObject: 'CAInvoicingDocument'
_CAInvcgDocHeader.CAInvcgReversalDocument,
//REVERSEDDOC
// @Consumption.semanticObject: 'CAInvoicingDocument'
_CAInvcgDocHeader.CAInvcgReversedDocument,
//CORRCAT
@ObjectModel.text.element: ['CAInvcgCorrectionCatText']
_CAInvcgDocHeader.CAInvcgCorrectionCategory,
//PYMET
_CAInvcgDocHeader.CAPaymentMethod,
//NRZAS
_CAInvcgDocHeader.CAPaymentFormNumber,
//ZLSCH
_CAInvcgDocHeader.FormIDForAttachedPaymentMedium,
//EXKID
_CAInvcgDocHeader.CAKeyIdentification,
//PTSRL
_CAInvcgDocHeader.CAPartnerSettlementRule,
//BUKRS
@ObjectModel.text.element: ['CompanyCodeName']
@Consumption.semanticObject: 'CompanyCode'
_CAInvcgDocHeader.CompanyCode,
//BUPLA
_CAInvcgDocHeader.BusinessPlace,
//VTREF
@ObjectModel.text.element: [ 'CAProviderContractName' ]
@Consumption.semanticObject: 'CAProviderContract'
@Consumption.valueHelpDefinition: [{entity: { name: 'D_CAContractCVH', element: 'CAContract'}}]
_CAInvcgDocHeader.CAContract,
@Semantics.text: true
@UI.hidden: true
cast(_ProviderContract.CAProviderContractName as vtref_text_gfn_kk preserving type ) as CAProviderContractName,
//SUBAP
@ObjectModel.text.element: ['CASubApplicationText']
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CASubApplicationVH', element: 'CASubApplication'}}]
@UI.textArrangement: #TEXT_ONLY
_CAInvcgDocHeader.CASubApplication,
@Semantics.text: true
@UI.hidden: true
cast(_CASubApplication._CASubApplicationText[1: Language=$session.system_language].CASubApplicationText as subap_text_gfn_kk preserving type ) as CASubApplicationText,
//INVOICE_BASEDATE
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CAInvcgBaseDate,
//INVPERCAT
@ObjectModel.text.element: ['CAInvcgPeriodCatText']
_CAInvcgDocHeader.CAInvcgDocPeriodCategory,
//INVPERIOD
@Consumption.filter.selectionType: #INTERVAL
_CAInvcgDocHeader.CAInvcgDocPeriodStartDate,
//CHGDOC_EX
@ObjectModel.text.element: ['CAInvcgDocChrgDiscItemsText']
_CAInvcgDocHeader.CAInvcgDocHasChargeOrDiscItems,
//BOLLOTAX
@ObjectModel.text.element: ['CAInvcgBolloTaxPostStatText']
_CAInvcgDocHeader.CAInvcgBolloTaxPostStatus,
//XSUBINV
@ObjectModel.text.element: ['CAInvcgDocPartOfListText']
_CAInvcgDocHeader.CAInvcgDocIsPartOfList,
//XINVDOC_X
_CAInvcgDocHeader.CAInvcgDocHasObjectRelation,
//SEPA_PRENOT
_CAInvcgDocHeader.CAInvcgDocHasSEPAPreNotif,
//EXT_INVDOCNO
_CAInvcgDocHeader.CAInvcgDocExternal,
@UI.hidden: true
_CAInvcgDocHeader._ContractAccountPartner._CompCodeGroup._CompanyCode.Country as CAPaymentCompanyCodeCountry,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocumentType._CAInvcgDocumentTypeText[1: Language=$session.system_language].CAInvcgDocumentTypeText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgProcess._CAInvcgProcessText[1: Language=$session.system_language].CAInvcgProcessText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgType._CAInvcgTypeText[1: Language=$session.system_language].CAInvcgTypeText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgCategory._CAInvcgCategoryText[1: Language=$session.system_language].CAInvcgCategoryText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText[1: Language=$session.system_language].CAInvcgDocTechDocTypeText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgTargetProc._CAInvcgTargetProcText[1: Language=$session.system_language].CAInvcgTargetProcText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgMasterDataType._CAInvcgMasterDataTypeText[1: Language=$session.system_language].CAInvcgMasterDataTypeText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocCreationMode._CAInvcgDocCreationModeText[1: Language=$session.system_language].CAInvcgDocCreationModeText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgPreliminaryCategory._Text[1: Language=$session.system_language].CAInvcgPreliminaryCategoryTxt,
@UI.hidden: true
_CAInvcgDocHeader._CAPreliminaryInvcgDocStatus._Text[1: Language=$session.system_language].CAPreliminaryInvcgDocStatusTxt,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocReversalReason._CAInvcgDocReversalReasonText[1: Language=$session.system_language].CAInvcgDocReversalReasonText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgCorrectionCat._CAInvcgCorrectionCatText[1: Language=$session.system_language].CAInvcgCorrectionCatText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocLockedforPrint._CAInvcgDocLockedForPrintText[1: Language=$session.system_language].CAInvcgDocLockedForPrintText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgPeriodCat._CAInvcgPeriodCatText[1: Language=$session.system_language].CAInvcgPeriodCatText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocChrgDiscItems._CAInvcgDocChrgDiscItemsText[1: Language=$session.system_language].CAInvcgDocChrgDiscItemsText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgBolloTaxPostStatus._CAInvcgBolloTaxPostStatText[1: Language=$session.system_language].CAInvcgBolloTaxPostStatText,
@UI.hidden: true
_CAInvcgDocHeader._CAInvcgDocPartOfList._CAInvcgDocPartOfListText[1: Language=$session.system_language].CAInvcgDocPartOfListText,
@UI.hidden: true
_CAInvcgDocHeader._CompanyCode.CompanyCodeName,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
_ContractAccountHeader,
@ObjectModel.filter.enabled: false
@ObjectModel.sort.enabled: false
_ContractAccountPartner
}