A_HandlingUnitHeaderDelivery

@AbapCatalog.sqlViewName: 'AHUHDRDLV'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #L
}
@VDM.viewType: #BASIC

@EndUserText.label: 'Handling Unit Header for Delivery'


define root view A_HandlingUnitHeaderDelivery
  as select from I_HandlingUnitHeader
    
//  association [0..*] to A_HandlingUnitItemDelivery as _HandlingUnitItem on $projection.HandlingUnitInternalID = _HandlingUnitItem.HandlingUnitInternalID

 composition [0..*] of A_HandlingUnitItemDelivery as  _HandlingUnitItem

  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to A_OutbDeliveryHeader_1 as _DeliveryDocumentHeader on $projection.DeliveryDocument = _DeliveryDocumentHeader.DeliveryDocument
  
  association [0..1] to I_PackingInstructionHeader as _PackingInstructionHeader on $projection.PackingInstruction = _PackingInstructionHeader.PackingInstructionSystemUUID
    
  //Extensibility

  association [0..1] to E_HandlingUnitHeader  as _Extension on  $projection. HandlingUnitExternalID = _Extension.HandlingUnitExternalID

{
      //I_handlingUnitHeader

  key HandlingUnitInternalID,
      HandlingUnitExternalID,
      HandlingUnitExternalIdType,
      PackagingMaterial,
      Warehouse,
      ShippingPoint,
      
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      GrossWeight,
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      NetWeight,
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      HandlingUnitMaxWeight,
      @Semantics.unitOfMeasure:true    
      WeightUnit,
      
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareWeightUnit'
      HandlingUnitTareWeight,
      @Semantics.unitOfMeasure:true    
      HandlingUnitTareWeightUnit,
      
      //HandlingUnitWeightTolerance, -> No unitOfMeasure 

      
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      GrossVolume,
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitNetVolume,
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitMaxVolume,
      @Semantics.unitOfMeasure:true    
      VolumeUnit,
      
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
      HandlingUnitTareVolume,
      @Semantics.unitOfMeasure:true    
      HandlingUnitTareVolumeUnit,
      
      //HandlingUnitVolumeTolerance,  -> No unitOfMeasure    


      CreationDate,
      CreationTime,
      CreatedByUser,
      
      LastChangeDate,
      LastChangeTime,
      LastChangedByUser,
            
      HandlingUnitGroup1,
      HandlingUnitGroup2,
      HandlingUnitGroup3,
      HandlingUnitGroup4,
      HandlingUnitGroup5,
      
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitUoMDimension'
      HandlingUnitLength,
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitUoMDimension'
      HandlingUnitWidth,
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitUoMDimension'
      HandlingUnitHeight,
      @Semantics.unitOfMeasure:true
      UnitOfMeasureDimension as HandlingUnitUoMDimension,
      
      HandlingUnitBaseUnitOfMeasure,
      HandlingUnitContentDescription,
      PackagingMaterialType,
      PackagingMaterialGroup,
      PackagingMaterialCategory,
      HandlingUnitSecondExternalId,
      HandlingUnitLowerLevelRefer,
      HandlingUnitInternalStatus,
      
      @Consumption.hidden: true
      PackingInstruction,
      _PackingInstructionHeader.PackingInstructionNumber as PackingInstructionNumber,
      
      /* Associations */
      //I_handlingUnitHeader

     // _HandlingUnitHistory, -> not yet supported

      
      //_Item,

// associations not needed for API      

//      _LoadingPoint,

//      _PackagingMaterial,

//      _PackagingMaterialCategory,

//      _PackagingMaterialGroup,

//      _PackagingMaterialType,

//      _PackingObjectType,

//      _Plant,

//      _SalesDocumentItemCategory,

//      _SalesOrganization,

//      _ShippingPoint,

//      _StorageLocation,

//      _UnitOfMeasureDimension,

//      _VolumeUnit,

//      _VolumeUnitTare,

//      _WeightUnit,

//      _WeightUnitTare,


      cast(HandlingUnitPackingObjectKey as vbeln) as DeliveryDocument,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]
      _DeliveryDocumentHeader,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
       _HandlingUnitItem
      
} where HandlingUnitInternalStatus <> '0060' and ( HandlingUnitPackingObjectType = '01' or HandlingUnitPackingObjectType = '03' )