A_CnsldtnPartFuncnlAreaHier

@AbapCatalog:{
  sqlViewName: 'ACSPARTFUNCAREAH',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL}
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Partner Functional Area Hier'
@OData.entitySet.name: 'PartnerFunctionalAreaHier'

define view A_CnsldtnPartFuncnlAreaHier
  as select from I_CnsldtnFuncnlAreaHierNode as _HierarchyNode

  association [0..1] to A_CnsldtnPartnerFuncnlArea   as _CnsldtnPartnerFuncnlArea   on  $projection.FunctionalArea = _CnsldtnPartnerFuncnlArea.FunctionalArea

  association [0..*] to A_CnsldtnPartFuncnlAreaHierT as _CnsldtnPartFuncnlAreaHierT on  $projection.AdditionalMasterDataHierarchy = _CnsldtnPartFuncnlAreaHierT.AdditionalMasterDataHierarchy
                                                                                    and $projection.HierarchyNode                 = _CnsldtnPartFuncnlAreaHierT.HierarchyNode
                                                                                    and $projection.ValidityEndDate               = _CnsldtnPartFuncnlAreaHierT.ValidityEndDate
                                                                                    and $projection.FunctionalArea                = ''

  association [0..*] to A_CnsldtnPartFuncnlAreaT     as _CnsldtnPartFuncnlAreaT     on  $projection.FunctionalArea = _CnsldtnPartFuncnlAreaT.FunctionalArea

  association [0..1] to A_CnsldtnPartFctArHierDir    as _CnsldtnPartFctArHierDir    on  $projection.AdditionalMasterDataHierarchy = _CnsldtnPartFctArHierDir.AdditionalMasterDataHierarchy
                                                                                    and $projection.ValidityEndDate               = _CnsldtnPartFctArHierDir.ValidityEndDate
{
      @ObjectModel.foreignKey.association: '_CnsldtnPartFctArHierDir'
      @EndUserText.label: 'Functional Area Hierarchy'
  key cast(left(_HierarchyNode.CnsldtnFunctionalAreaHierarchy, 40) as fincs_hryid preserving type ) as AdditionalMasterDataHierarchy,


      @ObjectModel.text.association: '_CnsldtnPartFuncnlAreaHierT'
  key HierarchyNode,

      @Semantics.businessDate.to: true
  key _HierarchyNode.ValidityEndDate,

      ParentNode,

      @Semantics.businessDate.from: true
      _HierarchyNode.ValidityStartDate,

      @EndUserText.label: 'Partner Functional Area'
      @ObjectModel.text.association: '_CnsldtnPartFuncnlAreaT'
      FunctionalArea,

      // STS - compatible ATC cleanup change - to be removed

      cast(HierarchyNodeSequence as abap.char( 56 ) )                                               as SequenceNumber,
      // STS - compatible ATC cleanup change - to be removed


      // STS - compatible ATC cleanup change

      HierarchyNodeSequence,
      // STS - compatible ATC cleanup change


      HierarchyNodeLevel,
      NodeType,

      @Consumption.hidden: true
      cast('CS05' as hrytype preserving type )                                                      as MDHierType,
      @Consumption.hidden: true
      cast('CS05' as hrytype preserving type )                                                      as HierarchyType,

      @Consumption.hidden: true
      _CnsldtnPartFctArHierDir,

      _CnsldtnPartnerFuncnlArea,
      _CnsldtnPartFuncnlAreaHierT,
      _CnsldtnPartFuncnlAreaT
}