C_BkAcctInstntBalSetting

@EndUserText.label: 'Bank Account Instant Balance Setting'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@Search.searchable: true
@VDM : { viewType: #CONSUMPTION,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] }
@ObjectModel: {
    usageType: {
        serviceQuality: #C,
        sizeCategory:   #M,
        dataClass:      #TRANSACTIONAL }
}
@AccessControl.privilegedAssociations: [ '_CreatedByUserCntctCard', '_LastChangedByUserCntctCard' ]
define root view entity C_BkAcctInstntBalSetting
  as select from I_BkAcctInstntBalanceEnhanced
  association [1..1] to I_BkAcctInstntBalanceStatus as _BkAcctInstntBalanceStatus  on $projection.BkAcctInstntBalanceStatus = _BkAcctInstntBalanceStatus.BkAcctInstntBalanceStatus
  association [1..1] to I_HsBkInstantBalanceStatus  as _HsBkInstantBalanceStatus   on $projection.HouseBankInstantBalanceStatus = _HsBkInstantBalanceStatus.HouseBankInstantBalanceStatus
  association [0..1] to I_UserContactCard           as _CreatedByUserCntctCard     on $projection.CreatedByUser = _CreatedByUserCntctCard.ContactCardID
  association [0..1] to I_UserContactCard           as _LastChangedByUserCntctCard on $projection.LastChangedByUser = _LastChangedByUserCntctCard.ContactCardID
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BankAccountInternalID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['CompanyCodeName']
      @UI.textArrangement: #TEXT_LAST
      CompanyCode,
      @Semantics.text
      _CompanyCode.CompanyCodeName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      HouseBank,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['HouseBankAccountDescription']
      HouseBankAccount,
      @ObjectModel.text.element: [ 'BkAcctInstntBalanceStatusText' ]
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [ { entity:  { name: 'I_BkAcctInstntBalanceStatus', element: 'BkAcctInstntBalanceStatus' } }]
      BkAcctInstntBalanceStatus,
      @Semantics.text: true
      _BkAcctInstntBalanceStatus._Text[1:Language = $session.system_language].BkAcctInstntBalanceStatusText,
      @Consumption.filter.hidden: true
      _BkAcctInstntBalanceStatus._Criticality.BkAcctInstntBalStsCritlty,
      @ObjectModel.text.element: [ 'HsBankInstntBalanceStatusText' ]
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [ { entity:  { name: 'I_HsBkInstantBalanceStatus', element: 'HouseBankInstantBalanceStatus' } }]
      @Consumption.filter : { selectionType: #SINGLE, defaultValue: '1', multipleSelections: false }
      HouseBankInstantBalanceStatus,
      @Semantics.text: true
      _HsBkInstantBalanceStatus._Text[1:Language = $session.system_language].HsBankInstntBalanceStatusText,
      @Consumption.filter.hidden: true
      _HsBkInstantBalanceStatus._Criticality.HsBankInstntBalStatusCritlty,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      HouseBankAccountDescription,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BankAccountNumber,
      @Consumption.filter.hidden: true
      BankInternalID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['BankName']
      @UI.textArrangement: #TEXT_LAST
      BankNumber,
      @Semantics.text: true
      _BankData.BankName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['CountryName']
      @UI.textArrangement: #TEXT_LAST
      BankCountry,
      @Semantics.text
      _BankCountry._Text[1:Language = $session.system_language].CountryName as CountryName,
      BankAccountCurrency,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      IBAN,

      @UI.textArrangement: #TEXT_LAST
      @ObjectModel.text.element: ['CreatedByUserDescription']
      @Semantics.user.createdBy: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessUserVH', element: 'UserID' } } ]
      CreatedByUser,
      @Semantics.text: true
      cast( _UserCreate.UserDescription as  fclm_ib_created_by_description preserving type ) as CreatedByUserDescription,

      @Consumption.filter.selectionType: #INTERVAL
      CreationDateTime,
      @UI.textArrangement: #TEXT_LAST
      @ObjectModel.text.element: ['LastChangedByUserDescription']
      @Semantics.user.lastChangedBy: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessUserVH', element: 'UserID' } } ]
      LastChangedByUser,
      @Semantics.text: true
      cast( _UserChange.UserDescription as fclm_ib_changed_by_description preserving type )  as LastChangedByUserDescription,
      @Consumption.filter.selectionType: #INTERVAL
      LastChangeDateTime,

      @Aggregation.default:#SUM
      @UI.hidden: true
      1                                                                     as DummyMeasure,

      @Consumption.filter.hidden: true
      _CreatedByUserCntctCard,
      @Consumption.filter.hidden: true
      _LastChangedByUserCntctCard
}