A_ClfnClassCharcForKeyDate

//@ClientHandling.algorithm: #SESSION_VARIABLE

//@AbapCatalog.sqlViewName: 'ANGCCLS03'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Class Characteristics'
//@VDM.viewType: #COMPOSITE

@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.representativeKey: 'CharcInternalID'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER
@Consumption.filter.businessDate.at: true
define view entity A_ClfnClassCharcForKeyDate
  with parameters        
    @Consumption.hidden: true
    @Semantics.businessDate.at: true 
    P_KeyDate : sydate
  as select from I_ClfnClassCharcForKeyDateTP( P_KeyDate: $parameters.P_KeyDate ) as ClassCharacteristic
                
      association to parent A_ClfnClassForKeyDate as _Class
        on $projection.ClassInternalID = _Class.ClassInternalID 
      association [1..1] to A_ClfnCharacteristicForKeyDate       as _Characteristic
        on $projection.CharcInternalID = _Characteristic.CharcInternalID         
{
      @ObjectModel.foreignKey.association: '_Class'
  key ClassCharacteristic.ClassInternalID, 
  key ClassCharacteristic.CharcInternalID,
      ClassCharacteristic.CharcPositionNumber,
      ClassCharacteristic.Characteristic,
      ClassCharacteristic.AncestorClassInternalID,
      ClassCharacteristic.OriginalCharcInternalID, 
      ClassCharacteristic.ChangeNumber,
      @EndUserText.label: 'Charc. Is Print Relevant'
      cast ( ClassCharacteristic.CharcIsPrintRelevant as relevanzkz ) as CharcIsPrintRelevant, //casting needed because of odata service compatibility reason

      @EndUserText.label: 'Charc. Is Search Relevant' 
      cast ( ClassCharacteristic.CharcIsSearchRelevant as relevanzkz ) as CharcIsSearchRelevant, //casting needed because of odata service compatibility reason

      @EndUserText.label: 'Charc. Is Display Relevant'
      cast ( ClassCharacteristic.CharcIsDisplayRelevant as relevanzkz ) as CharcIsDisplayRelevant, //casting needed because of odata service compatibility reason

      ClassCharacteristic.ValidityStartDate,
      ClassCharacteristic.ValidityEndDate,
//      @ObjectModel.readOnly: true

      ClassCharacteristic.CharcIsProposalRelevant,
//      @ObjectModel.readOnly: true

      $parameters.P_KeyDate as KeyDate,
//      @ObjectModel.readOnly: true

      ClassCharacteristic.ClassLastChangedDateTime,
      
      _Class,
      _Characteristic
}