C_CANotDisputedDocument

@AbapCatalog: { sqlViewName: 'CCANOTDISDOC',
                compiler: { compareFilter: true },
                preserveKey: true }
@ObjectModel: { usageType:         { dataClass: #TRANSACTIONAL,
                                     sizeCategory: #L,
                                     serviceQuality: #C } ,
                query: { implementedBy: 'ABAP:CL_FICA_DM_QRY_NOT_DIS_DOC' }
              }            
@AccessControl: { authorizationCheck: #CHECK,
                  personalData.blocking: #REQUIRED 
                }
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@Metadata: { allowExtensions: true }
@EndUserText.label: 'Not Disputed Document'
@UI: {
    presentationVariant: [
      { 
        requestAtLeast:  [
          'TransactionCurrency',
          //'CreationDate',

          //'CreationTime',

          'CreationDateTime',
          'CAAmountInTransactionCurrency'     
        ] 
      }
    ]
}
define view C_CANotDisputedDocument as select from I_CANotDisputedDocument as _NotDisputedDoc
  association [0..*] to C_CANotDisputedDocumentItem as _DocumentItem on $projection.CADocumentNumber = _DocumentItem.CADocumentNumber           
{
   @UI: {
      lineItem: {  position:5, importance: #HIGH },
      dataPoint: { title: 'Document Number' }
   }
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentHeaderValueHelp', element: 'CADocumentNumber'}}]
   key _NotDisputedDoc.CADocumentNumber,
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
   @UI.hidden: true
   key _NotDisputedDoc.BusinessPartner,
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount'}}]
   @UI.hidden: true
   key _NotDisputedDoc.ContractAccount,   
   @UI: {
      lineItem: {  position:15, importance: #HIGH }
   }    
   @ObjectModel: { text.element:  [ 'CAMainTransactionName' ] }
   @UI.textArrangement: #TEXT_FIRST
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAMainTransactionValueHelp', element: 'CAMainTransaction'}}]
   key _NotDisputedDoc.CAMainTransaction,
   @UI: {
      lineItem: {  position:20, importance: #HIGH }
   }  
   @ObjectModel: { text.element:  [ 'CASubTransactionName' ] }
   @UI.textArrangement: #TEXT_FIRST
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CASubTransactionValueHelp', element: 'CASubTransaction'}}]
   key _NotDisputedDoc.CASubTransaction,
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAClearingReasonValueHelp', element: 'CAClearingReason'}}]   
   @UI: {
      lineItem: {  position:40, importance: #HIGH }
   }
   @ObjectModel.text.element: ['CAClearingReasonName']   
   key _NotDisputedDoc.CAClearingReason,
   @UI.hidden: true
   cast('' as sysuuid_c ) as CaseUUID, 
   @UI: {
      lineItem: {  position:50, importance: #HIGH },
      dataPoint: { title: 'Amount' }
   }     
   @Semantics.amount.currencyCode: 'TransactionCurrency'
   _NotDisputedDoc.CAAmountInTransactionCurrency, 
   @Semantics.currencyCode: true 
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CurrencyValueHelp', element: 'Currency'}}]
   _NotDisputedDoc.TransactionCurrency,
   @UI: {
      lineItem: {  position:25, importance: #HIGH }
   }    
   @Consumption.filter.selectionType: #INTERVAL
   _NotDisputedDoc.CANetDueDate,
   @UI: {
      lineItem: {  position:30, importance: #HIGH }
   }      
   @Consumption.filter.selectionType: #INTERVAL
   _NotDisputedDoc.CADeferralDate,
   @UI: {
      lineItem: {  position:35, importance: #HIGH }
   }      
   @Consumption.filter.selectionType: #INTERVAL
   _NotDisputedDoc.CAClearingDate,
   @UI.hidden
   @Semantics.text: true
   _NotDisputedDoc.CAClearingReasonName, 
   @Semantics.amount.currencyCode: 'TransactionCurrency' 
   @UI: {
      lineItem: {  position:45, importance: #HIGH },
      dataPoint: { title: 'Open Amount' }
   }    
   _NotDisputedDoc.OpenAmountInTransCrcy,
   @UI.hidden
   _NotDisputedDoc.CAMainTransactionName,
   @UI.hidden
   _NotDisputedDoc.CASubTransactionName,
   
   @UI.hidden: true
   _NotDisputedDoc.CAContract,
   
   @UI.hidden: true
   _NotDisputedDoc.CASubApplication,
   
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CACompanyCodeVH', element: 'CompanyCode'}}]
   @UI.hidden
   _NotDisputedDoc.CompanyCode,
   @UI.hidden
   _NotDisputedDoc.CreationDate, 
   @UI.hidden
   _NotDisputedDoc.CreationTime,
   @Semantics.dateTime: true
   @Consumption.filter.selectionType: #INTERVAL
   CreationDateTime,
   @Consumption.filter.selectionType: #INTERVAL
   _NotDisputedDoc.CAPostingDate,
   _NotDisputedDoc.CAReferenceDocument,
   @EndUserText.label: 'Reference Procedure'
   _NotDisputedDoc.ReferenceDocumentType,
   @EndUserText.label: 'Document Type'
   _NotDisputedDoc.CADocumentTypeName,
   @Consumption.filter.selectionType: #INTERVAL
   _NotDisputedDoc.DocumentDate,
   @Consumption.valueHelpDefinition: [{entity: { name: 'I_CAReconciliationKeyVH', element: 'CAReconciliationKey'}}]
   _NotDisputedDoc.CAReconciliationKey,
   @Semantics.text: true
   @UI.hidden
   _NotDisputedDoc.CADocumentOriginCodeName,
   @ObjectModel: { text.element:  [ 'CreatedByUserName' ] }
   _NotDisputedDoc.CreatedByUser,
   @UI.hidden: true
   CreatedByUserName,
   @Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentOriginCodeVH', element: 'CADocumentOriginCode'}}] 
   @ObjectModel.text.element: ['CADocumentOriginCodeName']  
   _NotDisputedDoc.CADocumentOriginCode,
    @UI.hidden: true
   _NotDisputedDoc.CAReversalDocumentNumber,
    @UI.hidden: true
   _NotDisputedDoc.CAReversedDocumentNumber,
   @UI.hidden: true
   _NotDisputedDoc.CAAuthorizationGroup,
   @ObjectModel.filter.enabled: false
   _DocumentItem
}