C_ATPRlvtProdAssgdSoldToPtyVH

DDL: C_ATPRLVTPRODASSGDSOLDTOPTYVH Type: view_entity CONSUMPTION Package: ODATA_ATP_DISP_PROD_AVAILY

ATP Rlvt Product Assigned Sold to Party

C_ATPRlvtProdAssgdSoldToPtyVH is a Consumption CDS View that provides data about "ATP Rlvt Product Assigned Sold to Party" in SAP S/4HANA. It reads from 1 data source (I_Customer) and exposes 22 fields with key fields Product, SoldToParty. It has 1 association to related views. It is exposed through 1 OData service (UI_DISPLAY_PRODUCT_AVAILY). Part of development package ODATA_ATP_DISP_PROD_AVAILY.

1 data source(s) Exposed by 1 service(s) 22 fields

Data Sources (1)

SourceAliasJoin Type
I_Customer _Customer inner

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_CountryText _Text _Text.Country = $projection.Country and _Text.Language = $session.system_language

Annotations (11)

NameValueLevelField
EndUserText.label ATP Rlvt Product Assigned Sold to Party view
ObjectModel.dataCategory #VALUE_HELP view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #MANDATORY view
Search.searchable true view
Metadata.allowExtensions true view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.representativeKey SoldToParty view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view

OData Services (1)

ServiceBindingVersionContractRelease
UI_DISPLAY_PRODUCT_AVAILY UI_DISPLAY_PRODUCT_AVAILY V4 C1 NOT_RELEASED

Fields (22)

KeyFieldSource TableSource FieldDescription
KEY Product _SoldToParty Product Product
KEY SoldToParty _SoldToParty SoldToParty Customer
Country I_Customer Country Country/Region Key
Name I_Customer CustomerName Name
PostalCode I_Customer PostalCode Postal Code
CityName I_Customer CityName City
StreetName I_Customer StreetName Street
CountryName _Text CountryName
CustomerAccountGroup I_Customer CustomerAccountGroup
AuthorizationGroup I_Customer AuthorizationGroup
IsBusinessPurposeCompleted I_Customer IsBusinessPurposeCompleted
DataControllerSet I_Customer DataControllerSet
DataController1 I_Customer DataController1
DataController2 I_Customer DataController2
DataController3 I_Customer DataController3
DataController4 I_Customer DataController4
DataController5 I_Customer DataController5
DataController6 I_Customer DataController6
DataController7 I_Customer DataController7
DataController8 I_Customer DataController8
DataController9 I_Customer DataController9
DataController10 I_Customer DataController10 
@EndUserText.label: 'ATP Rlvt Product Assigned Sold to Party'
@ObjectModel.dataCategory: #VALUE_HELP
@VDM.viewType: #CONSUMPTION
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Search.searchable: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'SoldToParty'
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XL,
  dataClass: #MIXED
}

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view entity C_ATPRlvtProdAssgdSoldToPtyVH
  as select distinct from I_ATPRlvtProdAssgdSoldToPtyDsp as _SoldToParty
    inner join            I_Customer                     as _Customer on _SoldToParty.SoldToParty = _Customer.Customer
  association [0..1] to I_CountryText as _Text on  _Text.Country  = $projection.Country
                                               and _Text.Language = $session.system_language
{
      @EndUserText.label: 'Product'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @ObjectModel.sort.enabled: false
      @UI.lineItem: [ { position: 30 } ]
      @UI.selectionField: [{position: 3 }]
  key _SoldToParty.Product,

      @EndUserText.label: 'Customer'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.sort.enabled: false
      @UI.lineItem: [ { position: 10 } ]
      @UI.selectionField: [{position: 1 }]
  key _SoldToParty.SoldToParty,

      @EndUserText.label: 'Country/Region Key'
      @ObjectModel.text.element:[ 'CountryName' ]
      @UI.lineItem: [ { position: 60 } ]
      @UI.textArrangement: #TEXT_FIRST
      @UI.selectionField: [{position: 6 }]
      _Customer.Country      as Country,

      @EndUserText.label: 'Name'
      @UI.lineItem: [ { position: 20 } ]
      @UI.selectionField: [{position: 2 }]
      _Customer.CustomerName as Name,

      @EndUserText.label: 'Postal Code'
      @UI.lineItem: [ { position: 40 } ]
      @UI.selectionField: [{position: 4 }]
      _Customer.PostalCode,  

      @EndUserText.label: 'City'
      @UI.lineItem: [ { position: 50 } ]
      @UI.selectionField: [{position: 5 }]
      _Customer.CityName,

      @EndUserText.label: 'Street'
      @UI.lineItem: [ { position: 70 } ]
      @UI.selectionField: [{position: 7 }]
      _Customer.StreetName,

      @Semantics.text:true
      @Consumption.filter.hidden: true
      _Text.CountryName      as CountryName,
      
      // DCL relevant fields

      @Consumption.hidden: true
      _Customer.CustomerAccountGroup,
      @Consumption.hidden: true
      _Customer.AuthorizationGroup,
      @Semantics.booleanIndicator
      @Consumption.hidden: true
      _Customer.IsBusinessPurposeCompleted,
      //Added for DPP Data Controller

      @Consumption.hidden:true
      _Customer.DataControllerSet,
      @Consumption.hidden:true
      _Customer.DataController1,
      @Consumption.hidden:true
      _Customer.DataController2,
      @Consumption.hidden:true
      _Customer.DataController3,
      @Consumption.hidden:true
      _Customer.DataController4,
      @Consumption.hidden:true
      _Customer.DataController5,
      @Consumption.hidden:true
      _Customer.DataController6,
      @Consumption.hidden:true
      _Customer.DataController7,
      @Consumption.hidden:true
      _Customer.DataController8,
      @Consumption.hidden:true
      _Customer.DataController9,
      @Consumption.hidden:true
      _Customer.DataController10
}
where
  _SoldToParty.SoldToPartySpecialStockType = 'W'

Learn More