A_CADisputeCase_2

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Dispute Case'

@Metadata.ignorePropagatedAnnotations:true

@ObjectModel: { usageType: { dataClass: #TRANSACTIONAL,
                             serviceQuality: #C,
                             sizeCategory: #L } }

@OData.entityType.name: 'A_DisputeCase_2_Type'

@VDM: { lifecycle.contract.type: #PUBLIC_REMOTE_API,
        usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE] ,
        viewType: #CONSUMPTION }


define root view entity A_CADisputeCase_2
  provider contract transactional_query
  as projection on R_CADisputeCaseTP as CADisputeCaseTP
  association [1..1] to A_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
{
  key CaseUUID,
      @ObjectModel.text.element: ['BusinessPartnerFullName']
      BusinessPartner,
      @Semantics.text: true
      BusinessPartnerFullName,
      @ObjectModel.text.element: ['ContractAccountName']
      ContractAccount,
      @Semantics.text: true
      ContractAccountName,
      cast ( CAContract as vtref_kk preserving type )  as CAContract,//Default Element of GFN 

      @ObjectModel.sapObjectNodeTypeReference: 'ContrAcctgApplicationArea'
      CAApplicationArea,
      @ObjectModel.sapObjectNodeTypeReference: 'ContrAcctgSubapplication'
      CASubApplication,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      TotalReceivablesAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputeCaseCorrectionAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputeCaseReversedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      CreditedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      WriteOffAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputeCaseReplacedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      PaidAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      CARemainingDisputedAmount,
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      DisputeCaseCurrency,
      LogicalSystem,
      @ObjectModel: { sapObjectNodeTypeReference: 'ContrAcctgDisputeType',
                      text.element: ['CADisputeTypeText'] }
      CADisputeType,
      @Semantics.text: true
      CADisputeTypeText,
      @ObjectModel.text.element: ['CompanyCodeName']
      @ObjectModel.sapObjectNodeTypeReference: 'CompanyCode'
      CompanyCode,
      @Semantics.text: true
      CompanyCodeName,
      DisputeCaseCoordinator,
      @ObjectModel.text.element: ['CaseRootCauseDescription']
      DisputeCaseRootCause,
      @Semantics.text: true
      CaseRootCauseDescription,
      CaseProcessingDeadlineDate,
      ContactPersonFullName,
      ContactPersonEmailAddress,
      ContactPersonPhoneNumber,
      ContactPersonFaxNumber,
      ContactPersonFaxCountry,
      DisputeCaseBPCorrespondenceKey,
      DisputeCaseInformationText,
      DisputeCaseTransactionDate,
      CADisputeCase,
      CaseType,
      CaseID,
      CaseExternalReference,
      CaseCreatedBy,
      CaseCreationDate,
      CaseLastChangedBy,
      CaseLastChangedOn,
      CaseStatusProfile,
      CaseClosedBy,
      CaseClosedTime,
      CasePlannedCloseDate,
      CaseProcessor,
      CaseResponsible,
      CaseTitle,
      CaseAuthorizationLevel,
      @ObjectModel.text.element: ['CaseStatusName']
      CaseStatus,
      @Semantics.text: true
      CaseStatusName,
      @ObjectModel.text.element: ['CaseUserStatusName']
      CaseSystemStatus,
      @Semantics.text: true
      CaseUserStatusName,
      @ObjectModel.text.element: ['DisputeCasePriorityName']
      CasePriority,
      @Semantics.text: true
      DisputeCasePriorityName,
      @ObjectModel.text.element: ['DisputeCaseCategoryName']
      CaseCategory,
      @Semantics.text: true
      DisputeCaseCategoryName,
      @ObjectModel.text.element: ['CaseReasonName']
      CaseReason,
      @Semantics.text: true
      CaseReasonName,
      @ObjectModel.text.element: ['DsputCaseEscalationRsnName']
      CaseEscalationReason,
      @Semantics.text: true
      DsputCaseEscalationRsnName,
      StreetName,
      HouseNumber,
      CountryName,
      PostalCode,
      CityName,
      @ObjectModel.sapObjectNodeTypeReference: 'ContrAcctgDisputeExtCallerCode'
      CADisputeExternalCallerCode,
      DisputeCaseOrigin,
      CAAuthorizationGroup,
      _BusinessPartner,
      /* compositions */ 
      _CACaseObject : redirected to composition child A_CADisputeCaseObject_2
}