A_ProcessOrder_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Process Order'
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'ManufacturingOrder'
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

define view entity A_ProcessOrder_2 as select from I_MfgOrderWithStatus

  association [0..*] to A_ProcessOrderOperation_2      as _ProcessOrderOperation             // Operations

                                                       on  $projection.ManufacturingOrder = _ProcessOrderOperation.ManufacturingOrder
                                                      
  association [0..*] to A_ProcessOrderComponent_2      as _ProcessOrderComponent             // Components

                                                       on  $projection.ManufacturingOrder = _ProcessOrderComponent.ManufacturingOrder
                                                      
  association [0..*] to A_ProcessOrderItem_2           as _ProcessOrderItem                  // Items

                                                       on  $projection.ManufacturingOrder = _ProcessOrderItem.ManufacturingOrder
                                                      
  association [0..*] to A_ProcessOrderStatus_2         as _ProcessOrderStatus                // Status

                                                       on  $projection.ManufacturingOrder = _ProcessOrderStatus.ManufacturingOrder
                                                      
  association [0..*] to A_ProcessOrderProdnRsceTools_2 as _ProcessProdnRsceTools             // PRT

                                                       on  $projection.ManufacturingOrder = _ProcessProdnRsceTools.ManufacturingOrder
                                                     
  association [1..1] to E_LogisticsOrder               as _Extension                         // Extensibility

                                                       on  $projection.ManufacturingOrder = _Extension.OrderID
                                                                                                                                                     
{
      // Key

  @ObjectModel.sapObjectNodeTypeReference: 'ProductionOrder'    
  key cast(ManufacturingOrder                          as co_bid preserving type) as ManufacturingOrder,

      // Category and Type

      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderCategory'
      ManufacturingOrderCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderType'
      ManufacturingOrderType,
      
      // Text

      @Semantics.text:true
      _LongText.PlainLongText                            as OrderLongText,                     // New field in CE2008


      // Attributes

      @ObjectModel.sapObjectNodeTypeReference: 'ManufacturingOrderImportance'
      ManufacturingOrderImportance,                                                            // New change field in CE2008      


      // Status

      OrderIsCreated,
      OrderIsReleased,
      OrderIsPrinted,
      OrderIsConfirmed,
      OrderIsPartiallyConfirmed,
      OrderIsDelivered,
      OrderIsDeleted,
      OrderIsPreCosted,
      SettlementRuleIsCreated,
      OrderIsPartiallyReleased,
      OrderIsLocked,
      OrderIsTechnicallyCompleted,
      OrderIsClosed,
      OrderIsPartiallyDelivered,
      OrderIsMarkedForDeletion,
      SettlementRuleIsCrtedManually,
      OrderIsScheduled,
      OrderHasGeneratedOperations,
      OrderIsToBeHandledInBatches,
      MaterialAvailyIsNotChecked,

      // Admin

      CreationDate as MfgOrderCreationDate,
      CreationTime as MfgOrderCreationTime,
      case LastChangeDate
        when '00000000' then                                                                   // not changed yet, use create

          concat(CreationDate,CreationTime)
        else
          concat(LastChangeDate,LastChangeTime)
      end                                                as LastChangeDateTime,                // eTag


      // Header Material data          

      Material,
      @ObjectModel.sapObjectNodeTypeReference: 'StorageLocation'
      StorageLocation,                                                                         // New change field in CE2008

      @Semantics.text: true         
      GoodsRecipientName,                                                                      // New change field in CE2008

      @Semantics.text: true  
      UnloadingPointName,                                                                      // New change field in CE2008

      @ObjectModel.sapObjectNodeTypeReference: 'InventoryUsabilityCode'
      InventoryUsabilityCode,                                                                  // New change field in CE2008       

      MaterialGoodsReceiptDuration,                                                            // New change field in CE2008

      QuantityDistributionKey,                                                                 // New change field in CE2008

      StockSegment,                                                                            // New change field in CE2008

                    
      // Assignments

      MfgOrderInternalID                                 as OrderInternalBillOfOperations,  
      ProductionPlant,
      PlanningPlant                                      as Plant,
      @ObjectModel.sapObjectNodeTypeReference: 'MRPArea'
      MRPArea,
      @ObjectModel.sapObjectNodeTypeReference: 'MRPController'
      MRPController,                                                                           // New change field in CE2008    

      @ObjectModel.sapObjectNodeTypeReference: 'ProductionSupervisor'
      ProductionSupervisor,
      ProductionVersion,                                                                       // New change field in CE2008  

      @ObjectModel.sapObjectNodeTypeReference: 'PlannedOrder'
      PlannedOrder,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesOrder'
      SalesOrder,
      SalesOrderItem,
      @ObjectModel.sapObjectNodeTypeReference: 'SchedulingType'
      BasicSchedulingType,
      ManufacturingObject,
      ProductConfiguration,                                                                    // New field in CE2008

      OrderSequenceNumber,                                                                     // New change field in CE2008

 
      // Assignments FI/CO

      @ObjectModel.sapObjectNodeTypeReference: 'BusinessArea'
      BusinessArea,                                                                            // New change field in CE2008                                                                                                     

      @ObjectModel.sapObjectNodeTypeReference: 'CompanyCode'
      CompanyCode,
      @ObjectModel.sapObjectNodeTypeReference: 'ProfitCenter'
      ProfitCenter,                                                                            // New change field in CE2008

      @EndUserText.label: 'Actual Costing Variant'
      @ObjectModel.sapObjectNodeTypeReference: 'CostingVariant'
      ActualCostsCostingVariant,
      @EndUserText.label: 'Planned Costing Variant'
      PlannedCostsCostingVariant,
      FunctionalArea,                            
                   
      // Dates and Times

      MfgOrderPlannedStartDate,
      MfgOrderPlannedStartTime,
      MfgOrderPlannedEndDate,
      MfgOrderPlannedEndTime,
      MfgOrderScheduledStartDate,
      MfgOrderScheduledStartTime,
      MfgOrderScheduledEndDate,
      MfgOrderScheduledEndTime,
      MfgOrderActualReleaseDate,
                 
      // Quantities and UoM

      ProductionUnit,
      _ProductionUnit.UnitOfMeasureISOCode               as ProductionUnitISOCode,             // CE2105 

      _ProductionUnit.UnitOfMeasureSAPCode               as ProductionUnitSAPCode,             // CE2105      

      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedTotalQty                            as TotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedYieldQty,
      
      // Associations

      _SalesDocument._SoldToParty.CustomerName           as CustomerName,
      _WBSElementBasicData.WBSElementExternalID,                                               // New field in CE2008

      _ProcessOrderOperation,
      _ProcessOrderComponent,
      _ProcessOrderStatus,
      _ProcessOrderItem,
      _ProcessProdnRsceTools

}
where
  ManufacturingOrderCategory = '40';