A_BusSolnOrdPartnerAddress

@EndUserText.label: 'Partner Address of Solution Order'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck:#MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view entity A_BusSolnOrdPartnerAddress as select from I_CustMgmtPartner as SolutionOrderPartner
    inner join   I_Address_2       as Address      on Address.AddressID = SolutionOrderPartner.AddressID
    inner join   I_ServiceDocument as SolutionOrder on  SolutionOrderPartner.CustMgmtDocument          = SolutionOrder.ServiceDocument
                                                   and SolutionOrderPartner.CustMgmtObjectType        = SolutionOrder.ServiceObjectType
                                                   and SolutionOrderPartner.CustMgmtDocumentItem      = '000000'
                                                   and SolutionOrder.ServiceObjectType           = 'BUS2000172'
                                                   and SolutionOrder.ServiceDocumentIsQuotation  is initial
                                                   and SolutionOrder.ServiceDocumentTemplateType is initial

association [0..1] to I_PersonWorkplaceAddress as _PersonWorkplaceAddress on  $projection.AddressID       = _PersonWorkplaceAddress.AddressID
                                                                          and $projection.AddressPersonID = _PersonWorkplaceAddress.AddressPersonID

association [1] to A_BusinessSolutionOrder as _BusinessSolutionOrder on $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder
{
  key SolutionOrderPartner.CustMgmtDocument as BusinessSolutionOrder,
  key SolutionOrderPartner.CustMgmtPartnerFunction,
  key SolutionOrderPartner.CustMgmtBusinessPartner,
       @ObjectModel.readOnly: true
       SolutionOrderPartner.AddressID,
       @ObjectModel.readOnly: true
       SolutionOrderPartner.AddressPersonID,
        @ObjectModel.readOnly: true
       SolutionOrderPartner.AddressObjectType,
       
       @ObjectModel.readOnly: true
       case
        when SolutionOrderPartner.AddressObjectType = '3'
         then _PersonWorkplaceAddress.PersonFullName
        else Address.AddresseeFullName
       end  as AddresseeFullName,
       Address.Country,
       Address.DistrictName,
       Address._CurrentDfltEmailAddress.EmailAddress,
       Address._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber,
       Address._CurrentDfltFaxNumber.FaxExtensionNumber,
       Address._CurrentDfltFaxNumber.FaxNumberCountry,
       Address.HouseNumber,
       Address._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobileNumber,
       Address._CurrentDfltMobilePhoneNumber.PhoneNumberCountry            as MobilePhoneCountry,
       Address.OrganizationName1,
       Address.OrganizationName2,
       Address.OrganizationName3,
       Address.OrganizationName4,
       case
        when SolutionOrderPartner.AddressObjectType = '3'
         then _PersonWorkplaceAddress.FamilyName
        else Address.PersonFamilyName
       end                                                                 as PersonFamilyName,
       case
        when SolutionOrderPartner.AddressObjectType = '3'
         then _PersonWorkplaceAddress.GivenName
        else Address.PersonGivenName
       end  as PersonGivenName,
       Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber,
       Address._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,
       Address._CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry,
       Address.POBox,
       Address.POBoxPostalCode,
       Address.PostalCode,
       Address.Region,
       Address.StreetName,
       Address.TransportZone,
       
       _BusinessSolutionOrder
}