A_EHSRiskControlForSafetyInfo

@AbapCatalog.sqlViewName: 'AEHSRSKCTRLSRI'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Risk Controls for Safety Relevant Information'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  representativeKey: 'EHSControlInstanceUUID',
  usageType:{ serviceQuality: #D,         
              sizeCategory:   #M,         
              dataClass:      #MIXED }
}
define view A_EHSRiskControlForSafetyInfo as select from I_EHSRiskControl as EHSRiskControl
  association [1..*] to A_EHSCtrlTitleText         as _EHSCtrlTitleText         on $projection.EHSControlUUID       = _EHSCtrlTitleText.EHSControlUUID
  association [1..*] to A_EHSCtrlCatalogText       as _EHSCtrlCatalogText       on $projection.EHSControlCatalog    = _EHSCtrlCatalogText.EHSControlCatalog
  association [0..*] to A_EHSCtrlTypeText          as _EHSCtrlTypeText          on $projection.EHSControlType       = _EHSCtrlTypeText.EHSControlType 
  association [0..*] to A_EHSCtrlSubtypeText       as _EHSCtrlSubtypeText       on $projection.EHSControlSubtype    = _EHSCtrlSubtypeText.EHSControlSubtype
  association [0..*] to A_EHSCtrlImplmtnStatusText as _EHSCtrlImplmtnStatusText on $projection.EHSControlImplStatus = _EHSCtrlImplmtnStatusText.EHSControlImplStatus
{
  key EHSControlInstanceUUID,

  cast( EHSRiskUUID as ehhss_risk_uuid_ref preserving type )                as EHSRiskUUID,
  @ObjectModel.text.association: '_EHSCtrlTitleText'
  EHSRiskControl.EHSControlUUID,
  
  @ObjectModel.text.association: '_EHSCtrlCatalogText'
  cast( _EHSControl.EHSControlCatalog as ehfnd_control_code_nc preserving type ) as EHSControlCatalog,
  
  @ObjectModel.text.association: '_EHSCtrlTypeText'
  cast( _EHSControl._EHSCatalog.EHSControlType as ehhss_control_type_code preserving type ) as EHSControlType,
  
  @ObjectModel.text.association: '_EHSCtrlSubtypeText'
  cast ( _EHSControl._EHSCatalog.EHSControlSubtype as ehhss_control_subtype_code preserving type ) as EHSControlSubtype,
  
  @ObjectModel.text.association: '_EHSCtrlImplmtnStatusText'
  EHSControlImplStatus,
  
  ResponsiblePerson, 
  
  //exposed text associations

  _EHSCtrlTitleText,
  _EHSCtrlCatalogText,
  _EHSCtrlTypeText,
  _EHSCtrlSubtypeText,
  _EHSCtrlImplmtnStatusText
  
} where EHSControlIsAdhoc != 'X'                                  //controls from control catalog only

  and (EHSControlImplStatus = '03' or EHSControlImplStatus = '05')//only controls that are "implemented" or "existing"

  and _EHSRiskRevision.EHSRiskStatus = '03'                       //display controls for approved risks