C_CADocumentGLItemTP

@EndUserText.label: 'Contr Acctg General Ledger Item'

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.auditFilter: #ENABLED
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C

@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

@Metadata.allowExtensions: true
define view entity C_CADocumentGLItemTP
  as projection on R_CADocumentGLItemTP as ContrAcctgDocumentGenLdgrItem
{
  key     CADocumentNumber,
  key     CAGLItemNumber,
  
          @ObjectModel.text.element: [ 'CompanyCodeName' ]
          CompanyCode,
          @Semantics.text: true
          _CompanyCode.CompanyCodeName,
          
          @ObjectModel.text.element: [ 'BusinessAreaName' ]
          BusinessArea,
          @Semantics.text: true
          _BusinessArea._Text[1:Language=$session.system_language].BusinessAreaName,
          
         
          BusinessPlace,
          
          @ObjectModel.text.element: [ 'SegmentName' ]
          Segment,
          @Semantics.text: true
          _Segment._Text[1:Language=$session.system_language].SegmentName,
          
          ProfitCenter,
          
          @ObjectModel.text.element: [ 'CompanyName' ]
          PartnerCompany,
          @Semantics.text: true
          _PartnerCompany.CompanyName,
          
          @ObjectModel.text.element: [ 'GLAccountName' ]
          GLAccount,
          @Semantics.text: true
          _GLAccount._Text[1:Language=$session.system_language].GLAccountName,
          
          ValueDate,
          CAExchangeRate,
          ExchRateIsIndirectQuotation,
          TransactionCurrency,
          Currency,
          CAAmountInLocalCurrency,
          CAAmountInTransactionCurrency,
          CAAmountInSecondCurrency,
          CAAmountInThirdCurrency,
          
          @ObjectModel.text.element: [ 'CAAccountAssignmentCatName' ]
          CAAccountAssignmentCategory,
          @Semantics.text: true
          _CAAccountAssignmentCategory._Text[1:Language=$session.system_language].CAAccountAssignmentCatName,
          
          CAAccountAssignment,
          CostCenter,
          SalesOrder,
          SalesOrderItem,
          CAReconciliationKey,
          
          @ObjectModel.text.element: [ 'CAInternalPostingReasonCodeTxt' ]
          CAInternalPostingReasonCode,
          @Semantics.text: true
          _CAIntPostingReasonCode._Text[1:Language=$session.system_language].CAInternalPostingReasonCodeTxt,
          
          @ObjectModel.text.element: [ 'CANegativePostingCtrlCodeText' ]
          CANegativePostingControlCode,
          @Semantics.text: true
          _CANegativePostingCtrlCode._Text[1:Language=$session.system_language].CANegativePostingCtrlCodeText,
          
          CAGLPostingCurrency,
          LedgerGroup,
          ProfitabilitySegment_2,
          ProfitabilitySegmentChanges,
          PlanningLevel,
          CARepetitionGroup,
          CATransactionKeyAccountDetn,
          ConditionType,
          CAIsSeparateLineItemInGL,
          BaseUnit,
          TaxCode,
          CASupplementaryTaxCode,
          CAWithholdingTaxSupplement,
          
          @ObjectModel.text.element: [ 'CANegativePostingCtrlCodeText' ]
          CAOtherTaxCode,
          @Semantics.text: true
          _CAOtherTaxCode._Text[1:Language=$session.system_language].CAOtherTaxCodeName,
          
          CAGroupingCodeForTaxItems,
          TaxJurisdiction,
          CAEnteredTaxJurisdictionCode,
          CATaxJurisdictionLevelCounter,
          CATaxExceptionID,
          CATaxDate,
          CATaxBaseAmountInLocalCurrency,
          CATaxBaseAmount,
          CANonDeductibleTxAmtInDocCrcy,
          CANonDeductibleTxAmtInLoclCrcy,
          CAContainsNonDeductibleInptTax,
          CATaxRate,
          GrossIncomeTaxActivityCode,
          EmploymentTaxDistributionType,
          CATaxPortionInLocalCurrency,
          CATaxPortionInTransCurrency,
          CATaxIsCalculatedExternally,
          CAAltvExchangeRateSetCode,
          CAIsCashFlowItem,
          CACashFlowAccount,
          
          @ObjectModel.text.element: [ 'CACashFlowCompanyCodeName' ]
          CACashFlowCompanyCode,
          _CashFlowCompanyCode.CompanyCodeName as CACashFlowCompanyCodeName,
          HouseBank,
          HouseBankAccount,
          QuantitySignCode,
          BankStatementShortID,
          BankStatementItem,
          CashManagementLinkType,
          CashManagementLink,
          CAItmIsCreatedByPostgInterface,
          CAStatusOfEuroConversion,
          CAProfitAnalysisUpdtIsDirect,
          CAInvcgGroupingKey,
          CACtrlFieldForAcctAssgmtDistr,
          CAUpdateMethodForFundsMgmt,
          OriginalFinancialMgmtArea,
          OriglYearForFinMgmtAcctAssgmt,
          EarmarkedFundsDocument,
          ChartOfAccounts,
          Country,
          TaxCalculationProcedure,
          WBSElementInternalID,
          @ObjectModel.text.element: [ 'WBSDescription' ]
          _WBSElementBasicData.WBSElementExternalID,
          @Semantics.text: true
          _WBSElementBasicData.WBSDescription,
  
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_GLITEM_EXIT'
  virtual CADocumentGLItemLongDesc : opdesc_kk,


          _DocHeader.CAPostingDate,
          _DocHeader.CADocumentType,
          _DocHeader.CAReferenceDocument,
          _DocHeader._CADocumentType._Text[1:Language=$session.system_language].CADocumentTypeName,

          /* Associations */
          _BusinessArea,
          _CAAccountAssignmentCategory,
          _CAOtherTaxCode,
          _CashFlowAccount,
          _CashFlowCompanyCode,
          _CAWithholdingTaxSupplement,
          _ChartOfAccounts,
          _CompanyCode,
          _Country,
          _DocHeader : redirected to parent C_CADocumentTP,
          _GLAccount,
          _GLPostingCurrency,
          _PartnerCompany,
          _ProfitCenter,
          _Segment,
          _WBSElementBasicData
}