A_ProdVarConfignCharacteristic

DDL: A_PRODVARCONFIGNCHARACTERISTIC Type: view_entity CONSUMPTION Package: VDM_MD_PRODUCT_API_V3

Variant Configuration Characteristic

A_ProdVarConfignCharacteristic is a Consumption CDS View that provides data about "Variant Configuration Characteristic" in SAP S/4HANA. It reads from 1 data source (R_VarConfignCharacteristicTP) and exposes 14 fields with key fields VarConfigurationBusObjectKey, VarConfigurationBusObjectType, VarConfignInstceInternalID, Characteristic. It is exposed through 1 OData service (API_PRODUCT_2). Part of development package VDM_MD_PRODUCT_API_V3.

1 data source(s) Exposed by 1 service(s) 14 fields

Data Sources (1)

SourceAliasJoin Type
R_VarConfignCharacteristicTP R_VarConfignCharacteristicTP projection

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
EndUserText.label Variant Configuration Characteristic view
Metadata.ignorePropagatedAnnotations true view
OData.containment.accessByNavigationOnly true view
OData.entityType.name VarConfignCharacteristic_Type view
ObjectModel.query.implementedBy ABAP:CL_CMD_PRODUCT_VCR_EML_QRY view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
VDM.viewType #CONSUMPTION view
Feature CMD_PM_AVC_READ_RAP view

OData Services (1)

ServiceBindingVersionContractRelease
API_PRODUCT_2

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY VarConfigurationBusObjectKey VarConfigurationBusObjectKey
KEY VarConfigurationBusObjectType VarConfigurationBusObjectType
KEY VarConfignInstceInternalID VarConfignInstceInternalID
KEY Characteristic Characteristic
CharcDataType CharcDataType
CharcTemplate CharcTemplate
Currency Currency
CharcValueUnit CharcValueUnit
VarCnfCharcISOUnit VarCnfCharcISOUnit
IsReadOnly IsReadOnly
EntryIsRequired EntryIsRequired
CharcIsHidden CharcIsHidden
AdditionalValueIsAllowed AdditionalValueIsAllowed
MultipleValuesAreAllowed MultipleValuesAreAllowed 
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.privilegedAssociations: [ '_VariantConfiguration', '_Instance', '_AssignedValue' ]

@EndUserText.label: 'Variant Configuration Characteristic'

@Metadata.ignorePropagatedAnnotations: true

@OData.containment.accessByNavigationOnly: true
@OData.entityType.name: 'VarConfignCharacteristic_Type'

@ObjectModel.query.implementedBy: 'ABAP:CL_CMD_PRODUCT_VCR_EML_QRY'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #TRANSACTIONAL }

@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION
@Feature: 'CMD_PM_AVC_READ_RAP'
define view entity A_ProdVarConfignCharacteristic
  as projection on R_VarConfignCharacteristicTP

{
  key     VarConfigurationBusObjectKey,
  key     VarConfigurationBusObjectType,
  key     VarConfignInstceInternalID,
  key     Characteristic,

          CharcDataType,
          CharcTemplate,
          Currency,

          @Consumption.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VCR_CALC_ELEMTS_CHARC'
          @Semantics.nullValueIndicatorFor: 'Currency'
  virtual CurrencyIsNull           : rap_null_value_indicator,

          CharcValueUnit,

          @Consumption.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VCR_CALC_ELEMTS_CHARC'
          @Semantics.nullValueIndicatorFor: 'CharcValueUnit'
  virtual CharcValueUnitIsNull     : rap_null_value_indicator,

          VarCnfCharcISOUnit,

          @Consumption.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VCR_CALC_ELEMTS_CHARC'
          @Semantics.nullValueIndicatorFor: 'VarCnfCharcISOUnit'
  virtual VarCnfCharcISOUnitIsNull : rap_null_value_indicator,

          IsReadOnly,
          EntryIsRequired,
          CharcIsHidden,
          AdditionalValueIsAllowed,
          MultipleValuesAreAllowed,

          /* Associations */
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _VariantConfiguration : redirected to A_ProdVariantConfiguration,

          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _Instance             : redirected to parent A_ProdVarConfignInstance,

          @OData.containment.containsTarget: true
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _AssignedValue        : redirected to composition child A_ProdVarConfignAssignedValue
}

Learn More