A_HandlingUnit_2

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}

@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_REMOTE_API,
    usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
}

@OData.entitySet.name : 'HandlingUnit'

@EndUserText.label: 'Handling Unit'


define root view entity A_HandlingUnit_2
  provider contract transactional_query
  as projection on R_HandlingUnitTP as HandlingUnit
{
  key HandlingUnitExternalID,
  key Warehouse,

      PackagingMaterial,
      PackagingMaterialType,

      Plant,
      StorageLocation,
      ShippingPoint,

      ParentHandlingUnitNumber,
      HighestLevelHandlingUnitNumber,

      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      GrossWeight,
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      NetWeight,
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      HandlingUnitMaxWeight,
      @Semantics.unitOfMeasure:true
      WeightUnit,

      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareWeightUnit'
      HandlingUnitTareWeight,
      @Semantics.unitOfMeasure:true
      HandlingUnitTareWeightUnit,

      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      GrossVolume,
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitNetVolume,
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitMaxVolume,
      @Semantics.unitOfMeasure:true
      VolumeUnit,

      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
      HandlingUnitTareVolume,
      //      HandlingUnitVolumeTolerance,

      @Semantics.unitOfMeasure:true
      HandlingUnitTareVolumeUnit,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
      HandlingUnitLength,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
      HandlingUnitWidth,
      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
      HandlingUnitHeight,
      @Semantics.unitOfMeasure:true
      UnitOfMeasureDimension,

      HandlingUnitReferenceDocument,   @EndUserText.label:'Reference document for handling unit'
      HandlingUnitPackingObjectType as HandlingUnitRefDocType,
      HandlingUnitHasCrossRefDoc,      

      PackingInstruction,        @EndUserText.label:'Packing Instruction'
       
  
      HandlingUnitSecondExternalId,

      CreatedByUser,
      CreationDateTime,  @EndUserText.label:'Date and time of creation'
      LastChangedByUser,
      LastChangeDateTime, @EndUserText.label:'Date and time of last change'


      /* EWM specific fields */
      StorageType,
      StorageSection,
      StorageBin,
      EWMResource,
      
      EWMConsolidationGroup,
      HandlingUnitIsClosed,
      // EWM fields Process Oriented Storage Control (POSC) 

      // E.g., After packing create a warehouse task to move a HU from a work center to the staging/goods issue area

      @Feature: 'BF:API_FULLSCOPE'
      ExternalStorageProcessStep,
      @Feature: 'BF:API_FULLSCOPE'
      StorageProcess,
      @Feature: 'BF:API_FULLSCOPE'
      EWMHUProcessStepIsCompleted,
      // EWM fields HU Process Status

      EWMHandlingUnitIsPlanned,
      EWMHandlingUnitIsInStock,
      @Feature: 'BF:API_FULLSCOPE'
      EWMHandlingUnitIsUnloaded,
      EWMHandlingUnitIsLoaded,
      @Feature: 'BF:API_FULLSCOPE'
      EWMTranspUnitIsAssigned,
      // EWM fields HU Blocked Status

      EWMHUContentChangeIsBlocked,
      EWMHUMovementChangeIsBlocked,
      EWMHUAttributeChangeIsBlocked,
      EWMHUPostingChangeIsBlocked,
      EWMHUIsBlockedByCustoms,
      @Feature: 'BF:API_FULLSCOPE'
      EWMHUIsPackedForShipping,

      /* Compositions */
      _HandlingUnitItem          : redirected to composition child A_HandlingUnitItem_2,
      @Semantics.valueRange.maximum: '1'  
      _HandlingUnitReferenceDoc  : redirected to composition child A_HandlingUnitReferenceDoc,
      _HandlingUnitAlternativeID : redirected to composition child A_HandlingUnitAlternativeId
}