C_AllocationProfitCenterVH

DDL: C_ALLOCATIONPROFITCENTERVH SQL: CALOPRFTCNTRVH Type: view CONSUMPTION Package: ODATA_MANAGE_ALLOCATION

Allocation Profit Center

C_AllocationProfitCenterVH is a Consumption CDS View that provides data about "Allocation Profit Center" in SAP S/4HANA. It reads from 2 data sources (I_PrftCtrCompanyCodeAssignment, I_ProfitCenterStdVH) and exposes 8 fields with key fields ControllingArea, ProfitCenter, ValidityEndDate, CompanyCode. It is exposed through 1 OData service (UI_FCO_MANAGE_ALLOCATION). Part of development package ODATA_MANAGE_ALLOCATION.

2 data source(s) Exposed by 1 service(s) 8 fields

Data Sources (2)

SourceAliasJoin Type
I_PrftCtrCompanyCodeAssignment I_PrftCtrCompanyCodeAssignment inner
I_ProfitCenterStdVH I_ProfitCenterStdVH from

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CALOPRFTCNTRVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #NOT_REQUIRED view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.dataCategory #VALUE_HELP view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
Search.searchable true view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Allocation Profit Center view

OData Services (1)

ServiceBindingVersionContractRelease
UI_FCO_MANAGE_ALLOCATION UI_FCOUA_MANAGE_ALLOCATION V2 C1 NOT_RELEASED

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY ControllingArea I_ProfitCenterStdVH ControllingArea
KEY ProfitCenter I_ProfitCenterStdVH ProfitCenter
KEY ValidityEndDate ValidityEndDate
KEY CompanyCode
ValidityStartDate ValidityStartDate
_ControllingArea I_ProfitCenterStdVH _ControllingArea
ProfitCenterName
_Text _Text 
@AbapCatalog.sqlViewName: 'CALOPRFTCNTRVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.dataCategory: #VALUE_HELP

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@Search.searchable: true

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Allocation Profit Center'
define view C_AllocationProfitCenterVH as 
  select from I_ProfitCenterStdVH               
  inner join I_PrftCtrCompanyCodeAssignment on I_PrftCtrCompanyCodeAssignment.ProfitCenter    = I_ProfitCenterStdVH.ProfitCenter
                                           and I_PrftCtrCompanyCodeAssignment.ControllingArea = I_ProfitCenterStdVH.ControllingArea
{
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #LOW
  @UI.selectionField: [{position: 20 }]
      @UI: {
        textArrangement: #TEXT_LAST,
        lineItem: [{ position: 20 }]
      }
  key I_ProfitCenterStdVH.ControllingArea,
  
  @ObjectModel.text.element: 'ProfitCenterName'
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  @Search.ranking: #LOW
  @UI.selectionField: [{position: 10 }]
      @UI: {
        textArrangement: #TEXT_LAST,
        lineItem: [{ position: 10 }]
      }
  key I_ProfitCenterStdVH.ProfitCenter,
  
  @Semantics.businessDate.to: true
  @UI.selectionField: [{position: 40 }]
      @UI: {
        textArrangement: #TEXT_LAST,
        lineItem: [{ position: 40 }]
      }
  key ValidityEndDate,
  
  @Consumption.valueHelpDefinition: [ { entity: { name: 'I_AllocCompanyCodeVH', element: 'CompanyCode' } } ] 
  key cast(I_PrftCtrCompanyCodeAssignment.CompanyCode as bukrs) as CompanyCode,

  @Semantics.businessDate.from: true
  @UI.selectionField: [{position: 30 }]
      @UI: {
        textArrangement: #TEXT_LAST,
        lineItem: [{ position: 30 }]
      }
  ValidityStartDate,  
  
  /* Associations */
  @Consumption.hidden: true
  I_ProfitCenterStdVH._ControllingArea,
  
//  @Consumption.hidden: true

  @UI.hidden : true
  _Text[1:Language = $session.system_language].ProfitCenterName,
    
  _Text  
}
where ValidityEndDate >= $session.system_date
  and ValidityStartDate <= $session.system_date

Learn More