A_BusSolnOrderBundleItem

@EndUserText.label: 'Bundle Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view entity A_BusSolnOrderBundleItem
  as select from I_ServiceDocumentItemEnhcd
  association [1..1] to A_BusinessSolutionOrder       as _BusinessSolutionOrder on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder
  association [0..*] to A_BusSolutionOrderItemText    as _Text                  on  $projection.BusinessSolutionOrder     = _Text.BusinessSolutionOrder
                                                                                and $projection.BusinessSolutionOrderItem = _Text.BusinessSolutionOrderItem
  association [1..*] to A_BusSolnOrdItmConfiguration  as _Configurations        on  $projection.ConfigurationNumber = _Configurations.VariantConfigurationInstance
  association [0..1] to I_CustMgmtExtRefID            as _ExternalReference     on  $projection.BusinessSolutionOrder     = _ExternalReference.CustMgmtDocument
                                                                                and _ExternalReference.CustMgmtObjectType = 'BUS2000172'
                                                                                and _ExternalReference.CustMgmtExtRefIDType = '0001'
  association [0..*] to A_BusSolnOrdItmUserStatus     as _UserStatus            on  $projection.BusinessSolutionOrder     = _UserStatus.BusinessSolutionOrder
                                                                                and $projection.BusinessSolutionOrderItem = _UserStatus.BusinessSolutionOrderItem
  association [1..*] to I_SrvcDocAppointment          as _SrvcDocAppointment    on  $projection.BusinessSolutionOrderItemUUID = _SrvcDocAppointment.SrvcMgmtObjectUUID
  association [0..1] to I_CustMgmtPartner             as _ProjectManager        on  $projection.BusinessSolutionOrder            = _ProjectManager.CustMgmtDocument
                                                                                and $projection.BusinessSolutionOrderItem        = _ProjectManager.CustMgmtDocumentItem
                                                                                and _ProjectManager.CustMgmtPartFunctionCategory = '0093'
                                                                                and _ProjectManager.CustMgmtObjectType           = 'BUS2000172'
  association [0..1] to I_CustMgmtPartner             as _ServicePerformer      on  $projection.BusinessSolutionOrder              = _ServicePerformer.CustMgmtDocument
                                                                                and $projection.BusinessSolutionOrderItem          = _ServicePerformer.CustMgmtDocumentItem
                                                                                and _ServicePerformer.CustMgmtPartnerFunction      = '00000028'
                                                                                and _ServicePerformer.CustMgmtPartFunctionCategory = '0091'
                                                                                and $projection.BusinessSolutionOrder              = _ServicePerformer.CustMgmtDocument
                                                                                and $projection.BusinessSolutionOrderItem          = _ServicePerformer.CustMgmtDocumentItem
  association [0..1] to I_SalesDocumentRjcnReasonText as _RejectionReasonText   on  $projection.BusSolnOrdItmRjcnReason = _RejectionReasonText.SalesDocumentRjcnReason
                                                                                and $projection.Language                = _RejectionReasonText.Language
  association [0..1] to I_UnitOfMeasure               as _QuantityUnit          on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure
  association [0..*] to A_BusSolnOrdItmPartner        as _Partner               on  $projection.BusinessSolutionOrder     = _Partner.BusinessSolutionOrder
                                                                                and $projection.BusinessSolutionOrderItem = _Partner.BusinessSolutionOrderItem

{
  key ServiceDocument                                                                            as BusinessSolutionOrder,
  key ServiceDocumentItem                                                                        as BusinessSolutionOrderItem,
      @Semantics.uuid: true
      ServiceDocumentItemCharUUID,
      ServiceDocumentItemUUID                                                                    as BusinessSolutionOrderItemUUID,
      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentItemCategory'
      ServiceDocItemCategory                                                                     as BusSolnOrdItmCategory,
      ServiceDocumentItemDescription                                                             as BusSolnOrdItmDescription,
      Language,
      _ExternalReference.CustMgmtExtRefID                                                        as BusSolnOrdItmExtReference,

      case
      when ServiceDocumentItemStatus = 'C'
      then 'X' else ''
      end                                                                                        as BusSolnOrdItmIsCompleted,
      ServiceDocumentItemIsReleased                                                              as BusSolnOrdItmIsReleased,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentRjcnReason'
      ServiceDocItemRejectionReason                                                              as BusSolnOrdItmRjcnReason,
      _RejectionReasonText.SalesDocumentRjcnReasonName                                           as BusSolnOrdItmRjcnReasonText,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'BusSolnOrdItmQtyUnitSAPCode'
      @Semantics.quantity.unitOfMeasureIsoCode: 'BusSolnOrdItmQtyUnitISOCode'
      ServiceDocumentItemQuantity                                                                as Quantity,
      ServiceDocItemQuantityUnit                                                                 as QuantityUnit,
      cast(_QuantityUnit.UnitOfMeasureSAPCode as sd_ord_qty_sapunit preserving type)             as BusSolnOrdItmQtyUnitSAPCode,
      cast(_QuantityUnit.UnitOfMeasureISOCode as sd_ord_qty_isounit preserving type)             as BusSolnOrdItmQtyUnitISOCode,

      @ObjectModel.readOnly: true
      ConfigurationNumber,
      tstmp_to_dats( _SrvcDocAppointment[1:SrvcDocAppointmentType = 'CONFIGDATE'].SrvcDocApptStartDateTime,
                      abap_system_timezone( $session.client, 'NULL' ), $session.client, 'NULL' ) as BusSolnOrdItmConfigurationDate,
      DeliveryGroup,
      DeliveryPriority,
      IncotermsPart1,
      IncotermsPart2,
      DeliveryBlockReason,
      BillingBlockReason,
      @ObjectModel.readOnly: true
      Plant,
      OrderCombinationIsAllowed,
      @ObjectModel.readOnly: true
      @ObjectModel.createEnabled: true
      Product,
      ResponsibleEmployee                                                                        as RespEmployeeBusinessPartnerId,
      PayerParty,
      ContactPerson                                                                              as ContactPersonBusinessPartnerId,
      ShipToParty,
      SoldToParty,
      BillToParty,
      _ProjectManager.CustMgmtBusinessPartner                                                    as ProjectManager,

      _BusinessSolutionOrder,
      _Text,
      _Configurations,
      _UserStatus,
      _Partner
}
where
      ServiceObjectType             = 'BUS2000172'
  and ServiceDocumentItemObjectType = 'BUS2000214'