ATOV_EXPORT_LOG

@AbapCatalog.sqlViewName: 'ATO_V_EL'
@ClientHandling:{ type: #INHERITED, algorithm: #SESSION_VARIABLE }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Export Log'

define view ATOV_EXPORT_LOG
  as select from ato_col_versions as Log

  association [*] to ATOV_TEXT_ACTION        as Action_Texts           on Action_Texts.code = Log.action

  association [*] to ATOV_TEXT_ACTION_STATUS as Action_Status_Texts    on Action_Status_Texts.code = action_status

  association [1] to ATOV_USER               as Changed_By_Description on Changed_By_Description.name = Log.last_changed_by


{
  key Log.collection_id,
  key Log.version                                                         as collection_version,
      Log.ballog_handle,
      Log.timestamp, // = 0 -> Gateway uses changed_by as timestamp.

      Log.action,
      Log.action_variant,
      case
        when Log.action_status = 'P'
        then 'R'
        else Log.action_status
      end                                                                 as action_status,
      Log.action_duration,
      Log.last_changed_by                                                 as changed_by,
      coalesce( Changed_By_Description.description, Log.last_changed_by ) as changed_by_description,
      Log.last_changed_at                                                 as changed_at,

      /* Associations */
      Action_Texts,
      Action_Status_Texts
}
where
       Log.ballog_handle <> ''
  and  Log.timestamp     =  0
  and(
       Log.action        =  #ato_collection_action.'A'
    or Log.action        =  #ato_collection_action.'C'
  )