A_ProjectNetwork

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Project Network Data'
@VDM: {
    usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE],
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@OData.entitySet.name : 'ProjectNetwork'
@OData.entityType.name:'ProjectNetwork_Type'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

define root view entity A_ProjectNetwork
  provider contract transactional_query
  as projection on R_ProjectNetworkTP as _ProjectNetwork

  association [1..*] to A_ProjectNetworkStatus as _ProjectNetworkStatus on $projection.ProjectNetwork = _ProjectNetworkStatus.ProjectNetwork
  association [1..1] to E_LogisticsOrder       as _Extension            on $projection.ProjectNetwork = _Extension.OrderID

{
  key ProjectNetwork,
      ProjectNetworkInternalID,
      @Semantics.text: true
      ProjectNetworkDescription,
      @Semantics.text: true
      ProjNtwkLangBsdDescription,
      ProjectNetworkType,
      PlannedStartDate,
      PlannedEndDate,
      ScheduledReleaseDate,
      ScheduledBasicStartDate,
      ScheduledBasicEndDate,
      ForecastedStartDate,
      ForecastedEndDate,
      ScheduledFcstdReleaseDate,
      ScheduledForecastedStartDate,
      ScheduledForecastedEndDate,
      ActualReleasedDate,
      ActualStartDate,
      ActualEndDate,
      @ObjectModel.sapObjectNodeTypeReference: 'SchedulingType' 
      BasicSchedulingType,
      @ObjectModel.sapObjectNodeTypeReference: 'SchedulingReductionLevel'
      BasicSchedulingReductionLevel,
      @Semantics.booleanIndicator: true
      OrdIsNotSchedldAutomatically,
      CapacityRqmtHasNotToBeCreated,
      SchedulingIsAllowingForBreaks,
      @ObjectModel.sapObjectNodeTypeReference: 'SchedulingType'
      ForecastSchedulingType,
      @ObjectModel.sapObjectNodeTypeReference: 'SchedulingReductionLevel'
      FcstSchedulingReductionLevel,

      ProjectExternalID,
      ProjectInternalID,
      WBSElementExternalID,
      WBSElementInternalID,

      SalesOrder,
      SalesOrderItem,
      SuperiorProjectNetwork,
      SuperiorProjectNetworkIntID,
      SuperiorNtwkActivityExternalID,
      SuperiorNtwkActivityInternalID,

      ControllingArea,
      CompanyCode,
      BusinessArea,
      ProfitCenter,
      FunctionalArea,
      @ObjectModel.sapObjectNodeTypeReference: 'ControllingObjectClass'
      ControllingObjectClass,
      TaxJurisdiction,
      ResponsibleCostCenter,
      Currency,

      ResponsiblePlannerGroup,
      ChangeNumber,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectNetworkProfile'
      NetworkProfile,
      Plant,
      MRPController,
      @ObjectModel.sapObjectNodeTypeReference: 'ProjectObjectPriorityCode'
      PriorityCode,
      BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      PlannedTotalQty,

      CostingSheet,
      PlannedCostsCostingVariant,
      ActualCostsCostingVariant,
      OverheadCode,
      PlannedCostCalculation,
      PurReqnOrResvnGeneration,

      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      IsMarkedForDeletion,

      JointVenture,
      JointVentureRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,
      JointVentureOriginalCostObject,
      NetworkIsAccountAssigned,

      ProcurementMode,
      ProjectNetworkExecutionRate,
      StatusCombinationCode,
      /* Associations */
      _ProjectNetworkStatus,
      _ProjectNetworkActivity : redirected to composition child A_ProjectNetworkActivity
}