A_SalesInquiryPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Header Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASIPARTNER',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_SalesInquiryPartner
  as select from I_SDDocumentPartner as Partner
    inner join I_SalesDocumentBasic as SalesInquiry on SalesInquiry.SalesDocument = Partner.SDDocument // needed for DCL

                                                  and SalesInquiry.SDDocumentCategory     = 'A'
    
   association [1..1] to A_SalesInquiry              as _SalesInquiry     on  _SalesInquiry.SalesInquiry = $projection.SalesInquiry
   association [0..1] to I_BusPartAddress as _BusinessPartnerAddressCP on Partner.AddressID                  = _BusinessPartnerAddressCP.AddressID
                                                                      and $projection.ContactPerson is not initial
                                                                      and Partner.SDDocPartnerAddressRefType =  'I'
                                                   
{
      @ObjectModel.readOnly: true
  key SDDocument as SalesInquiry,
      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key PartnerFunction,

      Customer,
      
      Supplier,

      Personnel,

      ContactPerson,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES3, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end as BusinessPartnerAddressUUID,
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES3, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true  
      Partner._BPRefAddressForDocSpcfcAddr.AddressUUID  as BPRefAddrForDocSpcfcAddrUUID,
        
      // For Access control

      @Consumption.hidden: true
      SalesInquiry.SalesDocumentType as SalesInquiryType,
      @Consumption.hidden: true
      SalesInquiry.OrganizationDivision,
      @Consumption.hidden: true
      SalesInquiry.SalesOrganization,
      @Consumption.hidden: true
      SalesInquiry.DistributionChannel,
      
      //Expose associations

      _SalesInquiry 
}