C_BkRelshpDocAccountTP

DDL: C_BKRELSHPDOCACCOUNTTP Type: view_entity CONSUMPTION Package: FCLM_BRM_DOC

Bank Account of Bank Relationship Doc

C_BkRelshpDocAccountTP is a Consumption CDS View that provides data about "Bank Account of Bank Relationship Doc" in SAP S/4HANA. It reads from 1 data source (R_BkRelshpDocAccountTP) and exposes 29 fields with key fields BkRltnDocBankAccountUUID, BankRelationshipDocumentUUID. It is exposed through 1 OData service (UI_BANKRELATIONSHIPDOC). Part of development package FCLM_BRM_DOC.

1 data source(s) Exposed by 1 service(s) 29 fields

Data Sources (1)

SourceAliasJoin Type
R_BkRelshpDocAccountTP R_BkRelshpDocAccountTP projection

Annotations (10)

NameValueLevelField
EndUserText.label Bank Account of Bank Relationship Doc view
AccessControl.authorizationCheck #MANDATORY view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MASTER view
VDM.viewType #CONSUMPTION view
Search.searchable true view
AccessControl.personalData.blocking #REQUIRED view

OData Services (1)

ServiceBindingVersionContractRelease
UI_BANKRELATIONSHIPDOC UI_BANKRELATIONSHIPDOC_O4 V4 C1 NOT_RELEASED

Fields (29)

KeyFieldSource TableSource FieldDescription
KEY BkRltnDocBankAccountUUID BkRltnDocBankAccountUUID
KEY BankRelationshipDocumentUUID BankRelationshipDocumentUUID
BankAccountInternalID BankAccountInternalID
BkRltnDocBkAcctAssgmtDateTime BkRltnDocBkAcctAssgmtDateTime
BkRltnDocBkAcctRemovalDateTime BkRltnDocBkAcctRemovalDateTime
Bank _BankAccountBasicData Bank
BankName _BankAccountBasicData BankName
BankAccountNumber _BankAccountBasicData BankAccountNumber
BankCountry
CountryNameasBankCountryNamelocalized Bank Country/Region Name
BankAccountCurrency _BankAccountBasicData BankAccountCurrency
BankControlKey _BankAccountBasicData BankControlKey
BankAccountContractType _BankAccountBasicData BankAccountContractType
BankAccountStatus _BankAccountBasicData BankAccountStatus
BankAccountStatusName
BankAccountType _BankAccountBasicData BankAccountType
CompanyCode _BankAccountBasicData CompanyCode
CompanyCodeName
CompanyCodeCountry _BankAccountBasicData CompanyCodeCountry Company Country/Region
BankAccountDescription _BankAccountBasicData BankAccountDescription
BankGroup _BankAccountBasicData BankGroup Bank Group
BusinessPartnerName _BankAccountBasicData BusinessPartnerName
HouseBank _BankAccountBasicData HouseBank
HouseBankAccount _BankAccountBasicData HouseBankAccount House Bank Account
CreatedByUser CreatedByUser
CreationDateTime CreationDateTime
LastChangedByUser LastChangedByUser
LocalLastChangeDateTime LocalLastChangeDateTime
_BankAccountBasicData _BankAccountBasicData 
@EndUserText.label: 'Bank Account of Bank Relationship Doc'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions: true }
@ObjectModel.usageType: { serviceQuality: #C,
                          sizeCategory: #M,
                          dataClass: #MASTER }
@VDM: { viewType: #CONSUMPTION,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] }
@Search.searchable: true
@AccessControl.personalData.blocking: #REQUIRED
define view entity C_BkRelshpDocAccountTP as projection on R_BkRelshpDocAccountTP
{
    key BkRltnDocBankAccountUUID,
    key BankRelationshipDocumentUUID,
        @Search.defaultSearchElement: true
        BankAccountInternalID,
        BkRltnDocBkAcctAssgmtDateTime,
        BkRltnDocBkAcctRemovalDateTime,
        @ObjectModel.text.element: ['BankName']
        _BankAccountBasicData.Bank                                              as Bank,
        _BankAccountBasicData.BankName,
        @Search.defaultSearchElement: true
        @Search.ranking: #HIGH
        _BankAccountBasicData.BankAccountNumber                                 as BankAccountNumber,
        @ObjectModel.text.element: ['BankCountryName']
        cast (_BankAccountBasicData.BankCountry as banks preserving type)       as BankCountry,
        @EndUserText.label: 'Bank Country/Region Name'
        _BankAccountBasicData._BankCountry._Text.CountryName                    as BankCountryName : localized,
        _BankAccountBasicData.BankAccountCurrency                               as BankAccountCurrency,
        _BankAccountBasicData.BankControlKey                                    as BankControlKey,
        _BankAccountBasicData.BankAccountContractType                           as BankAccountContractType,
        @ObjectModel.text.element: ['BankAccountStatusName']
        _BankAccountBasicData.BankAccountStatus,
        _BankAccountBasicData._BankAccountStatus.BankAccountStatusName,
        @ObjectModel.text.element: ['BankAccountTypeText']
        _BankAccountBasicData.BankAccountType                                   as BankAccountType,
        @EndUserText.label: 'Bank Account Type Description'
        _BankAccountBasicData._BankAccountType.BankAccountTypeText              as BankAccountTypeText    : localized,
        @ObjectModel.text.element: ['CompanyCodeName']
        _BankAccountBasicData.CompanyCode                                       as CompanyCode,
        _BankAccountBasicData._CompanyCode.CompanyCodeName                      as CompanyCodeName,
        @EndUserText.label: 'Company Country/Region'
        @ObjectModel.text.element: ['CompanyCodeCountryName']
        _BankAccountBasicData.CompanyCodeCountry,
        _BankAccountBasicData._CompanyCode._Country._Text.CountryName           as CompanyCodeCountryName : localized,
        _BankAccountBasicData.BankAccountDescription                            as BankAccountDescription ,
        @EndUserText.label: 'Bank Group'
        @ObjectModel.text.element: ['BusinessPartnerName']
        _BankAccountBasicData.BankGroup,
        _BankAccountBasicData.BusinessPartnerName,

        _BankAccountBasicData.HouseBank,
        @EndUserText.label: 'House Bank Account'
        _BankAccountBasicData.HouseBankAccount,

        @Semantics.user.createdBy: true
        CreatedByUser,
        @Semantics.systemDateTime.createdAt: true
        CreationDateTime,
        @Semantics.user.lastChangedBy: true
        LastChangedByUser,
        @Semantics.systemDateTime.localInstanceLastChangedAt:true
        LocalLastChangeDateTime,

        _BankRelationshipDocument : redirected to parent C_BankRelationshipDocTP,
        _BankAccountBasicData
}

Learn More