C_BE_DomesticSalesListCube

@EndUserText.label: 'Domestic Sales List for Belgium'
@AbapCatalog.sqlViewName: 'CBEDOMSLSLSTCUBE'
@VDM.viewType: #CONSUMPTION
@Analytics.dataCategory: #CUBE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ClientHandling: { type: #INHERITED, algorithm: #SESSION_VARIABLE }
@ObjectModel.usageType: { dataClass: #MIXED, sizeCategory: #XL, serviceQuality: #X }
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@Consumption.dbHints: ['USE_HEX_PLAN']

////////////////////////////////////////////////////////////////////////////////

// This Cube publishes a specific Domestic Sales List for Belgium.

////////////////////////////////////////////////////////////////////////////////


define view C_BE_DomesticSalesListCube
  as select from    P_BE_DomesticSalesList20 as sl
{
  key   sl.CompanyCode,
  key   sl.FiscalYear,
  key   sl.AccountingDocument,
  key   sl.CADocumentNumber,
  key   sl.TaxCode,
  key   sl.TransactionTypeDetermination,
        @Semantics.currencyCode: true
  key   cast(sl.ReportingCurrency as waers)                                   as ReportingCurrency,

  key   sl.StatryRptgEntity,
  key   sl.StatryRptCategory,
  key   sl.StatryRptRunID,

        cast(min(sl.CAReconciliationKey) as fikey_kk preserving type)         as CAReconciliationKey,
        cast(min(sl.BusinessPartner) as bu_partner preserving type)           as BusinessPartner,
        cast(min(sl.BusinessPartnerName) as bp_name_ca preserving type)       as BusinessPartnerName,
        @DefaultAggregation:#SUM
        @Semantics.amount.currencyCode: 'ReportingCurrency'
        cast(sum(sl.TaxBaseAmountInRptgCrcy) as glo_taxbase_amount_rptg_crcy) as TaxBaseAmountInRptgCrcy,
        @DefaultAggregation:#SUM
        @Semantics.amount.currencyCode: 'ReportingCurrency'
        cast(sum(sl.TaxAmountInRptgCrcy) as glo_tax_amount_rptg_crcy)         as TaxAmountInRptgCrcy,

        cast(min(sl.PostingDate) as fis_budat)                                as PostingDate,
        cast(min(sl.TaxReportingDate) as vatdate)                             as TaxReportingDate,
        cast(min(sl.ReportingDate) as glo_reporting_date)                     as ReportingDate,
        cast(min(sl.Debtor) as kunnr)                                         as Debtor,
        cast(min(sl.Creditor) as lifnr)                                       as Creditor,
        cast(min(sl.Country) as land1_gp)                                     as Country, // Country of supplier / customer

        cast(min(sl.IsOneTimeAccount) as xcpdk)                               as IsOneTimeAccount,
        cast(min(sl.BPTaxNumber) as bptaxnum)                                 as BPTaxNumber
}
group by
  sl.CompanyCode,
  sl.FiscalYear,
  sl.AccountingDocument,
  sl.CADocumentNumber,
  sl.TaxCode,
  sl.TransactionTypeDetermination,
  sl.ReportingCurrency,
  sl.StatryRptgEntity,
  sl.StatryRptCategory,
  sl.StatryRptRunID