A_InsurancePolicyContract

@EndUserText.label: 'Contract under Policy'
@VDM: {
  viewType:#CONSUMPTION,
  lifecycle.contract.type:#PUBLIC_REMOTE_API,
  usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
}
@AccessControl: {
authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_Adjustment',
                            '_Beneficiary',
                            '_Benefit',
                            '_CBCPayer',
                            '_Charge',
                            '_Clause',
                            '_Coverage',
                            '_CoveragePackage',
                            '_Creditor',
                            '_Deductible',
                            '_ExternalReference',
                            '_InsuredObject',
                            '_Limit',
                            '_Premium',
                            '_PremiumPayer',
                            '_ProcessDependentCondition',
                            '_RelatedContract',
                            '_SurchargeDiscount',
                            '_ValueDate' ]
}
@Metadata: {
  ignorePropagatedAnnotations:true
}
@ObjectModel: {
   semanticKey: [ 'InsurPlcyInsurContr' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@OData.entityType.name: 'InsurancePolicyContract_Type'
define root view entity A_InsurancePolicyContract
  provider contract transactional_query
  as projection on R_InsurPlcyContractTP as Contract
{
                @ObjectModel.virtualElement: true
                @ObjectModel.filter.transformedBy: 'ABAP:/PM0/CL_ABT_F_CONTR_PLCY_ID'
  key           InsurPlcyUUID,
  key           InsurPlcyInsurContr,
                InsurPlcyJrnlNmbr,
                InsurPlcyJrnlEndNmbr,
                InsurPlcyProductPackageID,
                InsrrIDByInsrr,
                InsurPlcyAuthznSlsProductGroup,
                @ObjectModel.virtualElement: true
                @ObjectModel.filter.transformedBy: 'ABAP:/PM0/CL_ABT_VE_F_INQRY_CONTR'
                @ObjectModel.virtualElementCalculatedBy: 'ABAP:/PM0/CL_ABT_VE_INQRY_DTE'
  virtual       InsurancePolicyEffectiveDate : /pm0/abd_effective_dt,
                @ObjectModel.virtualElement: true
                @ObjectModel.filter.transformedBy: 'ABAP:/PM0/CL_ABT_VE_F_ORDER_CONTR'
                @ObjectModel.virtualElementCalculatedBy: 'ABAP:/PM0/CL_ABT_VE_ORDER_DTE'
  virtual       InsurPlcyOrderNumber         : /pm0/abj_orderno_id,
                InsurPlcyContractIsCanceled,
                InsurancePolicyContract,
                InsurPlcyContrOldContractID,
                InsurPlcyContrNmbrOfCoverage,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyLineOfBusiness'
                InsurPlcyLineOfBusiness,
                InsurPlcyContractStartDateTime,
                InsurPlcyContractEndDateTime,
                InsurPlcyContrCommentID,
                @ObjectModel.virtualElement: true
                @ObjectModel.virtualElementCalculatedBy: 'ABAP:/PM0/CL_ABP_VDM_VE_NOTE_LTXT'
                LongText,
                TextObjectCategory,
                TextObjectKey,
                Language,
                InsurPlcyContractCompanyID,
                InsurPlcyContractPolicyStatus,
                InsurPlcyContractCategory,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyContractStatus'
                InsurPlcyContrLifeCycleStatus,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurContrCancellationReason'
                InsurPlcyContrCanclnRsn,
                InsurPlcyContrCanclnDateTime,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyReversalAcctgVariant'
                InsurPlcyContractAcctVariant,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyPremiumPaymentStatus'
                InsurancePolicyContractStatus,
                InsurPlcyContrSuspensionType,
                InsurPlcyContrSuspnStrtDteTme,
                InsurPlcyBsCvrgSuspnEndDteTime,
                InsurPlcyContrMatlStartDate,
                InsurPlcyContrExtensionVariant,
                InsPlcyContrIsCoPensnSchmPmtd,
                InsurPlcyContrIsAdjustment,
                InsurPlcyContrTariffVariant,
                InsurPlcyContrIsManualRating,
                InsurPlcyContrGenerationDate,
                InsurPlcyContrProRtTmpVariant,
                InsurPlcyProductTemplate,
                InsurPlcyContrExprtnAgeValue,
                InsurPlcyContractRejectionDate,
                InsurPlcyContrRejectionReason,
                InsPlcyContrSrceDocStsDateTime,
                InsurPlcyContrInsurObjectID,
                InsPlcyContrHasPndgCommsnCase,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCommsnPostingCode'
                InsurPlcyContrCommsnPostgCode,
                InsurPlcyContractIsLifetime,
                InsurPlcyPrvsnlContractNumber,
                InsurPlcyCountry,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyTaxPayerInfo'
                InsurPlcyContrTxblPersnInfo,
                InsurPlcyContractIsGeneration,
                InsurPlcyContractRegion,
                InsurPlcyContrScpOfPremTxn,
                InsurPlcyContrIsAlreadyIncld,
                InsPlcyContrDiffntMttyDayMnth,
                InsurPlcyContrFirstProcessorID,
                InsurPlcyContrSecondProcsrID,
                InsurPlcyContrRefusalRsnText,
                InsurPlcyContrIsCheckPending,
                InsurPlcyContrIsAutomProdChg,
                InsurPlcyContrTransferType,
                InsurPlcyContrConversionType,
                InsurPlcyContrAutomProdChgDate,
                InsurPlcyContrGnrtnDetnDate,
                InsurPlcyContractIsDuplicate,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyShiftMode'
                InsurPlcyContractShiftType,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyFinalRenewalDecision'
                InsurPlcyContrFnlRnwlDcsn,
                InsurPlcyContrRnwlRefusalRsn,
                InsurPlcyContrRenewalDate,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyRenewalDecision'
                InsurPlcyContrRnwlDecision,
                InsurPlcyContrRnwlPrepLastDate,
                @ObjectModel.sapObjectNodeTypeReference: 'Currency'
                InsurPlcyContractCurrency,
                @Semantics.amount.currencyCode: 'InsurPlcyContractCurrency'
                InsurPlcyContrAbsltMnlPMLAmt,
                InsurPlcyContrRltvMnlPMLRate,
                InsurPlcyContrIsMnlPostprocg,
                InsurPlcyContrMnlFldLblAmtText,
                InsurPlcyContrEnhancedLife,
                InsurPlcyContrLoanLimitRate,
                InsPlcyContrAutomPremLoanOptn,
                @Semantics.amount.currencyCode: 'InsurPlcyContractCurrency'
                InsurPlcyContrMaxLoanAmount,
                InsurPlcyContractLocalCurrency,
                InsurPlcyContractRiskCurrency,
                InsurPlcyContrInvoiceCurrency,
                InsurPlcyContrRiskExchRate,
                InsurPlcyContrRiskExchRateDte,
                InsurPlcyContrInvcCrcyExchRate,
                InsurPlcyContrInvcExchRateDte,
                @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyExchangeRateDetn'
                InsurPlcyContrExchRateDetn,
                InsurPlcyContrRskApplExchRate,
                InsPlcyContrRskApplExchRateDte,
                InsurPlcyContrInvcApplExchRate,
                InsurPlcyInvcApplExchRateDate,
                InsurPlcyContrQuotationVariant,
                InsurPlcyBusinessObject,
                LastChangeDateTime,
                InsurPlcyGenContrEndDate,
                InsurPlcyGenContrInsurDurn,
                @Semantics.amount.currencyCode: 'InsurPlcyGenContrCrcy'
                InsurPlcyGenContrLossAbsltAmt,
                InsurPlcyGenContrMaxLossInPct,
                @ObjectModel.sapObjectNodeTypeReference: 'Currency'
                InsurPlcyGenContrCrcy,
                InsurPlcyGenContrMnlFldLblTxt,
                InsPlcyGenContrPostprocgIsRqd,
                InsurPlcyLifeContrEmplJoinDte,
                InsurPlcyLifeContrCalcRuleType,
                InsurPlcyLifeContrCoPensnSchm,
                InsPlcyLifeContrGuaranteedOptn,
                @Semantics.amount.currencyCode: 'InsurPlcyLifeContrCurrency'
                InsurPlcyLifeContrSpcfdAddlAmt,
                InsurPlcyLifeContrRnstmntSpec,
                InsPlcyContrDvdndCrdtIsTrnsfd,
                InsurPlcyLifeContrSrrndrValCat,
                InsurPlcyLifeContrPrtlSrrndr,
                InsurPlcyLifeContrBnftIncrSpec,
                InsurPlcyLifeContrPlcyDurnSpec,
                InsurPlcyLifeContrAvailPremShr,
                InsurPlcyLifeContrPremHasExmpt,
                InsurPlcyLifeContrPremExmpRsn,
                @ObjectModel.sapObjectNodeTypeReference: 'Currency'
                InsurPlcyLifeContrCurrency,
                InsurPlcyContrFreeLookIsExists,
                InsurPlcyContrFreeLookEndDte,
                @Semantics.amount.currencyCode: 'InsurPlcyLifeContrCurrency'
                InsurPlcyLifeContrEntrFeeAmt,
                InsPlcyLifeContrEntrFeeIsPaid,
                InsurPlcyLifeContrFreeLookPerd,
                InsurPlcyLifeContrModifCatAdd,
                InsurPlcyLifeContrModifCatChg,
                InsurPlcyLifeContrModifCat,
                InsurPlcyLifeContrAdjmtTrifVar,
                InsurPlcyLifeContrAddlTrifVar,
                InsurPlcyLifeContrIncrTrifVar,
                /* Associations */
                _Adjustment                : redirected to A_InsurPlcyContractAdjustment,
                _Beneficiary               : redirected to A_InsurPlcyContrBeneficiary,
                _Benefit                   : redirected to A_InsurPlcyContractBenefit,
                _CBCPayer                  : redirected to A_InsurPlcyCBCPayer,
                _Charge                    : redirected to A_InsurPlcyContractCharge,
                _Clause                    : redirected to A_InsurPlcyContractClause_2,
                _Coverage                  : redirected to A_InsurPlcyContractCoverage_2,
                _CoveragePackage           : redirected to A_InsurPlcyContrCvrgPackage,
                _Creditor                  : redirected to A_InsurPlcyContractCreditor,
                _Deductible                : redirected to A_InsurPlcyContrDeductible_2,
                _ExternalReference         : redirected to A_InsurPlcyContrExtReference,
                _InsuredObject             : redirected to A_InsurPlcyContrInsrdObj_2,
                _Limit                     : redirected to A_InsurPlcyContractLimit_2,
                _Premium                   : redirected to A_InsurPlcyContractPremium,
                _PremiumPayer              : redirected to A_InsurPlcyPremiumPayer_2,
                _ProcessDependentCondition : redirected to A_InsurPlcyProcDpCnd,
                _RelatedContract           : redirected to A_InsurPlcyContrReltdContr,
                _SurchargeDiscount         : redirected to A_InsurPlcyContrSuDsc,
                _ValueDate                 : redirected to A_InsurPlcyContrValDate
}