C_AccountingNotificationTP

@EndUserText.label: 'Accounting Notification'
@AccessControl.authorizationCheck:#MANDATORY
@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel: {
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #TRANSACTIONAL }
@OData.entityType.name:'AccountingNotification_Type'
@Metadata: {
  ignorePropagatedAnnotations: true,
  allowExtensions: true
}
@Search.searchable: true

@ObjectModel.semanticKey: ['AccountingNotificationType','ReferenceDocumentOID']
@AbapCatalog.extensibility: {
  extensible: true,
  allowNewCompositions: true  
}
define root view entity C_AccountingNotificationTP  
  provider contract transactional_query
  as projection on R_AccountingNotificationTP
{
  key     AccountingNotificationUUID,
          FinanceNotificationUUID,
          @ObjectModel.foreignKey.association: '_AccountingNotificationType'
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          AccountingNotificationType,
          @ObjectModel.foreignKey.association: '_FinanceNotificationType'
          FinanceNotificationType,
          @ObjectModel.foreignKey.association: '_ReferenceDocumentType'      
          ReferenceDocumentType,
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          ReferenceDocument,
          ReferenceDocumentContext,
          ReferenceDocumentItem,
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          ReferenceDocumentLogicalSystem,
          @Semantics.systemDate.createdAt: true
          @Consumption.filter.selectionType:#INTERVAL
          CreationDateTime,
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          ReferenceDocumentOID,
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          ReferenceDocumentDisplayID,
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          ReferenceDocumentEventOID,
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          RefDocumentEventDisplayID,
          @Semantics.systemDate.lastChangedAt: true
          RefDocLastChangeDateTime,
          @ObjectModel.foreignKey.association: '_LeadingCompanyCode'
          LeadingCompanyCode,
          @Consumption.filter.selectionType:#INTERVAL
          ProposedPostingDate,

          @ObjectModel.foreignKey.association: '_ProcessingStatus'
          AcctgNotifProcessingStatus,         
          @Semantics.systemDate.lastChangedAt: true
          LastChangeDateTime,
          @ObjectModel.foreignKey.association: '_CreatedByUser'
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          CreatedByUser,
          @ObjectModel.foreignKey.association: '_LastChangedByUser'
          @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
          LastChangedByUser,
          ApplicationLogHandle,         
          LatestMessageClass,
          LatestMessageNumber,
          LatestMessageSeverity,
          @Consumption.hidden: true
          LatestMessageVariable1Text,
          @Consumption.hidden: true
          LatestMessageVariable2Text,
          @Consumption.hidden: true
          LatestMessageVariable3Text,
          @Consumption.hidden: true
          LatestMessageVariable4Text,
          IsReversal,
          StatusCriticality,     
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FAN_ACCTR_NOTIF_MSG_TEXT'
  virtual SystemMessageText : natxt,      
          _AddlCompanyCode  : redirected to composition child C_AcctgNotifAddlCompanyCode,
          _JournalEntry     : redirected to composition child C_AcctgNotifJournalEntry,
          _ActionResult     : redirected to composition child C_AcctgNotifActionResultTP,
          _LeadingCompanyCode,
          _ReferenceDocumentType,
          _AccountingNotificationType,
          _FinanceNotificationType,
          _CreatedByUser,
          _LastChangedByUser,
          _ProcessingStatus
}