C_CADocumentBPItemTP

@EndUserText.label: 'Contr Acct Business Partner Item'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.auditFilter: #ENABLED
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.semanticKey: ['CADocumentNumber', 'CARepetitionItemNumber', 'CABPItemNumber', 'CASubItemNumber']

@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

@Metadata.allowExtensions: true
define view entity C_CADocumentBPItemTP
  as projection on R_CADocumentBPItemTP as ContrAcctgDocumentBusPartItem

  association [1..1] to C_CADocBPItemClrgProcData      as _ClearingData on  $projection.CADocumentNumber       = _ClearingData.CADocumentNumber
                                                                        and $projection.CARepetitionItemNumber = _ClearingData.CARepetitionItemNumber
                                                                        and $projection.CABPItemNumber         = _ClearingData.CABPItemNumber
                                                                        and $projection.CASubItemNumber        = _ClearingData.CASubItemNumber

  association [0..*] to C_CADocumentBPItemBusLockEnhcd as _BusLock      on  $projection.CADocumentNumber       = _BusLock.CADocumentNumber
                                                                        and $projection.CABPItemNumber         = _BusLock.CABPItemNumber
                                                                        and $projection.CARepetitionItemNumber = _BusLock.CARepetitionItemNumber
                                                                        and $projection.CASubItemNumber        = _BusLock.CASubItemNumber

  association [0..*] to C_CADocumentIssue              as _DocIssue     on  (
          _DocIssue.CADocumentIssueType                                                                          = '03'
          and $projection.CADocumentNumber                                                                       = _DocIssue.CADocumentNumber
        )
                                                                        or  (
                                                                            _DocIssue.CADocumentIssueType        = '01'
                                                                            and _DocIssue.CADocumentNumber       = $projection.CADocumentNumber
                                                                            and _DocIssue.CARepetitionItemNumber = $projection.CARepetitionItemNumber
                                                                            and _DocIssue.CABPItemNumber         = $projection.CABPItemNumber
                                                                            and _DocIssue.CASubItemNumber        = $projection.CASubItemNumber
                                                                          )
                                                                          
                                                                         
{
  key     CADocumentNumber,
  key     CARepetitionItemNumber,
  key     CABPItemNumber,
  key     CASubItemNumber,


          @ObjectModel.text.element: ['CompanyCodeName']
          CompanyCode,
          @Semantics.text: true
          _CompanyCode.CompanyCodeName,

          BusinessArea,
          BusinessPlace,
          Segment,
          ProfitCenter,
          Division,
          PersonnelNumber,
          PartnerCompany,
          @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
          @ObjectModel.foreignKey.association: '_BusinessPartner'
          @ObjectModel.text.element: ['BusinessPartnerFullName']
          BusinessPartner,
          @UI.hidden: true
          _BusinessPartner.BusinessPartnerFullName,
           
          @ObjectModel.text.element: [ 'CAProviderContractName' ]
          CAContract,
          
          @Semantics.text: true
          cast(_ProviderContract.CAProviderContractName as vtref_text_gfn_kk preserving type )   as CAProviderContractName,

          CAProviderContractItemNumber,
          CAAdditionalContract,

          @ObjectModel.text.element: ['ContractAccountName']
          ContractAccount,
          @Semantics.text: true
          _CAPartner.ContractAccountName,

          @ObjectModel.text.element: ['CASubApplicationText']
          CASubApplication,
          
          @Semantics.text: true
          cast(_CASubApplication._CASubApplicationText[1: Language=$session.system_language].CASubApplicationText as subap_text_gfn_kk preserving type ) as CASubApplicationText,
          
          AltvContractAcctForCollvBills,
          CAReconciliationAccount,
          CAApplicationArea,
          @ObjectModel.foreignKey.association: '_CAMainTransaction'
          CAMainTransaction,
          @ObjectModel.foreignKey.association: '_CASubTransaction'
          CASubTransaction,
          CAAccountDeterminationCode,
          CADoubtfulOrValueAdjmtCode,
          CAAccountAssignmentCategory,
          CAAccountAssignment,
          @ObjectModel.foreignKey.association: '_CADocumentType'
          @ObjectModel.text.element: ['CADocumentTypeName']
          CADocumentType,
          _CADocumentType._Text[1:Language=$session.system_language].CADocumentTypeName,
          CAIsDownPaymentRequest,
          CAItemIsOnlyForSettlement,
          CAStatisticalItemCode,
          CABPItemText,
          CANumberOfRepetitionItems,
          CARepetitionGroup,
          CAStartDateOfBillingPeriod,
          CAEndDateOfBillingPeriod,
          CAGroupingCodeForBPItems,
          CAPeriodCode,
          CAChangeIsForbidden,
          CAInterestCode,
          CARoundingItemCode,
          CAReceivingCountry,
          CAInternalPostingReasonCode,
          CAWorkflowCheckReason,
          CAWorkflowCheckProcess,
          CANegativePostingControlCode,
          CAPartnerSettlementStatus,
          CAIsPartOfJointLiability,
          CASubstituteDocumentNumber,
          CASubstituteDocumentCategory,
          CAStatisticalCodeOfOriginItem,
          CADocumentNumberOfOriginItem,
          CAReferenceDocument,
          DocumentDate,
          CAPostingDate,
          CANetDueDate,
          CADeferralDate,
          TransactionCurrency,
          CompanyCodeCurrency,
          AdditionalCurrency1,
          AdditionalCurrency2,
          CAExchangeRate,
          ExchRateIsIndirectQuotation,
          CAAmountInLocalCurrency,
          CAAmountInTransactionCurrency,
          CAAmountInSecondCurrency,
          CAAmountInThirdCurrency,
          CACashDiscountDueDate,
          CACashDiscountRate,
          CAEligibleAmountForCshDiscount,
          CACashDiscAmountInClearingCrcy,
          TaxCode,
          CASupplementaryTaxCode,
          CATaxAmountInLocalCurrency,
          CATaxAmountInTransCurrency,
          CATaxAmountInSecondCurrency,
          CATaxAmountInThirdCurrency,
          CADownPaymentTaxAccount,
          CADownPaymentOffsetTaxAccount,
          TaxJurisdiction,
          CATaxDate,
          WithholdingTaxCode,
          CAWithholdingTaxSupplement,
          CAWithholdingTaxCategory,
          CABaseAmountForWithholdingTax,
          CAWithholdingTaxAmount,
          CAWithholdingTaxPercentage,
          WithholdingTaxCertificate,
          CAOtherTaxCode,
          CAGroupingCodeForTaxItems,
          CATaxPortionInLocalCurrency,
          CATaxPortionInTransCurrency,
          CATaxIsCalculatedExternally,

          CAPaymentMethod,
          CAPaymentCompanyCode,
          CAGroupingForPayment,
          CAPaymentSpecificationCategory,

          @ObjectModel.foreignKey.association: '_CAClearingStatus'
          CAClearingStatus,
          CAClearingDate,
          CAClearingDocumentNumber,
          CAPostingDateOfClearingDoc,

          CAClearingReason,
          CAClearingCurrency,
          CAClearingAmountInClearingCrcy,
          CATaxAmountInClearingCrcy,
          CAValueDateForClearing,
          CAClearingRestrictionCode,
          CAClearingPostingIsReset,
          CAItemIsWithdrawn,
          CAItemIsExcludedFromDunning,
          CADunningProcedure,
          CAGrpgCodeForTransfToCollAgcy,
          CAIsIncludedInCollectionCase,
          CashPlanningGroup,
          PlanningLevel,
          CAAdditionalDaysForCashMgmt,
          PlannedAmtInTransactionCrcy,
          CAAltvBPForPayment,
          CABankOfAltvBPForPayment,
          CAAddressOfAltvBPForPayment,
          CACardOfAltvBPForPayment,
          CAGLPostingCurrency,
          CAGLPostingAmount,
          CAGLPostingTaxAmount,
          CAIsSeparateLineItemInGL,
          CAIsCashFlowItem,
          CACashFlowAccount,
          CACashFlowCompanyCode,
          CAPaymentPreNotificationCode,
          CASEPAPreNotificationNumber,
          CASEPAPreNotifOriginCode,
          CASEPAPreNotifExecutionDate,
          CASEPAPreNotificationRqmtCode,
          CARevenueDistrFinalRecipient,
          CARevenueDistrCurrentStatus,
          CARevenueDistrLastStatus,
          CACurrentFactoringStatusOfRbl,
          CAFactoringCheckStsForClrgInfo,
          SEPAMandateCAInternalID,
          ChartOfAccounts,
          ControllingArea,
          Country,

          @ObjectModel.text.element: [ 'CADocumentOriginCodeName' ]
          CADocumentOriginCode,
          @Semantics.text: true
          _CADocumentOriginCode._Text.CADocumentOriginCodeName : localized,

          _CASubTransaction._Text[1:Language=$session.system_language].CASubTransactionName,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CADocumentBPItemLongDesc       : opdesc_kk,
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CADocumentBPItemShortDesc      : opdesc_kk,
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CADocumentBPItemNavigationDesc : opdesc_kk,
          @UI.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual UICT_HideDisputeCreationButton : boole_d,
          @UI.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CAContractSemanticObject       : vtref_semobj_kk,
          @UI.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual UICT_HidePaymentMethodFacet    : boole_d,

          @ObjectModel.text.element: [ 'CAClearingInformationText' ]
          _DocHeader.CAClearingInformation,
          @Semantics.text: true
          _DocHeader._CAClearingInformation._Text.CAClearingInformationText : localized,
          _DocHeader.CreationDateTime,
          _DocHeader.CAReconciliationKey,
          _DocHeader.CAReversalDocumentNumber,

          /* Associations */
          _BPItemBusLock,
          _DocHeader : redirected to parent C_CADocumentTP,
          _BusLock,
          _DocIssue,
          @ObjectModel.sort.enabled: false
          @ObjectModel.filter.enabled: false
          _ClearingData,

          _AdditionalCurrency1,
          _AdditionalCurrency2,
          _BusinessArea,
          _BusinessPartner,
          _CAAccountAssignmentCategory,
          _CAAccountDeterminationCode,
          _CAApplicationArea,
          _CAClearingDocument,
          _CAClearingReason,
          _CAClearingRestrictionCode,
          _CAClearingStatus,
          _CADbtflOrValueAdjmtCode,
          _CADocument,
          _CADocumentType,
          _CADunningProcedure,
          _CAFactoringClrgCheckStatus,
          _CAFactoringReceivableStatus,
          _CAInterestCode,
          _CAInternalPostingReasonCode,
          _CAMainTransaction,
          _CANegativePostingControlCode,
          _CAOriginDocument,
          _CAOriglStatisticalItemCode,
          _CAOtherTaxCode,
          _CAPartner,
          _CAPartnerSettlementStatus,
          _CAPaymentMethod,
          _CAPaytPreNotificationCode,
          _CAPaytSpecificationCategory,
          _CAPeriodCode,
          _CARevenueDistrCurrentStatus,
          _CARevenueDistrLastStatus,
          _CARoundingItemCode,
          _CASEPAPreNotificationRqmtCode,
          _CASEPAPreNotifOriginCode,
          _CashFlowAccount,
          _CashFlowCompanyCode,
          _CashPlanningGroup,
          _CAStatisticalItemCode,
          _CASubApplication,
          _CASubstituteDocumentCategory,
          _CASubstituteDocument,
          _CASubTransaction,
          _CAWithholdingTaxCategory,
          _CAWithholdingTaxSupplement,
          _CAWorkflowCheckProcess,
          _CAWorkflowCheckReason,
          _ClearingCurrency,
          _CollvBillsAltvContractAccount,
          _CompanyCode,
          _CompanyCodeCurrency,
          _ContractAccount,
          _ControllingArea,
          _ChartOfAccounts,
          _Country,
          _Division,
          _DownPaymentOffsetTaxAccount,
          _DownPaymentTaxAccount,
          _GLPostingCurrency,
          _PartnerCompany,
          _PaytAltvBusinessPartner,
          _PlanningLevel,
          _PaymentCompanyCode,
          _ProfitCenter,
          _ProviderContract,
          _ReceivingCountry,
          _ReconciliationAccount,
          _RevnDistrFnlRcpntContrAccount,
          _Segment,
          _TransactionCurrency,
          _WithholdingTaxCode
}