A_CnsldtnCustomerGroupHier

@AbapCatalog:{
  sqlViewName: 'ACSCUSGROUPHIER',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL}
  }
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Customer Group Hierarchy'
@OData.entitySet.name: 'CustomerGroupHier'

define view A_CnsldtnCustomerGroupHier
  as select from I_CnsldtnCustGroupHierNode as _CnsldtnCustGroupHierNode

  association [0..1] to A_CnsldtnCustomerGroup      as _CnsldtnCustomerGroup      on  $projection.CustomerGroup = _CnsldtnCustomerGroup.CustomerGroup

  association [0..*] to A_CnsldtnCustomerGroupHierT as _CnsldtnCustomerGroupHierT on  $projection.AdditionalMasterDataHierarchy = _CnsldtnCustomerGroupHierT.AdditionalMasterDataHierarchy
                                                                                  and $projection.HierarchyNode                 = _CnsldtnCustomerGroupHierT.HierarchyNode
                                                                                  and $projection.ValidityEndDate               = _CnsldtnCustomerGroupHierT.ValidityEndDate
                                                                                  and $projection.CustomerGroup                 = ''

  association [0..*] to A_CnsldtnCustomerGroupT     as _CnsldtnCustomerGroupT     on  $projection.CustomerGroup = _CnsldtnCustomerGroupT.CustomerGroup

{

  key _CnsldtnCustGroupHierNode.CnsldtnCustomerGroupHierarchy                   as AdditionalMasterDataHierarchy,

      @ObjectModel.text.association: '_CnsldtnCustomerGroupHierT'
  key HierarchyNode,

      @Semantics.businessDate.to: true
  key _CnsldtnCustGroupHierNode.ValidityEndDate,

      ParentNode,

      @Semantics.businessDate.from: true
      _CnsldtnCustGroupHierNode.ValidityStartDate,

      @ObjectModel.text.association: '_CnsldtnCustomerGroupT'
      _CnsldtnCustGroupHierNode.CustomerGroup,

      cast(_CnsldtnCustGroupHierNode.HierarchyNodeSequence as abap.char( 56 ) ) as SequenceNumber, // obsolete


      _CnsldtnCustGroupHierNode.HierarchyNodeSequence,

      _CnsldtnCustGroupHierNode.HierarchyNodeLevel,

      _CnsldtnCustGroupHierNode.NodeType,
      
      @Consumption.hidden: true  
      cast('CS13' as hrytype preserving type )                                  as MDHierType,
      
      @Consumption.hidden: true
      cast('CS13' as hrytype preserving type )                                  as HierarchyType,


      _CnsldtnCustomerGroup,
      _CnsldtnCustomerGroupHierT,
      _CnsldtnCustomerGroupT
}