A_WorkCenterCapPplineOp

@AbapCatalog.sqlViewName: 'AWCCAPPPLINEOP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Queued Operations Capacity'
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
define view A_WorkCenterCapPplineOp as 
            select distinct from I_WorkCenterCapPplineOp as WrkCtrCapPplineOp
            
             association [0..*] to A_WorkCenterCapOrderPerBucket   as _WorkCenterOrders
                                    on  $projection.Plant = _WorkCenterOrders.Plant
                                    and $projection.MRPController = _WorkCenterOrders.MRPController
                                    and $projection.WorkCenter = _WorkCenterOrders.WorkCenter
                                    and $projection.WorkCenterInternalID = _WorkCenterOrders.WorkCenterInternalID
                                    and $projection.CapacityInternalID = _WorkCenterOrders.CapacityInternalID
                                    and $projection.Material = _WorkCenterOrders.Material
                                    
             association [0..*] to I_WorkCenterText             as _WorkCenterText                       on  $projection.WorkCenterInternalID = _WorkCenterText.WorkCenterInternalID
             association [0..*] to I_PlannedOrderTypeText as _PlannedOrderText on $projection.OrderType = _PlannedOrderText.PlannedOrderType
             association [0..*] to I_OrderTypeText as _WorkOrderText          on $projection.OrderType = _WorkOrderText.OrderType
             association [0..*] to I_OrderCategoryText as _WorkOrderCategoryText on $projection.OrderCategory = _WorkOrderCategoryText.OrderCategory
             association [0..*] to I_PlannedOrderCategoryText as _PlannedOrderCategoryText on $projection.OrderCategory = _PlannedOrderCategoryText.PlannedOrderCategory
             association [0..*] to I_CapEvalCapRqmtStsText as _OprPlanningText          on $projection.OperationPlanningStatusCode = _OprPlanningText.CapacityRequirementStatusCode
             association [0..*] to I_SystemStatusText as _OrderStatusText          on $projection.OrderStatusCode = _OrderStatusText.SystemStatus
             association [0..*] to I_CapEvalFirmingStsText as _FirmingStatusText          on WrkCtrCapPplineOp.OrderFirmingStatusCode = _FirmingStatusText.OrderFirmingStatusCode
             
{
    key WrkCtrCapPplineOp.Plant,
    key WrkCtrCapPplineOp.MRPController,
    key WrkCtrCapPplineOp.WorkCenter,
    key WrkCtrCapPplineOp.CapacityInternalID,
    key WrkCtrCapPplineOp.CapacityRequirement,
    key WrkCtrCapPplineOp.Material,
    key WrkCtrCapPplineOp.OrderID,
    key WrkCtrCapPplineOp.Operation,
    
        _WorkCenterText[1:Language=$session.system_language].WorkCenterText as WorkCenterDesc,
        WrkCtrCapPplineOp.WorkCenterResponsible,
        WrkCtrCapPplineOp.WorkCenterCategoryCode,
        WrkCtrCapPplineOp.WorkCenterInternalID,
        WrkCtrCapPplineOp.CapacityRequirementOrigin,
        @Semantics.unitOfMeasure: true
        WrkCtrCapPplineOp.CapacityRequirementUnit,
        WrkCtrCapPplineOp.OrderType,
        case WrkCtrCapPplineOp.CapacityRequirementOrigin
            when '1'
                  then _WorkOrderText[1:Language=$session.system_language].OrderTypeName
            when '2'
                  then _PlannedOrderText[1:Language=$session.system_language].PlannedOrderTypeName
            else ''
            end  as   OrderTypeName,
        WrkCtrCapPplineOp.OrderCategory,
         case WrkCtrCapPplineOp.CapacityRequirementOrigin
            when '1'
                  then _WorkOrderCategoryText[1:Language=$session.system_language].OrderCategoryName
            when '2'
                  then _PlannedOrderCategoryText[1:Language=$session.system_language].PlannedOrderCategoryName
            else ''
            end  as   OrderCategoryName,
         @Semantics.unitOfMeasure: true
        cast(WrkCtrCapPplineOp.BaseUnit as meins) as BaseUnit,
        @Semantics.quantity.unitOfMeasure: 'BaseUnit'
        WrkCtrCapPplineOp.OrderPlannedTotalQty,
        WrkCtrCapPplineOp.ProductionVersion,
        WrkCtrCapPplineOp.OperationPlanningStatusCode,
        _OprPlanningText[1:Language=$session.system_language].CapacityRequirementStatusText as OperationPlanningStatusText,
        cast(WrkCtrCapPplineOp.OperationLatestStartDate as char8) as OperationLatestStartDate,
        cast(WrkCtrCapPplineOp.OperationLatestStartTime as char6) as OperationLatestStartTime,
        cast(WrkCtrCapPplineOp.OperationLatestEndDate as char8) as OperationLatestEndDate,
        cast(WrkCtrCapPplineOp.OperationLatestEndTime as char6) as OperationLatestEndTime,
        WrkCtrCapPplineOp.OrderStatusCode,
        _OrderStatusText[1:Language=$session.system_language].SystemStatusName as OrderStatusText,
        _OrderStatusText[1:Language=$session.system_language].SystemStatusShortName as OrderStatusShortText,
        cast(WrkCtrCapPplineOp.OrderFirmingStatusCode as char1) as OrderFirmingStatusCode,
        _FirmingStatusText[1:Language=$session.system_language].OrderFirmingStatusText as OrderFirmingStatusText,
        cast(WrkCtrCapPplineOp.OpLtstSchedldProcgStrtDte as char8) as OpLtstSchedldProcgStrtDte,
        cast(WrkCtrCapPplineOp.OpLtstSchedldProcgStrtTme as char6) as OpLtstSchedldProcgStrtTme,
        cast(WrkCtrCapPplineOp.OpLtstSchedldTrdwnStrtDte as char8) as OpLtstSchedldTrdwnStrtDte,
        cast(WrkCtrCapPplineOp.OpLtstSchedldTrdwnStrtTme as char6) as OpLtstSchedldTrdwnStrtTme,
        @Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
        WrkCtrCapPplineOp.RemainingCapReqOpSegSetupDurn,
        @Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
        WrkCtrCapPplineOp.RemainingCapReqOpSegProcgDurn,
        @Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
        WrkCtrCapPplineOp.RemainingCapReqOpSegTrdwnDurn,
        WrkCtrCapPplineOp.CapacityRequirementsAreDtmnd,
        @Semantics.quantity.unitOfMeasure: 'CapacityRequirementUnit'
        WrkCtrCapPplineOp.CapacityRequirementsAreDtmnd as RemainingCapReqExecutionDurn,
        WrkCtrCapPplineOp.OrderInternalID,
        _WorkCenterOrders
}
where WrkCtrCapPplineOp.Sequence = '000000'or
      WrkCtrCapPplineOp.OrderCategory = '30'