A_Defect2

@EndUserText.label: 'Defect'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #B
  },
  representativeKey: 'DefectInternalID',
  semanticKey: ['Defect']
}
@OData: {
  entitySet:  { name: 'Defect' },
  entityType: { name: 'Defect_Type' }
}
@Metadata.ignorePropagatedAnnotations: true

define root view entity A_Defect2 
  provider contract transactional_query
  as projection on R_DefectTP as _Defect

  association [1..1] to E_NotificationItem as _Extension on  $projection.DefectInternalID = _Extension.Notification
                                                         and _Extension.NotificationItem = '0000'
{
  key _Defect.DefectInternalID,
  
      _Defect.Defect,
      _Defect.DefectCategory,
      _Defect.CreatedByUser,
      _Defect.CreationDate,
      @Semantics.time: true
      _Defect.CreationTime, 
      _Defect.LastChangedByUser,
      _Defect.LastChangeDate,
      @Semantics.time: true
      _Defect.LastChangeTime, 
      _Defect.DefectText,
      _Defect.DefectCodeCatalog,
      _Defect.DefectCodeGroup,
      _Defect.DefectCode,
      @Consumption.hidden: true      
      _Defect.DefectCodeVersion, // Do we need this field? Value is fix '0001' for each case 

      _Defect.DefectLocationCatalog   as DefectObjectCodeCatalog,
      _Defect.DefectLocationCodeGroup as DefectObjectCodeGroup,
      _Defect.DefectLocationCode      as DefectObjectCode,
      @Consumption.hidden: true
      _Defect.DefectLocationCodeVersion as DefectObjectCodeVersion, // Do we need this field? Value is fix '0001' for each case

      
      @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'
      _Defect.DefectiveQuantity,
      @Semantics.unitOfMeasure: true
      _Defect.DefectiveQuantityUnit,
      
      _Defect.ProductionOrder as ManufacturingOrder,
      _Defect.OrderInternalID,
      cast( _Defect.ProductionOrderOperation as vdm_vornr preserving type ) as ManufacturingOrderOperation,
      _Defect.ProductionOrderSequence as ManufacturingOrderSequence,
      
      _Defect.DefectClass,
      _Defect.NumberOfDefects,
      _Defect.InspPlanOperationInternalID,
      _Defect.InspectionCharacteristic,
      _Defect.InspectionSubsetInternalID,
      _Defect.MaterialSample,
      
//     Work center data

      _Defect.WorkCenterTypeCode,  
      _Defect.MainWorkCenterInternalID,  
      _Defect.MainWorkCenterPlant,
      _Defect.MainWorkCenter,
      
//      _Defect.Equipment, 

//      _Defect.FunctionalLocation,

       
      @Semantics.booleanIndicator: true
      _Defect.IsDeleted,
      _Defect.DefectOrigin,
      _Defect.Material, 
      _Defect.Batch,
      _Defect.Plant,
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.StorageLocation,
      @ObjectModel.sapObjectNodeTypeReference: 'InspectionLot'
      _Defect.InspectionLot,
//      _Defect.CatalogProfile,

      
      _Defect.ChangedDateTime,
      _Defect.DefectLifecycleStatus,
      _Defect.ProblemAnalysisStatus,
      
      _Defect.QualityIssueReference,
      _Defect.MasterLanguage,
      _Defect.DefectUUID,
      
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.ProductionSupplyArea,
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.EWMWarehouse,
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.SourceStorageType,
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.SourceStorageBin,
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.WarehouseLogicalSystem,
      
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.DefectCausedBy,
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _Defect.CostCenter,
      
      /* Association */
      @Feature: 'QM_CE_DEFECT_WAREHOUSE_DEF'
      _DefectAffectedObject : redirected to composition child A_DefectAffectedObject,
      _DefectLongText       as _DefectDetailedDescription : redirected to composition child A_DefectDetailedDescriptionT,
      
      @Consumption.hidden: true
      _Defect._InspectionLot as _InspectionLot 
}