C_BkRelshpDocAcctSelectionTP

DDL: C_BKRELSHPDOCACCTSELECTIONTP Type: view_entity CONSUMPTION Package: FCLM_BRM_DOC

Bank Account Selections of Bank Doc

C_BkRelshpDocAcctSelectionTP is a Consumption CDS View that provides data about "Bank Account Selections of Bank Doc" in SAP S/4HANA. It reads from 1 data source (R_BkRelshpDocAcctSelectionTP) and exposes 18 fields with key fields BkRltnDocBkAcctSelectionUUID, BankRelationshipDocumentUUID. It is exposed through 1 OData service (UI_BANKRELATIONSHIPDOC). Part of development package FCLM_BRM_DOC.

1 data source(s) Exposed by 1 service(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
R_BkRelshpDocAcctSelectionTP R_BkRelshpDocAcctSelectionTP projection

Annotations (9)

NameValueLevelField
EndUserText.label Bank Account Selections of Bank Doc view
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MASTER view
VDM.viewType #CONSUMPTION view
Search.searchable true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_BANKRELATIONSHIPDOC UI_BANKRELATIONSHIPDOC_O4 V4 C1 NOT_RELEASED

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY BkRltnDocBkAcctSelectionUUID BkRltnDocBkAcctSelectionUUID
KEY BankRelationshipDocumentUUID BankRelationshipDocumentUUID
BkRltnDocBkAcctSelectionField BkRltnDocBkAcctSelectionField
BkRltnDocBkAcctSelectionSign BkRltnDocBkAcctSelectionSign
BkRltnDocBkAcctSelectionOption BkRltnDocBkAcctSelectionOption
BkRltnDocBkAcctSelLowValue BkRltnDocBkAcctSelLowValue Value
BkRltnDocBkAcctSelHighValue BkRltnDocBkAcctSelHighValue
CreatedByUser CreatedByUser
CreationDateTime CreationDateTime
LastChangedByUser LastChangedByUser
LocalLastChangeDateTime LocalLastChangeDateTime
SelectionFieldIsCurrency SelectionFieldIsCurrency
SelectionFieldIsCountry SelectionFieldIsCountry
SelectionFieldIsCompanyCode SelectionFieldIsCompanyCode
SelectionFieldIsBankKey SelectionFieldIsBankKey
SelectionFieldIsBankGroup SelectionFieldIsBankGroup
BkRltnDocBkAcctSelLowText BkRltnDocBkAcctSelLowText
BkRltnDocBkAcctSelHighText BkRltnDocBkAcctSelHighText 
@EndUserText.label: 'Bank Account Selections of Bank Doc'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions: true }
@ObjectModel.usageType: { serviceQuality: #B,
                          sizeCategory: #S,
                          dataClass: #MASTER }
@VDM: { viewType: #CONSUMPTION,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] }
@Search.searchable: true        
define view entity C_BkRelshpDocAcctSelectionTP as projection on R_BkRelshpDocAcctSelectionTP
{
    
    key BkRltnDocBkAcctSelectionUUID,
    key BankRelationshipDocumentUUID,
        @Search.defaultSearchElement: true
        @Search.ranking: #HIGH
        @ObjectModel.text.element: ['BkRltnDocBkAcctSelFieldName']
        @Consumption.valueHelpDefinition: [{  entity: {name: 'I_BkRelshpDocSelectionField',
                                              element: 'BkRltnDocBkAcctSelectionField'} }]
        BkRltnDocBkAcctSelectionField,        
        _BkRltnDocSelectionFieldText.BkRltnDocBkAcctSelFieldName   as BkRltnDocBkAcctSelFieldName  : localized,
        BkRltnDocBkAcctSelectionSign,
        BkRltnDocBkAcctSelectionOption,
        @Consumption.valueHelpDefinition:
        [
          {
          qualifier: 'MyValueHelpA',
          entity: { name:'I_CountryVH', element:'Country' },
          enabled: 'SelectionFieldIsCountry'
          },
          {
          qualifier: 'MyValueHelpB',
          entity: { name:'I_CurrencyStdVH', element:'Currency' },
          enabled: 'SelectionFieldIsCurrency'
          },          
          {
          qualifier: 'MyValueHelpC',
          entity: { name:'C_CompanyCodeValueHelp', element:'CompanyCode' },
          enabled: 'SelectionFieldIsCompanyCode'
          },
          {
          qualifier: 'MyValueHelpD',
          entity: { name:'C_BankInternalIDVH', element:'BankInternalID' },
          enabled: 'SelectionFieldIsBankKey'
          },
          {
          qualifier: 'MyValueHelpE',
          entity: { name:'C_BankGroupRootNodeValueHelp', element:'BusinessPartnerNumber' },
          enabled: 'SelectionFieldIsBankGroup'
          }
        ]
        @EndUserText.label: 'Value'
        @ObjectModel.text.element: ['BkRltnDocBkAcctSelLowText']
        BkRltnDocBkAcctSelLowValue,
        @ObjectModel.text.element: ['BkRltnDocBkAcctSelHighText']
        BkRltnDocBkAcctSelHighValue,
        @Semantics.user.createdBy: true
        CreatedByUser,
        @Semantics.systemDateTime.createdAt: true
        CreationDateTime,
        @Semantics.user.lastChangedBy: true  
        LastChangedByUser,
        @Semantics.systemDateTime.localInstanceLastChangedAt:true
        LocalLastChangeDateTime,
        
        // Context dependent value help

        @UI.hidden:true
        @Semantics.booleanIndicator: true
        SelectionFieldIsCurrency,
        
        @UI.hidden:true
        @Semantics.booleanIndicator: true
        SelectionFieldIsCountry,
        
        @UI.hidden:true
        @Semantics.booleanIndicator: true
        SelectionFieldIsCompanyCode,
        
        @UI.hidden:true
        @Semantics.booleanIndicator: true
        SelectionFieldIsBankKey,
        
        @UI.hidden:true
        @Semantics.booleanIndicator: true
        SelectionFieldIsBankGroup,
        
        @UI.hidden:true
        BkRltnDocBkAcctSelLowText,
        @UI.hidden:true
        BkRltnDocBkAcctSelHighText,
        
        // Associations        

        _BankRelationshipDocument: redirected to parent C_BankRelationshipDocTP
}

Learn More