A_SubscriptionContract

@EndUserText.label: 'Subscription Contract Header'
@VDM: {
  viewType: #CONSUMPTION,
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   representativeKey: 'SubscriptionContract',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define root view entity A_SubscriptionContract
  as select from I_ServiceDocumentEnhcd

  association [0..*] to A_SubscriptionContractItem     as _Item                         on  $projection.SubscriptionContract = _Item.SubscriptionContract

  association [0..*] to A_SubscriptionContractText     as _Text                         on  $projection.SubscriptionContract = _Text.SubscriptionContract

  association [0..1] to E_ServiceDocument              as _Extension                    on  _Extension.ServiceCategory       = 'BUS2000266'
                                                                                        and $projection.SubscriptionContract = _Extension.ServiceOrder

  association [0..*] to A_SbscrContrPrdcssrBusSolnQtn  as _PredecessorSolutionQuotation on  $projection.SubscriptionContract = _PredecessorSolutionQuotation.SubscriptionContract

  association [0..*] to A_SbscrContrPrdcssrSubscrpnOrd as _PredecessorSubscriptionOrder on  $projection.SubscriptionContract = _PredecessorSubscriptionOrder.SubscriptionContract

  association [0..*] to A_SbscrContrFUPSubscrpnOrd     as _FollowUpSubscriptionOrder    on  $projection.SubscriptionContract = _FollowUpSubscriptionOrder.SubscriptionContract

  association [0..*] to A_SubscriptionContractPartner as _SubscriptionContractPartner on $projection.SubscriptionContract = _SubscriptionContractPartner.SubscriptionContract
{

  key ServiceDocument                               as SubscriptionContract,
      ServiceDocumentType                           as SubscriptionContractType,
      ServiceDocumentDescription                    as SubscrpnContractDescription,
      ServiceDocumentUUID                           as SubscriptionContractUUID,
      Language,

      /* STATUS */
      case ServiceDocumentStatus
      when 'C' then 'X'
      else ''
      end                                           as SubscrpnContractIsCompleted,

      /* ORG */
      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,

      /* PARTNER */
      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      cast( ResponsibleEmployee as abap.char( 12 )) as PersonResponsible,
      cast( ContactPerson as abap.numc( 10 ))       as ContactPerson,


      ServiceDocumentCreatedByUser                  as CreatedByUser,
      ServiceDocCreationDateTime                    as CreationDateTime,
      ServiceDocumentChangedByUser                  as LastChangedByUser,
      ServiceDocChangedDateTime                     as LastChangeDateTime,
      
      // Sales Set

      PurchaseOrderByCustomer,

      //Associations

      _Item,
      _Text,
      _PredecessorSolutionQuotation,
      _PredecessorSubscriptionOrder,
      _FollowUpSubscriptionOrder,
      _SubscriptionContractPartner
}
where
  ServiceObjectType = 'BUS2000266'