A_ProductPlant

@AbapCatalog.sqlViewName: 'APRODPLANT'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Plant Data'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true


define view A_ProductPlant
  as select from I_ProductPlant as Plant
  association [0..*] to A_ProductStorageLocation  as _StorageLocation             on  $projection.Product = _StorageLocation.Product
                                                                                  and $projection.Plant   = _StorageLocation.Plant

  association [0..1] to A_ProductPlantProcurement as _ProductPlantProcurement     on  $projection.Product = _ProductPlantProcurement.Product
                                                                                  and $projection.Plant   = _ProductPlantProcurement.Plant


  association [0..1] to A_ProductWorkScheduling   as _ProductWorkScheduling       on  $projection.Product = _ProductWorkScheduling.Product
                                                                                  and $projection.Plant   = _ProductWorkScheduling.Plant

  association [0..1] to A_ProductSupplyPlanning   as _ProductSupplyPlanning       on  $projection.Product = _ProductSupplyPlanning.Product
                                                                                  and $projection.Plant   = _ProductSupplyPlanning.Plant

  association [0..1] to A_ProductPlantIntlTrd     as _ProdPlantInternationalTrade on  $projection.Product = _ProdPlantInternationalTrade.Product
                                                                                  and $projection.Plant   = _ProdPlantInternationalTrade.Plant

  association [0..1] to A_ProductPlantCosting     as _ProductPlantCosting         on  $projection.Product = _ProductPlantCosting.Product
                                                                                  and $projection.Plant   = _ProductPlantCosting.Plant

  association [0..1] to A_ProductPlantForecasting as _ProductPlantForecast        on  $projection.Product = _ProductPlantForecast.Product
                                                                                  and $projection.Plant   = _ProductPlantForecast.Plant

  association [0..1] to A_ProductPlantQualityMgmt as _PlantQualityMgmt            on  $projection.Product = _PlantQualityMgmt.Product
                                                                                  and $projection.Plant   = _PlantQualityMgmt.Plant

  association [0..1] to A_ProductPlantSales       as _PlantSales                  on  $projection.Product = _PlantSales.Product
                                                                                  and $projection.Plant   = _PlantSales.Plant



  //new segments

  association [0..1] to A_ProductPlantStorage     as _PlantStorage                on  $projection.Product = _PlantStorage.Product
                                                                                  and $projection.Plant   = _PlantStorage.Plant

  association [0..1] to A_ProductPlantText        as _PlantText                   on  $projection.Product = _PlantText.Product
                                                                                  and $projection.Plant   = _PlantText.Plant

  association [0..*] to A_ProductPlantMRPArea     as _PlantMRPArea                on  $projection.Product = _PlantMRPArea.Product
                                                                                  and $projection.Plant   = _PlantMRPArea.Plant


  association [0..1] to E_Productplant            as _ProductPlantExt             on  $projection.Product = _ProductPlantExt.Product
                                                                                  and $projection.Plant   = _ProductPlantExt.Plant



  association [1..1] to A_Product                 as _Product                     on  $projection.Product = _Product.Product
{

  key Product,
  key Plant,

      PurchasingGroup,
      CountryOfOrigin,
      RegionOfOrigin,
      @ObjectModel.sapObjectNodeTypeReference:'StorageLocation'
      ProductionInvtryManagedLoc,
      @ObjectModel.sapObjectNodeTypeReference:'ProductProfileCode'
      ProfileCode,
      ProfileValidityStartDate,
      AvailabilityCheckType,
      @ObjectModel.sapObjectNodeTypeReference:'FiscalYearVariant'
      FiscalYearVariant,
      @ObjectModel.sapObjectNodeTypeReference:'ProductConsumptionPeriodType'
      PeriodType,
      ProfitCenter,
      Commodity,
      GoodsReceiptDuration,
      MaintenanceStatusName,
      IsMarkedForDeletion,
      @ObjectModel.sapObjectNodeTypeReference:'MRPType'
      MRPType,
      @ObjectModel.sapObjectNodeTypeReference:'MRPController'
      MRPResponsible,
      @ObjectModel.sapObjectNodeTypeReference:'ProdConsumptionValueCategory'
      ABCIndicator,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MinimumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      MaximumLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      FixedLotSizeQuantity,
      ConsumptionTaxCtrlCode,
      IsCoProduct,
      ProductIsConfigurable,
      StockDeterminationGroup,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      StockInTransferQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      StockInTransitQuantity,
      HasPostToInspectionStock,
      IsBatchManagementRequired,
      SerialNumberProfile,
      IsNegativeStockAllowed,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      GoodsReceiptBlockedStockQty,
      HasConsignmentCtrl,
      FiscalYearCurrentPeriod,
      FiscalMonthCurrentPeriod,
      @ObjectModel.sapObjectNodeTypeReference:'ProcurementType'
      ProcurementType,
      // IsPurgAcrossPurgGroup ,      Will be made available with retail

      IsInternalBatchManaged,
      ProductCFOPCategory,
      ProductIsExciseTaxRelevant, //Excise Tax

      @Semantics.unitOfMeasure: true
      BaseUnit,
      //      new fields for odata api

      ConfigurableProduct,
      GoodsIssueUnit,
      MaterialFreightGroup,
      OriginalBatchReferenceMaterial,
      OriglBatchManagementIsRequired,
      ProductIsCriticalPrt,
      @ObjectModel.sapObjectNodeTypeReference:'ProductLogisticsHandlingGroup'
      ProductLogisticsHandlingGroup,
      _StorageLocation,
      _ProductPlantProcurement,
      _ProductWorkScheduling,
      _ProductSupplyPlanning,
      _ProdPlantInternationalTrade,
      _ProductPlantCosting,
      _ProductPlantForecast,
      _PlantQualityMgmt,
      _PlantSales,
      _Product,

      _PlantStorage,
      _PlantText,
      _PlantMRPArea
}