C_BSOrdItmProcFlwPurReqn

DDL: C_BSORDITMPROCFLWPURREQN Type: view CONSUMPTION Package: CRMS4_SOLUTION_ORDER_PROGRESS

PurReqn Item Attrib for BSOrd Prgrs

C_BSOrdItmProcFlwPurReqn is a Consumption CDS View that provides data about "PurReqn Item Attrib for BSOrd Prgrs" in SAP S/4HANA. It reads from 1 data source (I_Purchaserequisitionitem) and exposes 15 fields with key fields UI5NetworkGraphAttributeValue, PurchaseRequisitionItem. It has 3 associations to related views. Part of development package CRMS4_SOLUTION_ORDER_PROGRESS.

1 data source(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
I_Purchaserequisitionitem PurReqnItm from

Associations (3)

CardinalityTargetAliasCondition
[0..1] P_BusSolnOrdSubsqntDocTypeText _DocumentType _DocumentType.UI5NetworkGraphDescription = 'BI'
[0..1] I_PurReqnReleaseStatus _PurReqnReleaseStatus $projection.PurReqnReleaseStatus = _PurReqnReleaseStatus.PurReqnReleaseStatus
[0..1] E_Purchaserequisitionitem _Extension PurReqnItm.PurchaseRequisition = _Extension.PurchaseRequisition and PurReqnItm.PurchaseRequisitionItem = _Extension.PurchaseRequisitionItem

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName CURREQNITMATTRIB view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
VDM.viewType #CONSUMPTION view
EndUserText.label PurReqn Item Attrib for BSOrd Prgrs view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY UI5NetworkGraphAttributeValue PurchaseRequisition
KEY PurchaseRequisitionItem PurchaseRequisitionItem
CreationDate I_Purchaserequisitionitem CreationDate
Product I_Purchaserequisitionitem Material
RequestedQuantity I_Purchaserequisitionitem RequestedQuantity
BaseUnit I_Purchaserequisitionitem BaseUnit
ItemNetAmount I_Purchaserequisitionitem ItemNetAmount
PurReqnItemCurrency I_Purchaserequisitionitem PurReqnItemCurrency
DeliveryDate I_Purchaserequisitionitem DeliveryDate
PurReqnReleaseStatus I_Purchaserequisitionitem PurReqnReleaseStatus
UI5NetworkGraphStatus
UI5NetworkGraphStatusName
UI5NetworkGraphDescription
_UnitOfMeasure _UnitOfMeasure
_PurReqnReleaseStatus _PurReqnReleaseStatus 
@AbapCatalog: {
    sqlViewName:            'CURREQNITMATTRIB',
    compiler.compareFilter: true,
    preserveKey:            true
}

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #XL
}

@VDM: {
    viewType: #CONSUMPTION
}

@EndUserText.label: 'PurReqn Item Attrib for BSOrd Prgrs'

define view C_BSOrdItmProcFlwPurReqn
  as select from I_Purchaserequisitionitem as PurReqnItm
  association [0..1] to P_BusSolnOrdSubsqntDocTypeText as _DocumentType         on  _DocumentType.UI5NetworkGraphDescription = 'BI'
  association [0..1] to I_PurReqnReleaseStatus         as _PurReqnReleaseStatus on  $projection.PurReqnReleaseStatus = _PurReqnReleaseStatus.PurReqnReleaseStatus

  association [0..1] to E_Purchaserequisitionitem      as _Extension            on  PurReqnItm.PurchaseRequisition     = _Extension.PurchaseRequisition
                                                                                and PurReqnItm.PurchaseRequisitionItem = _Extension.PurchaseRequisitionItem
{
  key  PurchaseRequisition                                                                          as UI5NetworkGraphAttributeValue,
  key  PurchaseRequisitionItem,

       PurReqnItm.CreationDate,

       PurReqnItm.Material                                                                          as Product,

       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       PurReqnItm.RequestedQuantity,
       PurReqnItm.BaseUnit,

       @Semantics.amount.currencyCode: 'PurReqnItemCurrency'
       PurReqnItm.ItemNetAmount,
       @Semantics.currencyCode: true
       PurReqnItm.PurReqnItemCurrency,

       PurReqnItm.DeliveryDate,

       @ObjectModel.foreignKey.association: '_PurReqnReleaseStatus'
       PurReqnItm.PurReqnReleaseStatus,
       cast ( PurReqnItm.PurReqnReleaseStatus as fac_network_graph_status )                         as UI5NetworkGraphStatus,
       _PurReqnReleaseStatus._Text[1: Language = $session.system_language].PurReqnReleaseStatusDesc as UI5NetworkGraphStatusName,

       @Semantics.text: true
       _DocumentType[1: Language = $session.system_language].UI5NetworkGraphDescriptionName         as UI5NetworkGraphDescription,

       _UnitOfMeasure,
       _PurReqnReleaseStatus
}

Learn More