A_CustomerSalesArea

@AbapCatalog.sqlViewName: 'ACUSTSALESAREA'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:#MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Sales Area'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:#PUBLIC_REMOTE_API
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.createEnabled:true
@ObjectModel.updateEnabled:true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
//@ObjectModel.deleteEnabled:true


define view A_CustomerSalesArea as select from I_CustomerSalesArea

  association [0..1] to E_BPSALESAREA_D as _SalesExtension on  $projection.Customer = _SalesExtension.Customer
                                                           and $projection.SalesOrganization = _SalesExtension.SalesOrganization
                                                           and $projection.DistributionChannel = _SalesExtension.DistributionChannel
                                                           and $projection.Division = _SalesExtension.Division

  association [1..1] to A_Customer as _Customer on $projection.Customer = _Customer.Customer
 
  association [0..*] to A_CustomerSalesAreaTax as _SalesAreaTax on  $projection.Customer = _SalesAreaTax.Customer 
                                                                and $projection.SalesOrganization = _SalesAreaTax.SalesOrganization 
                                                                and $projection.DistributionChannel = _SalesAreaTax.DistributionChannel
                                                                and $projection.Division = _SalesAreaTax.Division 
                                                               
  association [0..*] to A_CustSalesPartnerFunc as _PartnerFunction on  $projection.Customer = _PartnerFunction.Customer  
                                                                   and $projection.SalesOrganization = _PartnerFunction.SalesOrganization 
                                                                   and $projection.DistributionChannel = _PartnerFunction.DistributionChannel
                                                                   and $projection.Division = _PartnerFunction.Division 
  
  association [0..*] to A_CustomerSalesAreaText as _SalesAreaText on  $projection.Customer = _SalesAreaText.Customer  
                                                                  and $projection.SalesOrganization = _SalesAreaText.SalesOrganization 
                                                                  and $projection.DistributionChannel = _SalesAreaText.DistributionChannel
                                                                  and $projection.Division = _SalesAreaText.Division 
                                                               
  association [0..*] to A_CustSlsAreaAddrDepdntInfo as _SlsAreaAddrDepdntInfo on  $projection.Customer = _SlsAreaAddrDepdntInfo.Customer   
                                                                              and $projection.SalesOrganization = _SlsAreaAddrDepdntInfo.SalesOrganization 
                                                                              and $projection.DistributionChannel = _SlsAreaAddrDepdntInfo.DistributionChannel
                                                                              and $projection.Division = _SlsAreaAddrDepdntInfo.Division   
                                                                                                                                                                  
{
  key Customer,
  key SalesOrganization,
  key DistributionChannel, 
  key Division, 
      AccountByCustomer, 
      AuthorizationGroup, 
      BillingIsBlockedForCustomer, 
      CompleteDeliveryIsDefined, 
      CreditControlArea,
      Currency, 
      CustIsRlvtForSettlmtMgmt,
      CustomerABCClassification, 
      CustomerAccountAssignmentGroup, 
      CustomerGroup, 
      CustomerIsRebateRelevant,
      CustomerPaymentTerms, 
      CustomerPriceGroup, 
      CustomerPricingProcedure, 
      CustomerStatisticsGroup,
      CustProdProposalProcedure,
      DeliveryIsBlockedForCustomer, 
      DeliveryPriority, 
      IncotermsClassification, 
      IncotermsLocation2, 
      IncotermsVersion,
      IncotermsLocation1,  
      IncotermsSupChnLoc1AddlUUID,
      IncotermsSupChnLoc2AddlUUID,
      IncotermsSupChnDvtgLocAddlUUID,   
      DeletionIndicator,
      IncotermsTransferLocation, 
      InspSbstHasNoTimeOrQuantity,
      InvoiceDate, 
      ItemOrderProbabilityInPercent, 
      ManualInvoiceMaintIsRelevant,
      MaxNmbrOfPartialDelivery,
      OrderCombinationIsAllowed, 
      OrderIsBlockedForCustomer, 
      OverdelivTolrtdLmtRatioInPct,
      PartialDeliveryIsAllowed,
      PriceListType, 
      ProductUnitGroup,
      ProofOfDeliveryTimeValue,
      SalesGroup, 
      SalesItemProposal,
      SalesOffice, 
      ShippingCondition, 
      SlsDocIsRlvtForProofOfDeliv,
      SlsUnlmtdOvrdelivIsAllwd,
      SupplyingPlant,
      SalesDistrict,
      UnderdelivTolrtdLmtRatioInPct,
      InvoiceListSchedule,
      ExchangeRateType,
      @Consumption.hidden: true
      IsBusinessPurposeCompleted,
      AdditionalCustomerGroup1,
      AdditionalCustomerGroup2,
      AdditionalCustomerGroup3,
      AdditionalCustomerGroup4,
      AdditionalCustomerGroup5,
      PaymentGuaranteeProcedure,    
      _Customer.CustomerAccountGroup,
      _Customer,
      _SalesAreaTax,
      _PartnerFunction,
      _SalesAreaText,
      _SlsAreaAddrDepdntInfo
}