BH_ACDOCA_FOR_PRIMA_NOTA

@AbapCatalog.sqlViewName: 'BHACDFORPRIMNOT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'ML bloodhound: Quantity for prima nota'

define view BH_ACDOCA_FOR_PRIMA_NOTA as 

select from acdoca
{
   rldnr,
   rbukrs,
   gjahr,
   kalnr,
   awtyp,
   aworg,
   awref,
   vorgn,
   blart,
   sum(vmsl)   as lbkum,
   sum(hvkwrt) as vksal
}
where rrcty =  '0'   and
      ktosl =  'BSX' and
      poper <> '000' and
      bstat <> 'C'   and
      kalnr <> '000000000000'
group by
rldnr,
rbukrs,
gjahr,
kalnr,
awtyp,
aworg,
awref,
vorgn,
blart

union all

select from acdocd
{
   rldnr,
   rbukrs,
   gjahr,
   kalnr,
   awtyp,
   aworg,
   awref,
   vorgn,
   blart,
   sum(vmsl)   as lbkum,
   sum(hvkwrt) as vksal
}
where rrcty =  '0'   and
      ktosl =  'BSX' and
      poper <> '000' and
      bstat <> 'C'   and
      kalnr <> '000000000000'
group by
rldnr,
rbukrs,
gjahr,
kalnr,
awtyp,
aworg,
awref,
vorgn,
blart