A_ProcessOrder

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'API Process Order'
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'ProcessOrder'
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API

define view entity A_ProcessOrder as select from I_MfgOrderWithStatus

  association [0..*] to A_ProcessOrderOperation     as _ProcessOrderOperation // Operations

                                                                          on  $projection.ProcessOrder = _ProcessOrderOperation.ManufacturingOrder
  association [0..*] to A_ProcessOrderComponent     as _ProcessOrderComponent // Components

                                                                          on  $projection.ProcessOrder = _ProcessOrderComponent.ManufacturingOrder
  association [0..*] to A_ProcessOrderItem          as _ProcessOrderItem // Items

                                                                          on  $projection.ProcessOrder = _ProcessOrderItem.ManufacturingOrder
  association [0..*] to A_ProcessOrderStatus        as _ProcessOrderStatus // Status

                                                                          on  $projection.ProcessOrder = _ProcessOrderStatus.ManufacturingOrder
  association [1..1] to E_LogisticsOrder            as _Extension           // Extensibility

                                                                          on  $projection.ProcessOrder = _Extension.OrderID                                                                          
{

      //General Information

      @EndUserText.label: 'Process Order'
  key ManufacturingOrder                                                                                                                                                                                 as   ProcessOrder,
      ProductionPlant,
      @EndUserText.label: 'Operation Task List No.'
      MfgOrderInternalID as OrderInternalBillOfOperations,

      // Status

      OrderIsCreated,
      OrderIsReleased,
      OrderIsPrinted,
      OrderIsConfirmed,
      OrderIsPartiallyConfirmed,
      OrderIsDelivered,
      OrderIsDeleted,
      OrderIsPreCosted,
      SettlementRuleIsCreated,
      OrderIsPartiallyReleased,
      OrderIsLocked,
      OrderIsTechnicallyCompleted,
      OrderIsClosed,
      OrderIsPartiallyDelivered,
      OrderIsMarkedForDeletion,
      SettlementRuleIsCrtedManually,
      OrderIsScheduled,
      OrderHasGeneratedOperations,
      OrderIsToBeHandledInBatches,
      MaterialAvailyIsNotChecked,
      
      Material,

      _Material._Text[1: Language=$session.system_language].MaterialName                                                                                                                                 as   MaterialName,
      ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedTotalQty                                                                                                                                                                            as   TotalQuantity,
      ManufacturingOrderType,
      MRPArea,
      ManufacturingObject,

      PlanningPlant                                                                                                                                                                                      as   Plant,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderConfirmedYieldQty,
      //Dates/Times

      MfgOrderPlannedStartDate,
      MfgOrderPlannedStartTime,
      MfgOrderPlannedEndDate,
      MfgOrderPlannedEndTime,
      MfgOrderScheduledStartDate,
      MfgOrderScheduledStartTime,
      MfgOrderScheduledEndDate,
      MfgOrderScheduledEndTime,

      //       Assignments

      SalesOrder,
      SalesOrderItem,
      PlannedOrder,
      _SalesDocument._SoldToParty.CustomerName,
      cast( _WBSElement.WBSElement as rcpe_ps_posnr preserving type )                                                                                                                                    as   WBSElement,

      WBSElementInternalID,
      @Semantics.text: true
      _WBSElement.WBSDescription,
      CompanyCode,

      FunctionalArea,
      @EndUserText.label: 'Planned Costing Variant'
      PlannedCostsCostingVariant,
      
      @EndUserText.label: 'Actual Costing Variant'
      ActualCostsCostingVariant,

      _MRPController.UserID,
      ProductionVersion,
 
      //Responsibilities

      MRPController,
      @EndUserText.label: 'Production Supervisor'
      ProductionSupervisor,
      ManufacturingOrderCategory,
      _ProcessOrderOperation,
      _ProcessOrderComponent,
      _ProcessOrderItem,
      _ProcessOrderStatus,
      
    // added for extension of API_PROCESS_ORDERS

      BusinessArea,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      MfgOrderPlannedScrapQty,
      ProfitCenter,
      ManufacturingOrderImportance,
      OrderSequenceNumber,
      CreationDate as MfgOrderCreationDate,
      CreationTime as MfgOrderCreationTime,
      MfgOrderActualReleaseDate,

      // additional items

      GoodsRecipientName,
      MaterialGoodsReceiptDuration,
      InventoryUsabilityCode,
      UnloadingPointName,
      QuantityDistributionKey,
      StockSegment,
      StorageLocation,
          
      
      case LastChangeDate
        when '00000000' then  // not changed yet, use create

          concat(CreationDate,CreationTime)
        else
          concat(LastChangeDate,LastChangeTime)
      end as LastChangeDateTime,    
      BasicSchedulingType
}
where
  ManufacturingOrderCategory = '40';