A_SalesQuotationPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Header Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASQPARTNER',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesQuotationPartner
  as select from I_SDDocumentPartner as Partner
    inner join I_SalesDocumentBasic as SalesQuotation on SalesQuotation.SalesDocument = Partner.SDDocument // needed for DCL

                                                  and SalesQuotation.SDDocumentCategory     = 'B'
    
   association [1..1] to A_SalesQuotation              as _SalesQuotation     on  _SalesQuotation.SalesQuotation = $projection.SalesQuotation
   association [0..1] to I_BusPartAddress as _BusinessPartnerAddressCP on Partner.AddressID                  = _BusinessPartnerAddressCP.AddressID
                                                                      and $projection.ContactPerson is not initial
                                                                      and Partner.SDDocPartnerAddressRefType =  'I'
                                                   
{
      @ObjectModel.readOnly: true
  key SDDocument as SalesQuotation,
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key PartnerFunction,
  
      @ObjectModel.readOnly: true
      cast(PartnerFunction as parvw_unv preserving type ) as PartnerFunctionInternalCode,

      Customer,
      
      Supplier,

      Personnel,

      ContactPerson,
      
      @ObjectModel.readOnly: true
      ReferenceBusinessPartner,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES3, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end as BusinessPartnerAddressUUID,
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES3, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true  
      Partner._BPRefAddressForDocSpcfcAddr.AddressUUID  as BPRefAddrForDocSpcfcAddrUUID,
                      
      // For Access control

      @Consumption.hidden: true
      SalesQuotation.SalesDocumentType as SalesQuotationType,
      @Consumption.hidden: true
      SalesQuotation.OrganizationDivision,
      @Consumption.hidden: true
      SalesQuotation.SalesOrganization,
      @Consumption.hidden: true
      SalesQuotation.DistributionChannel,
      
      //Expose associations

      _SalesQuotation 
}