A_CnsldtnFunctionalAreaHier

@AbapCatalog:{
  sqlViewName: 'ACSFUNCAREAHIER',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #XL}
//  representativeKey: 'HierarchyNode'

  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Functional Area Hierarchy'
@OData.entitySet.name: 'FunctionalAreaHier'

define view A_CnsldtnFunctionalAreaHier
  as select from I_CnsldtnFuncnlAreaHierNode

  association [0..1] to A_CnsldtnFunctionalArea    as _CnsldtnFunctionalArea    on  $projection.FunctionalArea = _CnsldtnFunctionalArea.FunctionalArea

  association [0..*] to A_CnsldtnFuncnlAreaHierT   as _CnsldtnFuncnlAreaHierT   on  $projection.AdditionalMasterDataHierarchy = _CnsldtnFuncnlAreaHierT.AdditionalMasterDataHierarchy
                                                                                and $projection.HierarchyNode                 = _CnsldtnFuncnlAreaHierT.HierarchyNode
                                                                                and $projection.ValidityEndDate               = _CnsldtnFuncnlAreaHierT.ValidityEndDate
                                                                                and $projection.FunctionalArea                = ''

  association [0..*] to A_CnsldtnFunctionalAreaT   as _CnsldtnFunctionalAreaT   on  $projection.FunctionalArea = _CnsldtnFunctionalAreaT.FunctionalArea

  association [0..1] to A_CnsldtnFuncnlAreaHierDir as _CnsldtnFuncnlAreaHierDir on  $projection.AdditionalMasterDataHierarchy = _CnsldtnFuncnlAreaHierDir.AdditionalMasterDataHierarchy
                                                                                and $projection.ValidityEndDate               = _CnsldtnFuncnlAreaHierDir.ValidityEndDate
{
      @ObjectModel.foreignKey.association: '_CnsldtnFuncnlAreaHierDir'
      @EndUserText.label: 'Functional Area Hierarchy'
  key cast(left(CnsldtnFunctionalAreaHierarchy, 40) as fincs_hryid preserving type ) as AdditionalMasterDataHierarchy,

      @ObjectModel.text.association: '_CnsldtnFuncnlAreaHierT'
  key HierarchyNode,

      @Semantics.businessDate.to: true
  key I_CnsldtnFuncnlAreaHierNode.ValidityEndDate,

      ParentNode,

      @Semantics.businessDate.from: true
      I_CnsldtnFuncnlAreaHierNode.ValidityStartDate,

      @ObjectModel.text.association: '_CnsldtnFunctionalAreaT'
      FunctionalArea,

      // STS - compatible ATC cleanup change - to be removed

      cast(HierarchyNodeSequence as abap.char( 56 ) )                                as SequenceNumber,
      // STS - compatible ATC cleanup change - to be removed


      // STS - compatible ATC cleanup change

      HierarchyNodeSequence,
      // STS - compatible ATC cleanup change


      HierarchyNodeLevel,
      NodeType,

      @Consumption.hidden: true
      cast('CS05' as hrytype preserving type )                                       as MDHierType,
      @Consumption.hidden: true
      cast('CS05' as hrytype preserving type )                                       as HierarchyType,


      @Consumption.hidden: true
      _CnsldtnFuncnlAreaHierDir,

      _CnsldtnFunctionalArea,
      _CnsldtnFunctionalAreaT,
      _CnsldtnFuncnlAreaHierT
}