A_BusSolnOrdItmPartnerAddress

@EndUserText.label: 'Solution Order Item Partner Address'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck:#MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   updateEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view entity A_BusSolnOrdItmPartnerAddress  as select from I_CustMgmtPartner  as SolutionOrderItemPartner
    inner join     I_Address_2        as Address on Address.AddressID = SolutionOrderItemPartner.AddressID
    inner join     I_ServiceDocumentItemEnhcd as BusinessSolutionOrderItem on SolutionOrderItemPartner.CustMgmtDocument = BusinessSolutionOrderItem.ServiceDocument
                                                                           and SolutionOrderItemPartner.CustMgmtDocumentItem = BusinessSolutionOrderItem.ServiceDocumentItem
                                                                           and SolutionOrderItemPartner.CustMgmtObjectType   = BusinessSolutionOrderItem.ServiceObjectType
                                                                           and SolutionOrderItemPartner.CustMgmtObjectType   = 'BUS2000172'

association [0..1] to I_PersonWorkplaceAddress as _PersonWorkplaceAddress on  $projection.AddressID       = _PersonWorkplaceAddress.AddressID
                                                                          and $projection.AddressPersonID = _PersonWorkplaceAddress.AddressPersonID

association [1] to A_BusinessSolutionOrder as _BusinessSolutionOrder on $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder
{
  key SolutionOrderItemPartner.CustMgmtDocument as BusinessSolutionOrder,
  key SolutionOrderItemPartner.CustMgmtDocumentItem as BusinessSolutionOrderItem,
  key SolutionOrderItemPartner.CustMgmtPartnerFunction,
  key SolutionOrderItemPartner.CustMgmtBusinessPartner,
  
         @Consumption.hidden: true
       @ObjectModel.readOnly: true
       SolutionOrderItemPartner.AddressID,
       @Consumption.hidden: true
       @ObjectModel.readOnly: true
       SolutionOrderItemPartner.AddressPersonID,

       @Consumption.hidden: true
       @ObjectModel.readOnly: true
       //Added to fetch address details based on address type

       SolutionOrderItemPartner.AddressObjectType,

       @ObjectModel.readOnly: true
       case
           when SolutionOrderItemPartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.PersonFullName
           else Address.AddresseeFullName
       end                                                                 as AddresseeFullName,
       Address.CityName,
       case
           when SolutionOrderItemPartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.CorrespondenceLanguage
           else Address.CorrespondenceLanguage
       end                                                                 as CorrespondenceLanguage,
       Address.Country,
       Address.DistrictName,
       Address._CurrentDfltEmailAddress.EmailAddress,
       Address._CurrentDfltFaxNumber.FaxAreaCodeSubscriberNumber,
       Address._CurrentDfltFaxNumber.FaxExtensionNumber,
       Address._CurrentDfltFaxNumber.FaxNumberCountry,
       case
           when SolutionOrderItemPartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.FormOfAddress
           else Address.FormOfAddress
       end                                                                 as FormOfAddress,
       Address.HouseNumber,
       Address._CurrentDfltMobilePhoneNumber.PhoneAreaCodeSubscriberNumber as MobileNumber,
       Address._CurrentDfltMobilePhoneNumber.PhoneNumberCountry            as MobilePhoneCountry,
       Address.OrganizationName1,
       Address.OrganizationName2,
       Address.OrganizationName3,
       Address.OrganizationName4,
       case
           when SolutionOrderItemPartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.FamilyName
           else Address.PersonFamilyName
       end                                                                 as PersonFamilyName,
       case
           when SolutionOrderItemPartner.AddressObjectType = '3'
            then _PersonWorkplaceAddress.GivenName
           else Address.PersonGivenName
       end                                                                 as PersonGivenName,
       Address._CurrentDfltLandlinePhoneNmbr.PhoneExtensionNumber,
       Address._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,
       Address._CurrentDfltLandlinePhoneNmbr.PhoneNumberCountry,
       Address.POBox,
       Address.POBoxPostalCode,
       Address.PostalCode,
       Address.Region,
       Address.StreetName,
       Address.StreetPrefixName1,
       Address.StreetPrefixName2,
       Address.StreetSuffixName1,
       Address.StreetSuffixName2,
       Address.TaxJurisdiction,
       Address.TransportZone,
       
       _BusinessSolutionOrder
}