A_BusSolnQtanItmPriceElement

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Price Element'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ABSQITMPRELEM',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_BusSolnQtanItmPriceElement
  as select from I_PricingElement       as PricingElement
    inner join   I_ServiceDocumentEnhcd as BusinessSolutionQuotation on  BusinessSolutionQuotation.PricingDocument   = PricingElement.PricingDocument
                                                                     and BusinessSolutionQuotation.ServiceObjectType = 'BUS2000116'
  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasure             on $projection.ConditionQuantityUnit = _UnitOfMeasure.UnitOfMeasure

  association [1..1] to A_BusinessSolutionQuotation as _BusinessSolutionQuotation on $projection.BusinessSolutionQuotation = _BusinessSolutionQuotation.BusinessSolutionQuotation
{

  key BusinessSolutionQuotation.ServiceDocument as BusinessSolutionQuotation,

  key PricingDocumentItem                       as BusSolutionQuotationItem,

  key PricingProcedureStep,
  key PricingProcedureCounter,

      ConditionType,

      ConditionRateValue,

      ConditionCurrency,

      //PriceDetnExchangeRate,


      @Semantics.quantity.unitOfMeasure: 'ConditionQuantityUnit'
      ConditionQuantity,

      @Semantics.unitOfMeasure: true
      ConditionQuantityUnit,

      _UnitOfMeasure.UnitOfMeasureISOCode       as ConditionQuantityISOUnit,

      VariantCondition,

      case ConditionInactiveReason
        when '' then 'X'
        else ''
      end                                       as ConditionIsActive,

      //Expose associations

      _BusinessSolutionQuotation
}